Insert mode Ctrl-O without triggering autocmds - vim

Question

Having gone the full circle from default statusline, to customized, through neatstatus, powerline, airline and back to customized statusline, one of the fancy features was a coloured statusline depending on mode. So, a couple of autocmds to trigger a colour change on InsertEnter and InsertLeave, and all is nice, snappy, with a visual colour cue, and pretty much all in
set statusline=%-22.(%5l\ of\ %5L,%4c:%4v%)\ %P\ %6o\ %03b\ %<%F\ %y\ %h%m%r%=b:%2n\ %{strftime('%a\ %b\ %e\ %I:%M\ %p')}
But, Insert Mode Ctrl-O actually triggers the autocmds, and I like to have Up and Down imapped to gk gj, to move by display line and not entire wrapped lines. This can cause quite a bit of barely noticeable colour change flicker (the worst kind) during those times when quick scrolling through a file while in Insert mode. (This happens quite often when coding COBOL, when you need to scroll back and forth between DATA DIVISION and PROCEDURE DIVISION, but that's beside the point).
Anyway, I'll take the tsk-tsks for using cursor keys while in Insert mode, but I'm wondering if there is a way to
inoremap <Up> <C-O>gk
inoremap <Down> <C-O>gj
without triggering the InsertLeave InsertEnter autocmds, that repaint the statusline just to change the colour, pretty needlessly in this case. Or a different way to use cursor keys in Insert mode that move by display line and not wrapped line.

Answer 1

I thought only about really simple way how to do it
inoremap <Up> <C-c>gka
inoremap <Down> <C-c>gja
i_CTRL-c doesn't trigger InsertLeave autocommand event so I hope in your case it means no flash.
Then I found this excellent Ingo Karkat's answer:
function! IgnoreOn( motion )
set eventignore+=InsertLeave,InsertEnter
return "\<C-o>" . a:motion
endfunction
function! IgnoreOff()
set eventignore-=InsertLeave,InsertEnter
return "\<Left>\<Right>" | " Workaround for missing screen update.
endfunction
inoremap <expr> <SID>IgnoreOff IgnoreOff()
inoremap <expr> <SID>IgnoredDown IgnoreOn('gj')
inoremap <script> <Down> <SID>IgnoredDown<SID>IgnoreOff
inoremap <expr> <SID>IgnoredUp IgnoreOn('gk')
inoremap <script> <Up> <SID>IgnoredUp<SID>IgnoreOff