Filtering for the value in A1 - excel

Question

I am trying to figure out a way to filter Column C for the value in A1, then put the formula in the first cell and copy down. I have the below code but I can't seem to get it to work. I have an example of the spreadsheet below the code.
With ActiveSheet.Range("A5").CurrentRegion
.AutoFilter Field:=3, Criteria1:="=RC[1]"
If .Columns(1).SpecialCells(xlCellTypeVisible).Count > 1 Then
With .Columns(2)
.Resize(.Rows.Count - 1).Offset(1).SpecialCells(xlCellTypeVisible).FormulaR1C1 = "=RC[1]&""-R21"""
End With
End If
End With

Answer 1

I think the problem is that your formula is only being added to the first cell in your filtered range. That is because a discontiguous SpecialCells range such as yours, i.e., C7, C10,C12:C15, etc., will consist of multiple Areas. If that's the case, you need to loop through the Areas with a For/Next:
Dim FilteredArea as Range
With ActiveSheet.Range("A5").CurrentRegion
.AutoFilter Field:=3, Criteria1:="=RC[1]"
If .Columns(1).SpecialCells(xlCellTypeVisible).Count > 1 Then
For Each FilteredArea in .Columns(2).Resize(.Rows.Count - 1).Offset(1).SpecialCells(xlCellTypeVisible).Areas
FilteredArea.FormulaR1C1 = "=RC[1]&""-R21"""
Next FilteredArea
End If
End With
This is untested, but hopefully will give you an idea of how to work with Areas.

Answer 2

Set range("A1") as a variable
Sub Button2_Click()
Dim F As Range'declare F as a range
Set F = Range("A1")'set F as range("A1")
With ActiveSheet.Range("A5").CurrentRegion
.AutoFilter Field:=3, Criteria1:=F'Filter for F
If .Columns(1).SpecialCells(xlCellTypeVisible).Count > 1 Then
With .Columns(2)
.Resize(.Rows.Count - 1).Offset(1).SpecialCells(xlCellTypeVisible).FormulaR1C1 = "=RC[1]&""-R21"""
End With
End If
End With
End Sub
Here's another version, so you won't have to use Formulas.
Sub LoopThroughFilterd()
Dim rws As Long, rng As Range, Fltr As Range, c As Range
rws = Cells(Rows.Count, "A").End(xlUp).Row
Set rng = Range("C6:C" & rws)
Set Fltr = Range("A1")
Application.ScreenUpdating = 0
With ActiveSheet.Range("A5").CurrentRegion
.AutoFilter Field:=3, Criteria1:=Fltr
For Each c In rng.Cells
If c.EntireRow.Hidden = 0 Then
c.Offset(, -1) = c & "-R21"
End If
Next c
.AutoFilter
End With
End Sub
You can also Loop through the cells instead of filtering.
Sub LooPFor()
Dim rws As Long, rng As Range, Fltr As Range, c As Range
rws = Cells(Rows.Count, "A").End(xlUp).Row
Set rng = Range("C6:C" & rws)
Set Fltr = Range("A1")
For Each c In rng.Cells
If c = Fltr Then c.Offset(, -1) = c & "-R21"
Next c
End Sub