D: Split string from the second occurrence of the character - string

Question

I need to do splitting string before the second occurrence ("-").
Example: s1-qwe-123
need to get: s1-qwe
What is the best practice?
Ehm, thanks, but faced with situation where some files have structure like:
s1-123. And I need to get from them: s1.
Is there any way to make variant with split process such situation?

Answer 1

int saw;
auto s = "s1-qwe-123".findSplitBefore!(c => c == '-' && saw++ > 0)[0];

Answer 2

You could split it and join it together again.
string line = "s1-qwe-123";
string interestedBit = line.split("-")[0..2].join("-");
Or a loop through the chars:
int idx;
bool found;
string line = "s1-qwe-123";
for(idx = 0; idx < line.length; ++idx){
if(line[idx] == '-')
if(found)
break;
else
found = true;
}
auto interestedBit = line[0..idx];

Answer 3

My original answer was completely wrong as I misread the question. Here is a correct answer that provides a slight variation on the split solution already suggested in other answers:
import std.algorithm : splitter;
import std.array : join;
import std.range : take;
auto res = "s1-qwe-123".splitter("-").take(2).join('-');
assert(res == "s1-qwe");
The advantage of using splitter over split is lazy evaluation. This should only walk up to the second '-' and no further.

Answer 4

There are many ways to achieve this, I'll present two.
The first would be to split the whole string by "-" and then to join the first two elements:
import std.stdio, std.string;
"s1-qwe-123".split("-")[0 .. 2]
.join("-")
.writeln; // -> "s1-qwe"
This is simple but may not be efficient enough as the whole string has to be read. The other method I would propose is to use regular expressions as there is a matchFirst function that reads the string only up to the first occurence of the expression.
import std.stdio, std.regex;
"s1-qwe-123".matchFirst("[^-]+-[^-]+")[0]
.writeln; // -> "s1-qwe"
And if you want it to be really fast you can use a compile-time regular expression:
import std.stdio, std.regex;
"s1-qwe-123".matchFirst(ctRegex!("[^-]+-[^-]+"))[0]
.writeln; // -> "s1-qwe"