Translate the numbers before and after `/` - text

Question

In a text with lines of similar format:
3.1 Broadcasting 541/541,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
3.2 Prefix Computation 590/590,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
I would like to translate the numbers before and after / by a certain amount. For example, I woule like to translate the numbers before / by 1, and the number after / by 2, and the above will become:
3.1 Broadcasting 542/543,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
3.2 Prefix Computation 591/592,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
I try to do that using awk:
awk -F'[,/]' '{sub(/\//, " " ($2+1) "/"); sub($2, ($2+1) ) }1
But my problem is that I can't catch the number before /. How shall I improve my command?
Is awk the right tool to do that? Or something else?
Thanks.

Answer 1

In my opinion awk is not the best tool. It makes difficult when you have to split by different characters. You could use split but then it returns an array, modify the field of the array and traverse all fields to join them, but at this time you've lost the separator, and don't know which it was.
It could be considered a good option (not the best) because it's powerful enough for the task but in this case using perl with its regular expression and the evaluate flag beats it, like:
perl -pe 's{(\d+)/(\d+)(,)}{($1+1) . "/" . ($2+2) . $3}e' infile
It yields:
3.1 Broadcasting 542/543,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
3.2 Prefix Computation 591/592,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
EDIT FOR EXPLANATION of the perl command:
First curly braces are the regular expression that matches the text, and the second one is the replacement string. First one matches one or more digits between a slash, and a comma. The /e flag lets do arithmetic in the replacement part, so thanks to grouping I increment first number by one, second one by two and use the concatenation operator (.) to join them and replace the previous match.

Answer 2

Yes, awk is the right tool to use. e.g. with GNU awk for the 3rd arg to match():
$ awk 'match($0,/(.*)([0-9]+)\/([0-9]+)(.*)/,a){ $0 = a[1] a[2]+1 "/" a[3]+2 a[4] }1' file
3.1 Broadcasting 542/543,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
3.2 Prefix Computation 591/592,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
With other awks one approach would be:
$ awk 'match($0,/[0-9]+\/[0-9]+/){ split(substr($0,RSTART,RLENGTH),a,"/"); $0 = substr($0,1,RSTART-1) a[1]+1 "/" a[2]+2 substr($0,RSTART+RLENGTH) }1' file
3.1 Broadcasting 542/543,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
3.2 Prefix Computation 591/592,Black,notBold,notItalic,open,TopLeftZoom,0,0,0.0
In both cases the match() isolates the digit(s)/digit(s) part so you can then operate on that segment before recombining it with what came before and after it. The GNU awk solution just has the advantage of Capture Groups saved in the 3rd arg array so you don't need to use split()+substr() after the match().
By making the 2 as similar as possible, I think what follows makes the gawk/non-gawk differences clear:
Gawk:
awk 'match($0,/(.*)([0-9]+)\/([0-9]+)(.*)/,a) {
$0 = a[1] a[2]+1 "/" a[3]+2 a[4]
}1' file
Non-gawk:
awk 'match($0,/[0-9]+\/[0-9]+/) {
# START of what the gawk 3rd arg for match() saves you
split(substr($0,RSTART,RLENGTH),b,"/")
a[1] = substr($0,1,RSTART-1)
a[2] = b[1]
a[3] = b[2]
a[4] = substr($0,RSTART+RLENGTH)
# END of what the gawk 3rd arg for match() saves you
$0 = a[1] a[2]+1 "/" a[3]+2 a[4]
}1' file
As you can see that 3rd arg for match() is just some syntactic sugar, but a LITTLE sugar is OK in moderation :-).