Check if Cells contain value exactly one time - excel

Question

I have five cells in Excel filled with ones and zeros and now I want to check if in those five cells there is zero exactly one time?
Example:
(11110) true
(11100) false
I need a regular Excel function without VB please.

Answer 1

Assuming the value is in cell A1, use this formula:
This is an array formula and must be confirmed with Ctrl+Shift+Enter.
=1=SUM(--(MID(A1,ROW(OFFSET($A$1,,,LEN(A1))),1)="0"))
Now copy the formula to point at the four other cells.
That's it.
Here is how it works...
Let's say that the value of cell A1 is 11101111
So, that's a total of eight characters. We can see that seven of them are 1s and one is a 0.
But how do we get Excel to see the same thing?
At the heart of the formula is the MID() function. We use it to break apart the value into eight separate characters.
Under normal usage, the MID() function just returns one substring of text from a larger string. You provide it the start position within the larger text and how long of a substring you want and it returns that substring.
For example: =MID(A1,3,3) would return 101 when referencing our A1.
And if we changed that to: =MID(A1,4,1) we would get 0.
But how can we have the MID() function completely decompose the value in A1 into discreet, single-character substrings. Remember that MID() normally just returns one substring. But in our case we want it to return eight substrings.
This is where the array-formula comes in. Remember that the 2nd parameter for MID() is the start position of the substring we want back. If we pass to that 2nd parameter an array of numbers instead of one single number, then MID() will perform its function once for each value in the array.
One way of specifying arrays in Excel is to use and array constant. So we could change our MID() example to this:
=MID(A1,{1;2;3;4;5;6;7;8},1)
And the result would look like this: {"1";"1";"1";"0";"1";"1";"1";"1"}.
Now if you just enter the above formula in a single cell, you will only see the first element, which is a one. But if you selected a range of eight vertical cells and then clicked on the Formula Bar at the top of the worksheet and entered the formula and then confirmed the array-way with Ctrl+Shift+Enter
... you would see these eight different values appear in the selected range.
Another way to see the full results, even from one cell, is to select the full formula inside the Formula Bar and then press the F9 key on the keyboard. The formula will be replaced with the results in the Formula Bar. You can use this technique to evaluate the formula or discreet parts of a larger formula. If you press Enter the results will stay in the Formula Bar. If you want the formula instead, press Esc.
The problem with using the array constant is that it only works correctly when the text in cell A1 is exactly eight characters long or less. If we want to handle longer text, then we need an array constant with more values. One way to side-step this issue is to use a formula to create an array on the fly that when evaluated would look like our array constant. We would design this formula to have precisely the same number of incrementing elements as there are characters in the text in cell A1.
That is precisely what this construct in the middle of our formula does:
ROW(OFFSET($A$1,,,LEN(A1))
Recall that when the MID() function is finished we are left with this array of results: {"1";"1";"1";"0";"1";"1";"1";"1"}
Now we apply a logical test to each element, asking is each of these equal to 0?
Here is how that would look:
{"1";"1";"1";"0";"1";"1";"1";"1"}=0
A new array result is returned that looks like this:
{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}
Notice that only the 4th element is TRUE, which of course is exactly right.
So that's progress.
Now we want to count how many elements are TRUE. We know the answer is one. But how can Excel figure this out?
It would be nice if our array were of numbers rather than these Boolean TRUE and FALSE values. An easy way to convert the array of Booleans to numbers is to use two minus signs in front of the array. When a TRUE value is turned negative it becomes a number; it becomes -1. When we hit it with the 2nd minus sign, that -1 becomes +1. And of course FALSE becomes 0.
So doing that would look like this:
--({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}=0)
And the result would look like this:
{0;0;0;1;0;0;0;0}
Notice that the array is now composed of numbers. When we first looked at the results from the MID() function, it looked like this: {"1";"1";"1";"0";"1";"1";"1";"1"} and those are not numbers; they are text. Notice all the quotation marks.
If you are following closely you may be wondering why we could not have used the two minus signs directly on the output from the MID() function to convert those text numbers into real numbers. Well, in truth we could have. But we want an array where the 1s represent the source zeroes and the 0s represent the source 1s. In other words, we want the inverse. Taking these extra steps gives us that.
We can now use SUM() on the array.
=SUM{0;0;0;1;0;0;0;0})
Since it is only summing 1s and 0s and the 1s represent the original source zeros, the result is the count of the source zeroes.
We perform one final test to see if the result is equal to one, because you want to know if the value in cell A1 has one and only one zero in it:
=1=SUM{0;0;0;1;0;0;0;0})
The result is TRUE.