How can i prevent duplicates from being created - excel

Question

I've created an excel spreadsheet which will be tracking faulty assets that have been sent back from our external agents, I have two tabs that will be the main focus of this spreadsheet. Tab 1 will be the tested assets tab and Tab 2 will be awaiting testing. So once any asset that gets sent back will be manually logged on the awaiting testing tab, but once it's been tested I've created a vba code that will export anything that's been marked with a "Y" meaning it's been tested on to the Tested assets tab.
But the problem i have here is that one asset can come in to testing and be sent back out to the field to our engineers more than once, so if it comes back to be tested again and gets logged on the awaiting testing and once it's been tested and exported to the tested assets tab it duplicates what already is on the tested asset tab and i get two cells with the same data. Is there anyway i can put in another line of code that will prompt me on a duplicate before it exports it. See code below;
Sub automove()
Dim SerialNo As String
Dim AwaitTestLastRow, PasteToRow As Long
Sheets("Awaiting Testing").Select
AwaitTestLastRow = Range("a1000000").End(xlUp).Row
For x = AwaitTestLastRow To 3 Step -1
If Range("c" & x).Value = "Y" Or Range("c" & x).Value = "y" Then
SerialNo = Range("a" & x).Value
Rows(x).Delete
Sheets("Tested Assets").Select
Range("a1000000").End(xlUp).Offset(1, 0).Value = SerialNo
Range("e1000000").End(xlUp).Offset(1, 0).Value = SerialNo
PasteToRow = Range("a1000000").End(xlUp).Row
Range("b3:d3").Select
Selection.Copy
Range("b" & PasteToRow & ":d" & PasteToRow).Select
ActiveSheet.Paste
Range("f3").Select
Selection.Copy
Range("f" & PasteToRow & ":f" & PasteToRow).Select
ActiveSheet.Paste
Sheets("Awaiting Testing").Select
End If
Next x

Answer 1

There are many different ways of checking for duplicates. In the code below, I've used a .Find function on the "Tested Assets" worksheet. If the return object is Nothing then it's a new item, if it's a Range then we know the address of your duplicate. It's not necessarily the quickest way (a Collection might be quicker, for example), but the .Find function is still pretty snappy and as, you'll see in my next comment, I wanted to have the range address.
I've put some code below that instead of prompting you for a duplicate, records the frequency with which the same item is returning to the test lab - might be of some use to you for tracking a repeat offender. However, if you don't want that then delete the 4 lines and replace with MsgBox asset(1, 1) & " is a duplicate."
I've adjusted your code slightly to speed it up, and watch out for declaring two variables on the same line as each variable must have its own declaration type. In your line: Dim AwaitTestLastRow, PasteToRow As Long, the AwaitTestLastRow variable isn't a Long (it's actually not typed ie a Variant).
Sub AutoMove_v2()
Dim awaitingRange As Range
Dim testedRange As Range
Dim flaggedRange As Range
Dim newRow As Range
Dim dupCell As Range
Dim testFlag As String
Dim asset As Variant
Dim cell As Range
Dim frq As Long
'Initialise the parameters
With ThisWorkbook.Worksheets("Awaiting Testing")
Set awaitingRange = .Range("A3", _
.Cells(.Rows.Count, "A").End(xlUp))
End With
With ThisWorkbook.Worksheets("Tested Assets")
Set testedRange = .Range("A1", _
.Cells(.Rows.Count, "A").End(xlUp))
End With
'Loop through the awaiting sheet to find assets for transferral
For Each cell In awaitingRange
testFlag = UCase(cell.Offset(, 2).value)
If testFlag = "Y" Then
If flaggedRange Is Nothing Then
Set flaggedRange = cell
Else
Set flaggedRange = Union(flaggedRange, cell)
End If
End If
Next
'Identify duplicates or transfer new assets
For Each cell In flaggedRange
asset = cell.Resize(, 4).value
Set dupCell = testedRange.Cells.Find(What:=asset(1, 1), _
After:=testedRange.Cells(1), _
LookIn:=xlFormulas, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=True)
If dupCell Is Nothing Then
'It's a new entry so transfer the values
Set newRow = testedRange.Cells(testedRange.Cells.Count).Offset(1)
Set testedRange = Union(testedRange, newRow)
newRow.Resize(, 4) = asset
Else
'It's a duplicate so increment the frequency counter
frq = dupCell.Offset(, 5).value
If frq = 0 Then frq = 1
frq = frq + 1
dupCell.Offset(, 5) = frq
End If
Next
'Delete the transferred rows
flaggedRange.EntireRow.Delete
End Sub