So I have a table with description lines like this: EFT VISA RF#509723083734 04/07 ENDICIA POSTAGE (EMS) 650-321-2640.
What I'd like to be able to do is add up all the amounts with descriptions containing "Endicia".
I tried =VLOOKUP(SEARCH("endicia",D9,0)="true",D2:F12,3) but that didn't work.
I tried using SumIf instead, with similar lack of success.
Any advice would be much appreciated
IF helpful, the description is in column D and the amount is in column E.
If you can add an additional column, you can add one in that only counts the number if the keyword ("ENDICIA") is found in the cell (otherwise return 0).
=IFERROR(IF(FIND("ENDICIA",D1),E1,0),0)
From there you just need to sum the column where you put this formula.
Please try:
=SUMIF(D:D,"*ENDICIA*",E:E)
Related
UPDATE: found an answer to my problem through this website: https://exceljet.net/formula/categorize-text-with-keywords
I'm trying to categorize certain products based on the beginning of each product name. My first table is the look-up table below:
My second table currently looks like this:
And I want the end result of that second table to look like this:
What excel formula can I use to achieve the red column? I've tried scouring the internet, for the formula that best suits my need, but I can't figure it out. I've seen people throw out the =Lookup(Search()) function, but my formula needs to start with the key word, but just contain the keyword somewhere in the cell.
I've read many different forums, but I haven't been able to find one that answers a scenario similar enough to mine. Any suggestions are appreciated.
If the first word of the Product Name is always matched to the product start, you can vlookup by just the 1st word. Assuming your product start is in column A, Categerization in Column B, Product Name in Column C, you can key in the formula in Column D:
'''
=vlookup(left(C2,search(" ",c2)-1),A:B,2,0)
'''
Just set your vlookup 4th parameter to TRUE:
Note: formula as written can be drag/filled down from B2. Also your Category Table needs to be in A-Z sorted order.
HTH
I need help with the below formula. I already tried to find a solution for this problem but no success.
If account number exists in column A in the 'Returns' tab and also in column A in the 'July Sales' tab, then I need to get date from the column B in 'Returns' tab.
I manually checked a few accounts on both spreadsheet and find some duplicates.
My formula is as follows:
=VLOOKUP(Returns!A:B,A:B,2,0)
Screenshots:
I tried to change format to text/general, text to columns and trim function but it's still not working.
Also, as I have over 200k rows in each table, can I use any different formula instead to speed this up?
Finally, is there any way to pick dates only if these are within 30 days
Thanks in advance.
You're using Returns!A:B as your lookup value, which doesn't make sense. Instead, try the following:
=VLOOKUP([#Account], tblReturns[[Account]:[Submit_Date]],2,FALSE)
where tblReturns is the name of the table on your Returns worksheet.
I've made the assumption that you're working with tables, since the data in your screenshots is formatted like the default table. If they're just normal ranges, the equivalent is
=VLOOKUP($A2,Returns!$A:$B,2,FALSE)
=IF(COUNTIF(RETURNS!A:A,A2)>0,B2,"NO RETURN INFO")
Not sure what you want done when the account is not found on the RETURNS worksheet. Change "NO RETURN INFO" to what ever text you want including "" for a blank. Make sure you apply the same format for cells in column F as you do in column B. Copy the above formula down as required.
try the below, which will return blanks for non-matches as opposed to errors;
=IFERROR(VLOOKUP($A2,Returns!$A:$B,2,FALSE),"")
I highly recommend an INDEX/MATCH combination over a VLOOKUP. It is MUCH faster, particularly if you are working with a large number of rows. It may even be faster than the COUNTIF solution suggested by #ForwardEd.
=IFERROR(INDEX(Returns!$B:$B,MATCH($A2,Returns!$A:$A,0)),"")
For a large series of numbers I would like to find out a certain moving average.
I want for example in T(750) the average of K2:K(index). This certain index can be found in the same row, in column B. So in Cell B750.
How can I do this?
Any help is much appreciated
Use INDEX():
=AVERAGE($K$2:INDEX($K:$K,B750))
Or to ensure no errors as #Jeeped suggested
=AVERAGE($K$2:INDEX($K:$K,MAX(B750,2))
Otherwise you will get errors if B750 is text or null.
I'm having trouble finding the proper formula for this. I have two columns with stock names where some of them are duplicates. However I want to extract the number i column F into column B if they are duplicates. I tried to do so manually to provide with an example. Anyone knows how to do this?
Firstly, why did you remove the image from the question, nobody will be able to help you without it as your question is not clear.
Hope this is what you want. Assuming your data is as in the image below, use the following formula
=IFERROR(VLOOKUP(A2,$E$2:$F$10,2,FALSE),"")
or
=IFERROR(INDEX($F$2:$F$10,MATCH(A2,$E$2:$E$10,0)),"")
I need to download warehouse inventory levels in a CSV, every morning, and update my website inventory CSV based on those numbers.
I've combined them into one worksheet.
Image: http://i62.tinypic.com/1zqxd7n.png
Column K contains the SKUs of all the items in my online store.
In column A is the list of the warehouse's SKUs, sorted to only display out-of-stock items.
I need to go down column A and see if that SKU exists in my store by looking in column K. If it's not in column K, ignore. "999999999" just means "in-stock." If it is in column K, write "0" in the cell one right of it, for "out-of-stock."
I'm looking for the formula for column L. So far I've tried something like =0*(INDEX(K:K,MATCH(A3,K:K,0))), but I think I've got it all wrong.
This problem is similar to the one here, but slightly different.
I would greatly appreciate your help, it would save me a LOT of time. Thanks in advance!
Eric, . The following formula should give you what you are after. I have replaced '999999' and '0' with a narrative return, as the logic (in the question) for whether or not an item is in stock appears to be the wrong way around.
Since an error would ordinarily be returned by a straight Index/Match formula, when a value cannot be found, you can build that into the formula.
=IF(ISERROR(INDEX(K:K,MATCH(A3,K:K,0))),"Cannot Find in Col K","Can Find in Col K")
You don't really need INDEX function if you aren't retrieving any values, perhaps try this formula:
=IF(COUNTIF(K:K,A3),999,0)
That will return 999 if A3 exists in column K, otherwise 0