Neo4j Get All Properties IFF Relationship 'Met' Exists, Partial Properties Otherwise - node.js

Question

I am still learning Neo4j and using the browser console with REST transactions to perform queries. I have a question on how to accomplish a particular task. Given the following scenario how would one go about completing the following:
I have 3 users in the database
2 users are connected with a relationship :Met label.
The 3rd user does not have any relationship connections
I want to be able to create a Cypher query to do the following:
IFF a :Met relationship exists between the user with whom we are making the query context and the desired user, return all of the properties for the desired user.
If no relationship exists between the user with whom we are making the query context and the desired user, only return back a public subset of data (avatar, first name, etc.)
Is there a way to execute a single query which can check if this relationship connection exists, return all User information? And if not, return only a subset of properties?
Thanks all!

Answer 1

In this query, p1 is the "query context", and p2 is all other people. A result row will only have the bar property if p1 and p2 have met.
MATCH (p1:Person { name: 'Fred' }),(p2:Person)
USING INDEX p1:Person(name)
WHERE p1 <> p2
RETURN
CASE WHEN (p1)-[:Met]-(p2)
THEN { name: p2.name, foo: p2.foo, bar: p2.bar }
ELSE { name: p2.name, foo: p2.foo }
END AS result;
For efficiency, this query assumes that you have first created an index on :Person(name).

Answer 2

You could do something like this whereby you match the first person and then optionally match the second person connected to the first via the :MET relationship. If the relationship exists then the results set you return could have more sensitive data in it.
match (p1:Person {name: '1'})
with p1
optional match (p1)-[r:MET]->(p2:Person {name: '2'})
with p1, case when r is not null then
{ name: p1.name, birthday: p1.birthday }
else
{ name: p1.name }
end as data
return data
EDIT:
OR maybe this is a better fit instead. Match both users and if a relationship exists return more data for the second person.
match (p1:Person {name: '1'}), (p2:Person {name: '2'})
with p1, p2
optional match (p1)-[r:MET]->(p2)
with p2, case when r is not null then
{ name: p2.name, birthday: p2.birthday }
else
{ name: p2.name }
end as data
return data