Removing outliers from sas dataset - statistics

Question

I have loaded an excel table into SAS using this code -
FILENAME REFFILE "/folders/myfolders/subji.xlsx" TERMSTR=CR;
PROC IMPORT DATAFILE=REFFILE
DBMS=XLSX
OUT=ds;
GETNAMES=YES;
RUN;
And then sorted it to apply a repeated measures analysis to it using this sort proc -
PROC SORT DATA=ds;
BY subject Color_Compatibility sameloc;
RUN;
And then, ran a univariate ANOVA to retrieve stats and effects using this code -
PROC UNIVARIATE DATA=ds NOPRINT;
VAR resprt;
OUTPUT OUT=unids1 MEAN=resprt;
BY subject Color_Compatibility sameloc;
where Color_Compatibility >0
and practice = 0
and outlier = 0
and respAC=1;
RUN;
The outlier column is currently calculated through excel, but I've noticed the values excel's STDEV function gives are not accurate. For that reason I want to create an outlier variable with SAS, and then remove every outlier row from my analysis (using +/-2.5 STDEV as a benchmark).
How could this be done?
Thanks.

Answer 1

Here's a way using proc sql in one step to identify outliers. You can calculate aggregate statistics in SQL though it does leave a warning in your log about remerging. The key is to ensure that you GROUP BY variable is the level you want the calculations at. In this example I'm looking for outliers in the MPG_CITY metric from the SASHELP.CARS data set based on the number of cylinders in a vehicle.
*Identify Outliers;
proc sql;
create table outliers as
select *, std(mpg_city) as std, mean(mpg_city) as avg,
case when ((mpg_city - calculated avg)/(calculated std) < -2.5) or ((mpg_city - calculated avg)/(calculated std) > 2.5) then 'Outlier'
else 'Normal'
end as outlier_status
from sashelp.cars
group by cylinders;
quit;
*Check number of outliers;
proc freq data=outliers;
table outlier_status;
run;
*Print observations of interest;
proc print data=outliers;
where outlier_status='Outlier';
var origin make model cylinders mpg_city std avg;
run;