Loop through rows in dynamic table - excel

Question

I have entered data into an Excel 2013 worksheet and converted it to a table (Table4) which has two columns "colour code" and "description". I want to read the table data from another workbook and loop through the table rows in VBA and where the value matches a value in the "description" column then I want to use the "colour code".
How do I loop through the table to do this?
At the moment I have tried a few ways but I am finding errors. The section of code currently looks like this:
Dim row As Range
For Each row In wb.Worksheets("Colour").ListObjects("Table4").ListRows
Debug.Print row.value
Next

Answer 1

Unless the table is only a single colum, you can't do a Debug.Print on the row.Value because the row will represent an array of values, and the debugger will raise an error if you try to print it.
Try something like this:
For Each row In wb.Worksheets("Colour").ListObjects("Table4").ListRows
For c = 1 to row.Columns.Count
Debug.Print row(1,c).Value
Next
Next
That method is cell-by-cell iteration which is probably what you need.
Alternatively, to simply print the entire row value:
For Each row In wb.Worksheets("Colour").ListObjects("Table4").ListRows
Debug.Print Join(Application.Transpose(row.Value), vbTab)
Next
But this doesn't give you as much freedom to manipulate cell values or anything like that.

Answer 2

Try looping over just the column you want to match. Once you find a match, you can look for the value in the correct column in the same row.
For Each cell in wb.Worksheets("Colour").Range("Table4[description]")
If cell.value = "Desired Value" then
Debug.Print(Cells(cell.row(), Range("Table4[colour code]").column))
End If
Next
The benefit to doing it this way is you can rearrange your table and your code will still work so long as those columns still exist with the same names.

Answer 3

I'd suggest using the following function:
Function lrWrap(lr As ListRow) As Collection
Dim lo As ListObject
set lo = lr.Parent
Dim vh As Variant: vh = lo.HeaderRowRange.Value 'Header
Dim vr As Variant: vr = lr.Range.Value 'This row
Dim retCol As New Collection
'Append list row and object to collection as __ListRow and __ListObject
retCol.Add lr, "__ListRow"
retCol.Add lo, "__ListObject"
'Loop through each header and append row value with header as key into return collection
For i = LBound(vh, 2) To UBound(vh, 2)
retCol.Add vr(1, i), vh(1, i)
Next
'Return retCol
Set lrWrap = retCol
End Function
Ultimately with the function you can do the following:
Dim row as ListRow, rCol as Collection
For each row in Sheets("MySheet").ListObjects("MyTableName").ListRows
set rCol = lrWrap(row)
debug.print rCol("My Table Header")
'If you need to access the list object you can do so via __ListObject
debug.print rCol("__ListObject").name
next
This makes your code a lot cleaner than any of the above solutions, in my opinion.