Diff 2 long strings and write result in 3rd file - linux

Question

I am working on my initial bash scripts and got stuck at a place where need help from the forum.
How to implement below in shell script? (Any suggestions/pointers are appreciated!!!)
Requirement:
Compare 2 files matchings KEY containing long string and persist in 3rd file only long strings which differ in other attributes (say value of USER is different). Also skip some attributes comparison.
Input FILE1-
AAUTOX=Y;ACCT=;ACTION=C;APRICE=99.975;AQTY=5541;USER=Sam,bpl;CONFIRM=Y;KEY=29976DYE4;DEPT=MYNA-CLCD -- same
AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Todd,chr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD -- diff (USER=Todd,chr) write in result file
Input FILE2-
AAUTOX=Y;ACCT=;ACTION=C;APRICE=99.975;AQTY=5541;USER=Sam,bpl;CONFIRM=Y;KEY=29976DYE4;DEPT=MYNA-CLCD -- same
AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Alan,ncr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD -- diff (USER=Alan,ncr) write in result file
AAUTOX=Y;ACCT=;ACTION=C;APRICE=17.000;AQTY=6453;USER=Todd,chr;CONFIRM=N;KEY=29976DYE6;DEPT=MYNA-CLCD -- no match (KEY) found write in result file
Output FILE3:
FILE1:AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Todd,chr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD
FILE2:AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Alan,ncr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD
FILE1:
FILE2: AAUTOX=Y;ACCT=;ACTION=C;APRICE=17.000;AQTY=6453;USER=Todd,chr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD
and so on for each differed line....
Approach in my mind (It's first cut and cud improve later):
Read FILE1 line by line (awk or read??)
For each Line
a) read FILE2 for matching unique "KEY" (which command to use here??? Could awk read file based on key??? grep KEY from FILE2 but how to break line into fields for comparison??)
b) Now compare each field of FILE1.LINE1 with FILE2.LINE and if different write in 3rd result file (awk breaks line into fields $1, $2 so could compare
though not sure how to do if use "read" command???)

Answer 1

This uses GNU awk 4.* for sorted in (see http://www.gnu.org/software/gawk/manual/gawk.html#Controlling-Array-Traversal), with other awks you can pipe to sort or otherwise determine the key order:
$ cat tst.awk
BEGIN { FS="[;=]" }
{
delete name2val
for (i=1; i<=NF; i+=2) { name2val[$i] = $(i+1) }
key = name2val["KEY"]
keys[key]
recs[key,FILENAME] = $0
for (name in name2val) { vals[key,FILENAME,name] = name2val[name] }
}
END {
PROCINFO["sorted_in"] = "#ind_str_asc"
file1 = ARGV[1]
file2 = ARGV[2]
for (key in keys) {
state = "SAME"
if ( (key,file1) in recs ) {
if ( (key,file2) in recs ) {
for (name in name2val) {
if (name != "CONFIRM") {
if (vals[key,file1,name] != vals[key,file2,name]) {
state = "DIFF"
}
}
}
} else { state = "FILE1_ONLY" }
} else { state = "FILE2_ONLY" }
if (state != "SAME") {
print file1":", recs[key,file1]
print file2":", recs[key,file2]
print ""
}
}
}
.
$ gawk -f tst.awk FILE1 FILE2
FILE1: AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Todd,chr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD -- diff (USER=Todd,c
hr) write in result file
FILE2: AAUTOX=Y;ACCT=;ACTION=C;APRICE=05.975;AQTY=3451;USER=Alan,ncr;CONFIRM=N;KEY=29976DYE5;DEPT=MYNA-CLCD -- diff (USER=Alan,ncr) write in result file
FILE1:
FILE2: AAUTOX=Y;ACCT=;ACTION=C;APRICE=17.000;AQTY=6453;USER=Todd,chr;CONFIRM=N;KEY=29976DYE6;DEPT=MYNA-CLCD -- no match (KEY) found write in result file