VBA code help opening file with differnt name - excel

Question

I have a Macro i made and can't seem to get it to work correctly.
If i run the macro and pick a file in a folder with multiple files of the same type.
it only opens the first file in the folder. know matter what file i try to open, it will re-open the same file. for example. if i have 3 files with the names
cycle0001 , cycle0002, cycle0003 when ever i try to open file 003 it opens file 001 always. the code works great except i can't open the file i would like.
only the file with the lowest number in the name.
Here is my code.
Sub jsonDataExtractor()
'
' jsonDataExtractor Macro
' Json Data Extractor
'
' Keyboard Shortcut: Ctrl+t
'
File = Application.GetOpenFilename( _
FileFilter:=" (*.json), *.json", _
Title:="Select a file or files", _
MultiSelect:=True)
Application.ScreenUpdating = False
Workbooks.OpenText filename:= _
"cycle*.json", StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=True, Tab:=True, Semicolon:=True, Comma:=True, _
Space:=False, Other:=True, OtherChar:=":", FieldInfo:=Array(Array(1, 9), _
Array(2, 1), Array(3, 1)), TrailingMinusNumbers:=True

Answer 1

Use code similar to this:
Option Explicit
Sub jsonDataExtractor()
Dim selectedFile As Variant, itm As Variant
selectedFile = Application.GetOpenFilename(FileFilter:=" (*.json), *.json", _
Title:="Select a file or files", _
MultiSelect:=True)
Application.ScreenUpdating = False
If TypeName(selectedFile) <> "Boolean" Then
For Each itm In selectedFile
Workbooks.OpenText Filename:=itm, StartRow:=1, DataType:=xlDelimited, _
TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=True, _
Tab:=True, Semicolon:=True, Comma:=True, _
Space:=False, Other:=True, OtherChar:=":", _
FieldInfo:=Array(Array(1, 9), _
Array(2, 1), Array(3, 1)), TrailingMinusNumbers:=True
Next
End If
Application.ScreenUpdating = True
End Sub
.
You need to use the result returned by Application.GetOpenFilename()
.
If MultiSelect:=True it can return either
a Boolean (False if the user canceled)
or an array of variants (file names) even if the user selects only one file
.
If MultiSelect:=False it can return either
a Boolean (False if the user canceled)
or the file name (including its full path)