Nullable timestamp with order by - cassandra

Question

We've recently decided to migrate an application to Cassandra (from Oracle) because it may help with performance, and as I have a decent Oracle background, I gotta admit I struggle with the Cassandra "way of thinking".
Basically i'm having a table with ~15 fields, among those dates. One of these dates is used for "ordering", so I need to be able to do "order by" on it. At the same time though, this field can be nullable.
Now i've figured putting that field as a primary key lets me actually do the order-by part, but I can't assign the null value to it anymore...
Any ideas ?

Answer 1

You are correct in that you cannot query by NULL values in Cassandra. There's a really good reason for that; which is that NULL values don't really exist. That row simply does not contain a value for the "NULL" column. So the CQL interface abstracts that with the "NULL" output, because that's easier to explain to people.
Cassandra also does not allow NULLs (or an absence of a column value) in its key fields. So the best you can do in this case, is to come up with a timestamp constant that you (and your application) recognize to be NULL without breaking anything. So consider this example table structure:
aploetz#cqlsh:stackoverflow> CREATE TABLE eventsByMonth (
monthBucket text,
eventTime timestamp,
event text,
PRIMARY KEY (monthBucket,eventTime))
WITH CLUSTERING ORDER BY (eventTime DESC);
Next I'll insert some values to test with:
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201509','2015-09-19 00:00:00','Talk Like A Pirate Day');
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201509','2015-09-25 00:00:00','Hobbit Day');
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201509','2015-09-19 21:00:00','dentist appt');
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201503','2015-03-14 00:00:00','Pi Day');
Let's say that I have two events that I want to keep track of, but I don't know the eventTimes, so instead of INSERTing a NULL, I'll just specify a zero. For the sake of the example, I'll put one in September 2015 and the other in October 2015:
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201510',0,'Some random day I want to keep track of');
aploetz#cqlsh:stackoverflow> INSERT INTO eventsByMonth (monthBucket,eventTime,event)
VALUES ('201509',0,'Some other random day I want to keep track of');
Now when I query for September of 2015, I'll get the following output:
aploetz#cqlsh:stackoverflow> SELECT * FROM eventsbymonth WHERe monthbucket = '201509';
monthbucket | eventtime | event
-------------+--------------------------+-----------------------------------------------
201509 | 2015-09-25 00:00:00-0500 | Hobbit Day
201509 | 2015-09-19 21:00:00-0500 | dentist appt
201509 | 2015-09-19 00:00:00-0500 | Talk Like A Pirate Day
201509 | 1969-12-31 18:00:00-0600 | Some other random day I want to keep track of
(4 rows)
Notes:
This is probably something you want to avoid doing, if possible.
INSERT/UPDATE (Upsert) with a "NULL" value is the same as a DELETE operation, and creates tombstone(s).
Upserting a zero (0) as a TIMESTAMP defaults to 1970-01-01 00:00:00 UTC. My current timezone offset is -0600, which is why the value of 1969-12-31 18:00:00 appears.
I don't need to specify an ORDER BY clause in my query, because the defined clustering order is what I want. It is a good idea to configure this as per your query requirements, because all ORDER BY can really do is enforce ASCending or DESCending. You cannot specify a column in your ORDER BY that differs from your table's defined clustering order.
An advantage of using a zero TIMESTAMP, is that all rows containing that key are ordered at the bottom of the result set (DESCending order), so you'll always know where to look for them.
Not sure what your partitioning key is, but I used monthBucket for mine. FYI- "bucketing" is a Cassandra modeling technique used when working with time series data, to evenly distribute data in your cluster.