OSX - Package a shell based interactive binary - node.js

Question

I've created a small NodeJS script that compiles down using EncloseJS so the app becomes its own binary. The app is meant to run in Terminal and be interactive with the user. I'd like to package this in a .app so it feels like a full application that regular users can run.
How can I go about this? I've so far tried Platypus with mixed results as it doesn't seem to exit correctly.

Answer 1

Try the following:
Use [Apple]Script Editor to create a new script and save it as an application.
Place your binary - let's call it foo - in the new .app bundle's Contents/MacOS subfolder.
Place the following code in the application's AppleScript:
set embeddedBinary to POSIX path of (path to me) & "Contents/MacOS/foo"
tell application "Terminal"
do script quoted form of embeddedBinary
activate
end tell
When you run the application, the embedded binary is opened in a new Terminal window that you can interact with.
Append & "; exit" to the do script command to automatically close the Terminal window when the binary terminates.
Note, however, that your application merely act as a launcher for the embedded binary:
It terminates after the Terminal window has been created
so its Dock icon only shows up briefly and disappears again
and you'll get no application menu (which wouldn't be an option anyway, given that your binary runs in Terminal).
Every time you start the app, a new Terminal window is opened, even if your binary is already running in one.
There are ways to address these issues (except the menu one), but they require additional work - see below.
A solution that addresses above issues for a more integrated experience:
It keeps the wrapper application open (showing its own Dock icon).
It relays activation to the launched Terminal window running the embedded binary when the app is activated (e.g., by clicking on the Dock icon)
The wrapper application terminates automatically when the launched Terminal window is closed.
However, it has limitations:
Sadly, to relay activation, GUI scripting is needed, which requires a one-time authorization with administrative privileges on any given machine; the user is prompted on first launch, but it requires a few steps.
For the application to be able to quickly relay activation when clicked and to quickly quit when the Terminal window closes, its on idle event handler must be invoked frequently, which consumes CPU resources, although the extra load on the CPU is pretty small - see comments in source code below.
Instructions:
Use [Apple]Script Editor to create a new script and save it as a stay-open application:
In the Save As dialog, choose format Application and check the Stay open after run handler checkbox.
Place your binary - let's call it foo - in the new .app bundle's Contents/MacOS subfolder.
Place the following code in the application's AppleScript:
# Global variable to track the launched Terminal window (tab).
global g_winLaunched
on run
# Get full path of embedded binary.
set embeddedBinary to POSIX path of (path to me) & "Contents/MacOS/foo"
tell application "Terminal"
# Launch embedded binary in new Terminal window, and
# have the window closed when the binary terminates *successfully*.
# This leaves the window open in case of error - whether on
# initial launch or on existing - giving the user a chance to investigate.
do script quoted form of embeddedBinary & " && exit"
set g_winLaunched to front window
end tell
end run
on idle
if frontmost of me then # If this app is activated, relay activation to the launched Terminal window.
try
# Activate the running window using GUI scripting.
# Sadly, `set index of g_winLaunched to 1` is NOT enough to activate the window.
# NOTE: This requires that this app be authorized for assistive access via
# System Preferences > Security & Privacy > Accessibility.
tell application "System Events"
perform action "AXRaise" of window (name of g_winLaunched) of process "Terminal"
end tell
activate application "Terminal"
on error
tell me to quit # Window is no longer alive, quit this app.
end try
else
# See if tab is still alive, and, if not, quit this app.
try
id of g_winLaunched
on error
tell me to quit
end try
end if
# Call this handler every N seconds.
# This is a trade-off between responsiveness and CPU usage.
# With 0.3 secs., CPU usage of this app is around 0.8%
# on my 3.2 Ghz quad-core Intel Core i5 iMac.
return 0.3
end idle

Answer 2

You can try JXcore which offers native packaging (self executables) of Node.JS apps with a single command, like:
$ jx package myapp.js MyApp -native
Then you can just run it on OSX (or other unix systems):
$./MyApp
For Windows (if you would ever need it) the file name would be MyApp.exe.
More on this here: Packaging & Code Protection.