Sort by variable Range - excel

Question

I want code to figure how large a table of data is, then sort it. I assumed that I would declare a variable range once I knew how large the table is and tell Excel to sort first by the variable range "Account" and then "Symbol" and then "Quantity."
The problem occurs with the ActiveWorkbook.Worksheets("Mutual Funds").Sort.SortFields.Add Key:=Range("Account")...
Method Range of Object' Global Failed is my error message. It appears that this is not the correct way to give it a variable range.
Anyone know how to fix this?
Sub Macro1()
'
ActiveWorkbook.Sheets("Mutual Funds").Activate
Range("A12").Select
Do Until IsEmpty(ActiveCell)
ActiveCell.Offset(1).Select
Loop
ActiveCell.Offset(-1).Select
Dim Account As Range
Dim Symbol As Range
Dim Quantity As Range
Dim EntireRange As Range
Set Account = Range(ActiveCell, "A11")
Set Symbol = Range(ActiveCell.Offset(, 9), "J11")
Set Quantity = Range(ActiveCell.Offset(, 7), "H11")
Set EntireRange = Range(ActiveCell, "AS11")
ActiveWorkbook.Worksheets("Mutual Funds").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("Mutual Funds").Sort.SortFields.Add Key:=Range("Account"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortTextAsNumbers
ActiveWorkbook.Worksheets("Mutual Funds").Sort.SortFields.Add Key:=Range("Symbol"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
ActiveWorkbook.Worksheets("Mutual Funds").Sort.SortFields.Add Key:=Range("Quantity"), SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("Mutual Funds").Sort
.SetRange Range("EntireRange")
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
End Sub

Answer 1

Using Range("Account") to reference a Range variable is wrong.
Just use Account
Other issues:
The Key's need to exclude the header,
Your method of getting the used ranges is highly inefficient.
Here's your code refactored :
Sub Macro1()
Dim wb As Workbook
Dim ws As Worksheet
Dim Account As Range
Dim Symbol As Range
Dim Quantity As Range
Dim EntireRange As Range
Set wb = ActiveWorkbook
Set ws = wb.Sheets("Mutual Funds")
With ws
Set Account = .Range(.Cells(12, 1), .Cells(12, 1).End(xlDown))
End With
Set Symbol = Account.Offset(, 8)
Set Quantity = Account.Offset(, 6)
Set EntireRange = Account.Offset(-1, 0).Resize(Account.Rows.Count + 1, 45)
With ws.Sort ' EntireRange
.SortFields.Clear
.SortFields.Add Key:=Account, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortTextAsNumbers
.SortFields.Add Key:=Symbol, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.SortFields.Add Key:=Quantity, SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
.SetRange EntireRange
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
End Sub