Highlighting a the used cells in a particular row - excel

Question

I am writing VBA for a file at work and need to do something a little odd. I need to highlight the row (not the entire row, just the used part of the row) if the cell in Column J contains a certain value. I have figured everything out except my code is highlighting the entire row, and I only want it to highlight the used cells in that row. Can anyone advise? Code below
'Yellow Highlight..........THIS IS HIGHLIGHTING THE WHOLE ROW....WHY!!!!! WHY!!!!!!!!!!!
Sheets("EMM").Activate
With Sheets("EMM")
For Lrow = 1 To ActiveSheet.UsedRange.Rows.Count
With .Cells(Lrow, "J")
If Not IsError(.Value) Then
If .Value = "Desk to adjust" Then
.EntireRow.Interior.ColorIndex = 6
End If
End If
End With
Next Lrow
End With

Answer 1

With Sheets("EMM")
For Lrow = 1 To .UsedRange.Rows.Count
With .Cells(Lrow, "J")
If Not IsError(.Value) Then
If .Value = "Desk to adjust" Then
Sheets("EMM").UsedRange.Rows(Lrow).Interior.ColorIndex = 6
End If
End If
End With
Next
End With
or using AutoFilter
With Sheets("EMM").UsedRange
.Parent.AutoFilterMode = False
.AutoFilter
.AutoFilter Field:=10, Criteria1:="Desk to adjust"
.Rows(1).Hidden = True 'Header row
.Interior.ColorIndex = 6
.Rows(1).Hidden = False 'Header row
.AutoFilter
.Cells(1, 1).Activate
End With

Answer 2

The easiest to avoid looping on the row and fetching non-blank cells, or setting up a filter, is to do this inside the IF:
.UsedRange.Rows(lRow).Interior.ColorIndex = 6
.UsedRange.Rows(lRow).SpecialCells(xlCellTypeBlanks).Interior.ColorIndex = 0
(highlight the row then unhighlight empty cells)

Answer 3

Here is some commented code showing how to use the Range.AutoFilter method to achieve the results you're looking for. No looping required, so it is generally much more efficient:
Sub tgrFilter()
Dim ws As Worksheet
Dim rngData As Range
Dim strMatch As String
Set ws = ActiveWorkbook.Sheets("EMM") 'We will be working with sheet "EMM" in activeworkbook
Set rngData = ws.Range("J1").CurrentRegion 'Get the region that column J is a part of in order to limit the highlighting (so it doesn't highlight entire row)
strMatch = "Desk to adjust" 'This is the string/value we are looking for in column J
rngData.Interior.Color = xlNone 'Clear any previous highlighting
On Error Resume Next 'If there are no results, it would cause an error
'Work with just column J within rngData
With Intersect(rngData, ws.Columns("J"))
.AutoFilter 1, strMatch 'Note that the filter is not case sensitive
'Color the matching rows contained in the data (not the entire row)
Intersect(rngData, .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).EntireRow).Interior.ColorIndex = 6
.AutoFilter 'Remove the filter
End With
If Err.Number <> 0 Then
'Error occurred which means there were no results
MsgBox "No matches found in column J for [" & strMatch & "]", , "No results"
Err.Clear
End If
On Error GoTo 0 'Remove the On Error Resume Next condition
End Sub

Answer 4

You can use Conditional Formatting instead of macro.
Select the cell your need to highlight and at menu bar go to Format -> Conditional Formatting
In dialog select condition you need to check, this example check if cell value is equal to 'AA'. You can add condition up to 3 conditions at a time
Next, Click format button to format cell when the condition is true.
After finish all click OK to close dialog you will get the highlight you need.