First part of IF statement is being ignored - excel

Question

I have the following IF statement in VBA, but the "delete" part of the statement, or the bit before the ElseIf, is completely ignored:
For i = 3 To (customerNum + 3)
If Sheets("Reports").Range("L" & i).Value = "A" Then
Sheets("Reports").Range("G" & i & ":M" & i).Select
Selection.Delete Shift:=xlUp
ElseIf Sheets("Reports").Range("L" & i).Value <> "A" Then
Sheets("Reports").Range("J" & i).Value = form1_1 & i & form1_2
Sheets("Reports").Range("J" & i).NumberFormat = "d-mmm-yy"
Sheets("Reports").Range("M" & i).Value = form2_1 & i & form2_2 & i
Sheets("Reports").Range("M" & i).NumberFormat = "_-[$£-809]* #,##0.00_-;-[$£-809]* #,##0.00_-;_-[$£-809]* ""-""??_-;_-#_-"
End If
Next i
The rest runs smoothly. No crashes or bugs.
Any ideas?

Answer 1

This is not (!) supposed to be an additional answer. Yet, I would like to add this "answer" because (occasionally) I encountered the problem of various different "A"s or "C"s (etc.) in one Excel sheet. Working in large corporations I had colleagues working with multiple different character sets at a time (their native character set and the English one). Note that the cyrillic "A" looks like the latin "A". Yet, even with Option Compare Text the two are different. The following code will reveal the unicode of a character and might be a better way of checking if an "A" has been entered into a particular cell:
Public Sub CheckUnicode()
Dim lngRowNumber As Long
Debug.Print AscW("A")
With Sheets("Reports")
For lngRowNumber = 1 To 100000
If Trim(.Range("L" & lngRowNumber).Value2) = vbNullString Then Exit For
Debug.Print AscW(Left(.Range("L" & lngRowNumber).Value2, 1))
Next lngRowNumber
' The following will append a cyrillic a to the bottom of the sheet in Column "A"
.Range("A" & lngRowNumber + 1).Value2 = ChrW(1072)
End With
End Sub
I am merely addition this "solution" for others who might encounter a similar problem. As mentioned before there are several characters which look alike but are not. Also note, that this is only the cyrillic alphabet. There might be other character sets out there which seem to look alike.

Answer 2

Maybe you need to start from the bottom then go up.
Sub Button1_Click()
Dim sh As Worksheet
Dim Rws As Long, rng As Range, nwrw As Long
Set sh = Sheets("Reports")
With sh
Rws = .Cells(.Rows.Count, "L").End(xlUp).Row
For i = Rws To 3 Step -1
If .Cells(i, "L") = "A" Then .Range(.Cells(i, "G"), .Cells(i, "M")).Delete Shift:=xlUp
If .Cells(i, "L") <> "A" Then
.Cells(i, "J") = "something" & i & "something else"
.Cells(i, "M") = "something" & i & "something else"
End If
Next i
End With
End Sub