Excel 2010 calculates when nothing changed - excel

Question

I have an Excel 2010 workbook that insists on "calculating" every time I enter, then exit a cell (blank) even when nothing is changed.
If the above workbook is open it spreads the problem to any other workbook is that is open. Problem will disappear when the above workbook is closed.
The problematic workbook contains 3 Sheets;
1 has a table that pulls external data with an SQL command,
2 has various formulas that summarise the data from Sheet 1,
3 has various graphs that use data from Sheet2.
The problematic workbook contains no macros.
I've searched Google high and low to no avail, any ideas?

Answer 1

As the TODAY function is considered a volatile¹ function, it isn't wise to use it repeatedly within long columns and/or rows of formulas, particularly within calculation-intensive array formulas. Calculation lag can quickly build up and the function's volatile nature will force a calculation cycle whenever anything in the entire workbook changes, not just when something that actually affects its outcome changes as is the norm with non-volatile functions.
A formula based defined name that does not actually refer to any worksheet call is a good fit here. Using something like =DATE(YEAR(TODAY()), MONTH(TODAY()), DAY(TODAY())) is counterproductive because you have not removed the volatile TODAY() function. However, VBA can write a hardcoded native worksheet function into the RefersTo: of the defined name. In this case, the current date will be constructed using the worksheets' DATE function.
The following code belongs in the ThisWorkbook code page. Tap Alt+F11 and when the VBE opens, locate ThisWorkbook in the Project Explorer. If the project explorer is not visible, tap Ctrl+R or use the pull-down menus to choose View ► Project Explorer. 
            
Double-click ThisWorkbook or right-click and choose View Code. Paste the following into the code sheet titled something like Book1 - ThisWorkbook (Code).
Private Const dnCURRENT As String = "Current"
Private Sub Workbook_Open()
'force a Workbook_SheetChange on open to check Current date
Call Workbook_SheetChange(Worksheets(1), Worksheets(1).Cells(1))
End Sub
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
On Error GoTo no_Current
With ThisWorkbook.Names(dnCURRENT)
On Error GoTo bm_Safe_Exit
If Application.Evaluate(.RefersTo) <> Date Then
Application.EnableEvents = False
.RefersTo = "=DATE(" & Year(Date) & ", " & Month(Date) & ", " & Day(Date) & ")"
End If
End With
GoTo bm_Safe_Exit
no_Current:
ThisWorkbook.Names.Add Name:=dnCURRENT, _
RefersTo:="=DATE(" & Year(Date) & ", " & Month(Date) & ", " & Day(Date) & ")", _
Visible:=True
Resume
bm_Safe_Exit:
If CBool(Err.Number) Then _
Debug.Print Err.Number & ":" & Err.Description
Application.EnableEvents = True
End Sub
If you wish to change the name of the defined name, do so in the private constant variable declaration at the top. Tap Alt+Q to return to your worksheet(s).
The first time that any change is made on any worksheet, a new defined name with workbook scope will be created called Current. It will have a RefersTo: with a hardcoded DATE function that returns the current system date (e.g. =DATE(2015, 10, 14)). If the current date is not equal to the defined names value returned by that formula, a new formula is written using the current date and this forces a new workbook-wide calculation cycle on all formulas that reference the defined name.
The defined name Current is a direct replacement for anywhere that the TODAY() function can be used. In practise, the formula(s) involving Current will only be recalculated once per day. The following image demonstrates how it will appear as an option as you start to type it into a formula.
           
¹ Volatile functions recalculate whenever anything in the entire workbook changes, not just when something that affects their outcome changes. Examples of volatile functions are INDIRECT, OFFSET, TODAY, NOW, RAND and RANDBETWEEN. Some sub-functions of the CELL and INFO worksheet functions will make them volatile as well.