Excel VBA opening file with the latest version - excel

Question

just starting to learn VBA for excel and experimenting in automating my routine work.
I have a workbook which some of the contents are copied from other files. In the same file directory, i have several files that data i copied with. The problem is the files have several versioning, for example:
companyA_20151101.xlx
companyA_20151105.xlx
companyA_20151106.xlx
companyB_20151105.xlx
companyC_20151109.xlx
I take documents from company A to C, but having problem due to the date. Would it be possible to tell VBA just pick the latest version (i.e. for companyA takes the one with 06 date)?

Answer 1

You could create a UDF to return a string with the correct file name. I've assumed from the naming convention that the most recent file is actually created on that date and therefore will have the most recent Creation Date property.
Function GetRecentFile(partialFileName As String) As String
Dim files As Variant
Dim checkDate As Date
Dim returnFile As String
With CreateObject("System.FileScriptingObject")
files = Filter(Split(CreateObject("WScript.Shell").Exec("CMD /C DIR """ & partialFileName & _
"*.xl*"" /S /B /A:-D").StdOut.ReadAll, vbCrLf), ".")
checkDate = .GetFile(CStr(files(0))).DateCreated
For Each file In files
If .GetFile(CStr(file)).DateCreated > checkDate Then
checkDate = .GetFile(CStr(file)).DateCreated
returnFile = CStr(file)
End If
Next
End With
GetRecentFile = returnFile
End Function
Use like so:
Sub MM()
Dim myFile As String, wb As Excel.Workbook
myFile = GetRecentFile("C:\Users\MM\Work Files\CompanyA")
If Not myFile = vbNullString Then
Set wb = Workbooks.Open(myFile)
End If
End Sub

Answer 2

I've approached this slightly differently and am using the date suffix on the filename to determine which is the 'latest' file:
Public Function MostRecentCompanyFile(ByRef strCompany As String, _
ByRef strDirectory As String) As String
Dim strDir As String
Dim datDateSuffix As Date
Dim strLatest As String
Dim datLatest As Date
strDir = Dir(strDirectory & "\" & strCompany & "*")
Do Until Len(strDir) = 0
datDateSuffix = StripDate(strDir)
If Len(strLatest) = 0 Then
'the first iteration
strLatest = strDir
datLatest = datDateSuffix
ElseIf datDateSuffix > datLatest Then
'this file has a later date suffix so this is now the latest
strLatest = strDir
datLatest = datDateSuffix
End If
'get the next file
strDir = Dir
Loop
MostRecentCompanyFile = strLatest
End Function
Private Function StripDate(ByRef strFileName As String) As Date
Dim intPos As Integer
Dim strDate As String
Dim datDate As Date
'assume the date suffix occurs after the underscore in the file name and is in the format yyyymmdd
intPos = InStr(1, strFileName, "_")
strDate = Mid$(strFileName, intPos + 1, 8)
datDate = DateSerial(Left$(strDate, 4), Mid$(strDate, 5, 2), Right$(strDate, 2))
StripDate = datDate
End Function
Here, we are:
Looping through all the files in the given strDirectory.
Stripping off the date suffix (using the StripDate method).
Comparing this date to all others for the given strCompany.