VBA fill a listbox will all occurrences - excel

Question

I have a spreadsheet with 4 columns and 35000 lines.
I have made a form with 3 listboxes (among other buttons)
When I click search button I would like to search column A for all occurrences of the number and fill the listboxes with the corresponding B, C & D
(if it helps speed there will never be more than 10 occurrences of the same number and column A is sorted)
123 dog Fido Elm $50
123 dog Spot Oak $40
456 Cat Jet Adam $30
Search for 123 and
listbox 1 will show Fido & Spot
listbox 2 will show Elm & Oak
listbox3 ....
Code so far:
Private Sub cmdSearch_Click()
Dim Response As Long
Dim NotFound As Integer
NotFound = 0
ActiveWorkbook.Sheets("test").Activate
Frame1.Visible = False
Response = txtItemNumber.Text
If Response <> False Then
Range("A2").Select
Do Until ActiveCell.Value = Val(Response)
If ActiveCell.Value = "" Then
MsgBox "Item Number Not Found!", vbExclamation
NotFound = 1
Exit Do
End If
ActiveCell.Offset(1, 0).Select
Loop
If ActiveCell.Value = Val(Response) Then
Frame1.Visible = True
ListBox1.Text = ActiveCell.Offset(0, 1)
ListBox2.Text = ActiveCell.Offset(0, 2)
ListBox3.Text = ActiveCell.Offset(0, 3)
**'would like to see if next number in Column A is also the same as being searched... if so then add to listbox'
'do this until the next number doesn't match'**
End If
End If
End Sub
also would the process be sped up with an array or vlookup? I'm not to familiar with those
and I would like the multiple list boxes rather than a multicolumn list box (in case that comes up)

Answer 1

This code is based on your idea but it uses an array, called arr, to input the data quickly and to facilitate fast processing. The located references are stored in strings which are split later into the ListBoxes.
A vertical bar is used as a split character. If that clashes with your data you will need to change it.
Note: I don't think your Frame1.Visible commands are effective.actually do anything.
Private Sub cmdSearch_Click()
Dim Response As Long
Dim NotFound As Integer
Dim arr As Variant
Dim i As Long
Dim str1 As String, str2 As String, str3 As String
NotFound = 0
ActiveWorkbook.Sheets("test").Activate
Frame1.Visible = False
Response = txtItemNumber.Text
If Response <> False Then
With ActiveSheet
arr = .Range("A2:D" & .Cells(.Rows.Count, "A").End(xlUp).Row)
End With
For i = 1 To UBound(arr)
If arr(i, 1) = Response Then
str1 = IIf(str1 = "", arr(i, 2), str1 & "|" & arr(i, 2))
str2 = IIf(str2 = "", arr(i, 3), str2 & "|" & arr(i, 3))
str3 = IIf(str3 = "", arr(i, 4), str3 & "|" & arr(i, 4))
End If
Next
If str1 = "" Then
MsgBox "Item Number Not Found!", vbExclamation
NotFound = 1
Else
Frame1.Visible = True
ListBox1.List = Split(str1, "|")
ListBox2.List = Split(str2, "|")
ListBox3.List = Split(str3, "|")
End If
End If
End Sub

Answer 2

Just curious, if you define Response as a long, why are you using val(Response) in the while loop? And if its a long, then Response = txtItemNumber.Text could throw an error by potentially trying to store an alphanumeric string in a numeric only long.
Since you dim Response as a long, use this instead...
Response = Val("0" & txtItemNumber.Text)
This assumes no negative numbers. By pre-pending the zero you don't change the value of the number (0100 is still 100) but you also handle "0abc" issues if the user enters text. It will return 0 if the user enters "abc" and your solution checks for 0 (false) already. If the user enters "100" it converts "0100" to 100 and your solution then moves on with that value. It will fail if the user enters "-100" since "0-100" isn't 100.
Now, since we are using a long, remove all references to Val(Response) elsewhere. This will reduce the type conversions inside the loop that searches for the cell value. As you have it, each time through the loop it converts Response from a long to a string then to a long and then does the UNTIL compare. And it does that 35000 times.
By converting it using Val before the loop, it now does the string to long conversion ONCE instead of all 35000 times it loops going through the cells. Its a minor change that could speed it up a bit.