Related
I've got the following formula that works correctly
=SUM(COUNTIFS(MachineData!N:N,{"*Arlington*","*RenewNorfolk*"}, MachineData!$X:$X,"Y"))
but now if I try to do the same but with "not arlington or not renewnorforlk" I get the wrong answer (it counts double the amount of values that I want to count)
=SUM(COUNTIFS(MachineData!N:N,{"<>*Arlington*","<>*RenewNorfolk*"}, MachineData!$X:$X,"Y"))
what is happening here?
Your first statement is equivalent to
=COUNTIFS(MachineData!N:N,"*Arlington*", MachineData!$X:$X,"Y") + COUNTIFS(MachineData!N:N,"*RenewNorfolk*", MachineData!$X:$X,"Y")
where the array constant is manually split into it two constituent parts.
If you try this with the second statement
=COUNTIFS(MachineData!N:N,"<>*Arlington*", MachineData!$X:$X,"Y") + COUNTIFS(MachineData!N:N,"<>*RenewNorfolk*", MachineData!$X:$X,"Y")
we can see that anything that isn't either Arlington or RenewNorfolk gets counted by both COUNTIFS statements, which isn't what we want the result to be.
The simplest solution is to use
=COUNTIFS(MachineData!N:N,"<>*Arlington*", MachineData!N:N,"<>*RenewNorfolk*", MachineData!$X:$X,"Y")
which requires all the criteria to be met for a data item to be counted.
I am trying to create a capacity tracker for my organisation whereby new starters are reflected at a reduced capacity throughout their induction. To do this I have an additional table next to the general capacity tracker that shows the start date vs the current date giving how many days the person has been working. This is then converted into 'months served' which is translated to a capacity adjustment. This adjustment is then used to divide their capacity by a set value per month, so 1 month served = an adjustment of 3 therefore their capacity is reduced to .3.
I am having some incorrect returns in my IF, AND statement which converts their days worked into months served. I am using the formula below, is there a better way to do this or could anyone spot the error in the formula? The first few statements are returning the correct answer but it goes wrong after 3 where the return '6+' when it should be 4.
=IF(
AJ38<30,
1,
IF(
AND(AJ38>30,AJ38<60),
2,
IF(
AND(AJ38>61,AJ38<90),
3,
IF(
AND(AJ38>91,AJ38<120),
4,
IF(
AND(AJ38>121,AJ38<150),
5,
IF(
AND(AJ38>151,AJ38<180),
6,
"6+"
)
)
)
)
)
)
I hope that makes sense, and thank you for your help!
I think I have solved this. I had not accounted for when a value returns the actual figure of say '90'. Each statement was between 2 figures and so if the figure landed on an a whole number it was not accounted for. I have adjusted the ranges to be from 1 figure down and it is now working. Working formula - =IF(AJ4<30,1,IF(AND(AJ4>29,AJ4<60),2,IF(AND(AJ4>59,AJ4<90),3,IF(AND(AJ4>89,AJ4<120),4,IF(AND(AJ4>119,AJ4<150),5,IF(AND(AJ4>149,AJ4<180),6,"6+"))))))
A few other possibilities:
Reduce the amount of layering by using IFS() instead of nested IF. Note: This works in Excel 2016 or newer.
=ifs(AJ4<30,1,
AND(AJ4>=30,AJ4<60),2,
AND(AJ4>=60,AJ4<90),3,
AND(AJ4>=90,AJ4<120),4,
AND(AJ4>=120,AJ4<150),5,
AND(AJ4>=150,AJ4<180),6,
TRUE,"6+")
Use integer division to do it mathematically.
=INT(AJ4/30)+1
If you need that "6+" in there, you'll have to use an IF statement:
=IF(AJ4<180,INT(AJ4/30)+1,"6+")
=IF(AND(A2<=20151231),(B2=0) 0, 15, IF(AND(A2>=20190101,B2>=2),15, 7.5))
This is what I entered in the function.
if A2 is less than 20151231 and B2 is equal to 0 the value will be 0.
if A2 is greater than 20190101 and B2 is equal to or greater than 2 the value will be 15.
the problem is that excel says that I entered too many arguments and when I try to derive it it says that there is something wrong with the function I entered.
Try this:
=IF(AND(A2<=20151231,B2=0),"0",IF(AND(A2>=20191010,B2>=2),15,""))
it seems your formula has too much close and open parenthesis. When using "and()" enclose all logic in one set of parenthesis.
Hope this helps. Thanks
Reymond's answer is correct, assuming that you want the result to be:
0 - if A2<=20151231 AND B2=0
15 - if A2>=20190101 AND B2>=2
7.5 - if neither of these cases are true.
If you are struggling to see what parameters you are passing to which function, I would suggest that you format your formulas so that they are easier to read:
=IF(
AND(A2<=20151231, B2=0),
0,
IF(
AND(A2>=20190101,B2>=2),
15,
7.5
)
)
This makes it much easier to see what is going on and it can even be done in the excel formula bar if you wish (by using Alt+Enter):
Im trying to nest 6 IF statements in my excel spread sheet but I get the error #NAME? which I know is most likely a syntax error.
However I cant find the syntax error. I read online that you can nest up to 7 IF statements, does this not apply to Excel 2017?
Heres my function:
=IF(AND(F2=KWILA, B14=0.14), B38, IF(AND(F2=KWILA, B14=0.9), C38, IF(AND(F2=VITEX, B14=0.9), C39, IF(AND(F2=PINE, B14=0.14), B40, IF(AND(F2=PINE, B14=0.9), C40, IF(AND(F2=MACRO, B14=0.14), B41, H2))))))
Can someone help me please?
When combining functions in a formula, start simple, with a single function. Get it working and producing the result you want before making it more complex by adding a second function (or five more).
Since your question doesn't include an example of the data you're working with, I can't be sure of the issue, but I suspect you're trying to compare the text (strings) like KWILA to the cells (like A2).
If so, the problem is that text (strings) needs to be enclosed in "Quotation Marks".
Almost every time I more than 2 nested IF's, there's usually a more efficient way to accomplish the same thing.
In this cas, I split up the formula in Notepad to see what the goal is:
=IF(
AND(F2=KWILA, B14=0.14), B38
AND(F2=KWILA, B14=0.9), C38,
AND(F2=VITEX, B14=0.9), C39,
AND(F2=PINE, B14=0.14), B40,
AND(F2=PINE, B14=0.9), C40,
AND(F2=MACRO, B14=0.14), B41,
...if none of the above: H2
I encourage you to double check your criteria above - since, at first glance, it looks like a "broken pattern". For example there are two 38's, one 39, two 40's and one 41.
Assuming it's correct, I look for anything I can group, and I see that there are only 2 options for B14. So I regroup:
=IF(B14=0.14,
IF( F2=KWILA, B38
F2=PINE, B40,
F2=MACRO, B41,
IF(B14=0.9,
IF( F2=KWILA, C38,
F2=VITEX, C39,
F2=PINE, C40,
...if none of the above: H2
I also noticed that there are only 4 options for F2, so I considered using CHOOSE instead of IF but I'm not sure how B14 relates the the rest of the data (since it wasn't posted) so we'll stick with this simplification for now.
Midway through putting it "back together" I have:
=IF(B14=0.14,
IF( F2=KWILA, B38, if( F2=PINE, B40, if( F2=MACRO, B41, h2 ))),
IF(B14=0.9,
IF( F2=KWILA, C38, if( F2=VITEX, C39, if( F2=PINE, C40, h2 )))
h2 )
basically 2 set of IF statements. Note that I used H2 three times for "else confitions" -I'm not happy with this and I can almost guarantee there's a better way, but again, without seeing your data.....
Put back into a formula, we get a slightly more manageable:
=IF(B14=0.14,IF(F2="KWILA",B38,IF(F2="PINE",B40,IF(F2="MACRO",B41,H2))),
IF(B14=0.9,IF(F2="KWILA",C38,IF(F2="VITEX",C39,IF(F2="PINE",C40,H2))),H2))
I can't guarantee this will work since I wasn't able to test it, since... no data included in the question. You don't need to switch to this if your method works after adding the quotes.
There are still other alternate way this could have been simplified (and easier to understand or change later) which I won't get into now. Personally, I would have put the values in a table on another worksheet, and used INXDEX/MATCH to get the values I needed.
-
I have an interesting challenge - I need to run a check on the following data in Excel:
| A - B - C - D |
|------|------|------|------|
| 36 | 0 | 0 | x |
| 0 | 600 | 700 | x |
|___________________________|
You'll have to excuse my wonderfully bad ASCII art. So I need the D column (x) to run a check against the adjacent cells, then convert the values if necessary. Here's the criteria:
If column B is greater than 0, everything works great and I can get coffee. If it doesn't meet that requirement, then I need to convert A1 according to a table - for example, 32 = 1420 and place into D. Unfortunately, there is no relationship between A and what it needs to convert to, so creating a calculation is out of the question.
A case or switch statement would be perfect in this scenario, but I don't think it is a native function in Excel. I also think it would be kind of crazy to chain a bunch of =IF() statements together, which I did about four times before deciding it was a bad idea (story of my life).
Sounds like a job for VLOOKUP!
You can put your 32 -> 1420 type mappings in a couple of columns somewhere, then use the VLOOKUP function to perform the lookup.
Without reference to the original problem (which I suspect is long since solved), I very recently discovered a neat trick that makes the Choose function work exactly like a select case statement without any need to modify data. There's only one catch: only one of your choose conditions can be true at any one time.
The syntax is as follows:
CHOOSE(
(1 * (CONDITION_1)) + (2 * (CONDITION_2)) + ... + (N * (CONDITION_N)),
RESULT_1, RESULT_2, ... , RESULT_N
)
On the assumption that only one of the conditions 1 to N will be true, everything else is 0, meaning the numeric value will correspond to the appropriate result.
If you are not 100% certain that all conditions are mutually exclusive, you might prefer something like:
CHOOSE(
(1 * TEST1) + (2 * TEST2) + (4 * TEST3) + (8 * TEST4) ... (2^N * TESTN)
OUT1, OUT2, , OUT3, , , , OUT4 , , <LOTS OF COMMAS> , OUT5
)
That said, if Excel has an upper limit on the number of arguments a function can take, you'd hit it pretty quickly.
Honestly, can't believe it's taken me years to work it out, but I haven't seen it before, so figured I'd leave it here to help others.
EDIT: Per comment below from #aTrusty:
Silly numbers of commas can be eliminated (and as a result, the choose statement would work for up to 254 cases) by using a formula of the following form:
CHOOSE(
1 + LOG(1 + (2*TEST1) + (4*TEST2) + (8*TEST3) + (16*TEST4),2),
OTHERWISE, RESULT1, RESULT2, RESULT3, RESULT4
)
Note the second argument to the LOG clause, which puts it in base 2 and makes the whole thing work.
Edit: Per David's answer, there's now an actual switch statement if you're lucky enough to be working on office 2016. Aside from difficulty in reading, this also means you get the efficiency of switch, not just the behaviour!
The Switch function is now available, in Excel 2016 / Office 365
SWITCH(expression, value1, result1, [default or value2, result2],…[default or value3, result3])
example:
=SWITCH(A1,0,"FALSE",-1,"TRUE","Maybe")
Microsoft -Office Support
Note: MS has updated that page to only document the behavior of Excel 2019. Eventually, they will probably remove references to 2019 as well... To see what the page looked like in 2016, use the wayback machine:
https://web.archive.org/web/20161010180642/https://support.office.com/en-us/article/SWITCH-function-47ab33c0-28ce-4530-8a45-d532ec4aa25e
Try this;
=IF(B1>=0, B1, OFFSET($X$1, MATCH(B1, $X:$X, Z) - 1, Y)
WHERE
X = The columns you are indexing into
Y = The number of columns to the left (-Y) or right (Y) of the indexed column to get the value you are looking for
Z = 0 if exact-match (if you want to handle errors)
I used this solution to convert single letter color codes into their descriptions:
=CHOOSE(FIND(H5,"GYR"),"Good","OK","Bad")
You basically look up the element you're trying to decode in the array, then use CHOOSE() to pick the associated item. It's a little more compact than building a table for VLOOKUP().
I know it a little late to answer but I think this short video will help you a lot.
http://www.xlninja.com/2012/07/25/excel-choose-function-explained/
Essentially it is using the choose function. He explains it very well in the video so I'll let do it instead of typing 20 pages.
Another video of his explains how to use data validation to populate a drop down which you can select from a limited range.
http://www.xlninja.com/2012/08/13/excel-data-validation-using-dependent-lists/
You could combine the two and use the value in the drop down as your index to the choose function. While he did not show how to combine them, I'm sure you could figure it out as his videos are good. If you have trouble, let me know and I'll update my answer to show you.
I understand that this is a response to an old post-
I like the If() function combined with Index()/Match():
=IF(B2>0,"x",INDEX($H$2:$I$9,MATCH(A2,$H$2:$H$9,0),2))
The if function compare what is in column b and if it is greater than 0, it returns x, if not it uses the array (table of information) identified by the Index() function and selected by Match() to return the value that a corresponds to.
The Index array has the absolute location set $H$2:$I$9 (the dollar signs) so that the place it points to will not change as the formula is copied. The row with the value that you want returned is identified by the Match() function. Match() has the added value of not needing a sorted list to look through that Vlookup() requires. Match() can find the value with a value: 1 less than, 0 exact, -1 greater than. I put a zero in after the absolute Match() array $H$2:$H$9 to find the exact match. For the column that value of the Index() array that one would like returned is entered. I entered a 2 because in my array the return value was in the second column. Below my index array looked like this:
32 1420
36 1650
40 1790
44 1860
55 2010
The value in your 'a' column to search for in the list is in the first column in my example and the corresponding value that is to be return is to the right. The look up/reference table can be on any tab in the work book - or even in another file. -Book2 is the file name, and Sheet2 is the 'other tab' name.
=IF(B2>0,"x",INDEX([Book2]Sheet2!$A$1:$B$8,MATCH(A2,[Book2]Sheet2!$A$1:$A$8,0),2))
If you do not want x return when the value of b is greater than zero delete the x for a 'blank'/null equivalent or maybe put a 0 - not sure what you would want there.
Below is beginning of the function with the x deleted.
=IF(B2>0,"",INDEX...
If you don't have a SWITCH statement in your Excel version (pre-Excel-2016), here's a VBA implementation for it:
Public Function SWITCH(ParamArray args() As Variant) As Variant
Dim i As Integer
Dim val As Variant
Dim tmp As Variant
If ((UBound(args) - LBound(args)) = 0) Or (((UBound(args) - LBound(args)) Mod 2 = 0)) Then
Error 450 'Invalid arguments
Else
val = args(LBound(args))
i = LBound(args) + 1
tmp = args(UBound(args))
While (i < UBound(args))
If val = args(i) Then
tmp = args(i + 1)
End If
i = i + 2
Wend
End If
SWITCH = tmp
End Function
It works exactly like expected, a drop-in replacement for example for Google Spreadsheet's SWITCH function.
Syntax:
=SWITCH(selector; [keyN; valueN;] ... defaultvalue)
where
selector is any expression that is compared to keys
key1, key2, ... are expressions that are compared to the selector
value1, value2, ... are values that are selected if the selector equals to the corresponding key (only)
defaultvalue is used if no key matches the selector
Examples:
=SWITCH("a";"?") returns "?"
=SWITCH("a";"a";"1";"?") returns "1"
=SWITCH("x";"a";"1";"?") returns "?"
=SWITCH("b";"a";"1";"b";TRUE;"?") returns TRUE
=SWITCH(7;7;1;7;2;0) returns 2
=SWITCH("a";"a";"1") returns #VALUE!
To use it, open your Excel, go to Develpment tools tab, click Visual Basic, rightclick on ThisWorkbook, choose Insert, then Module, finally copy the code into the editor. You have to save as a macro-friendly Excel workbook (xlsm).
Even if old, this seems to be a popular questions, so I'll post another solution, which I think is very elegant:
http://fiveminutelessons.com/learn-microsoft-excel/using-multiple-if-statements-excel
It's elegant because it uses just the IF function. Basically, it boils down to this:
if(condition, choose/use a value from the table, if(condition, choose/use another value from the table...
And so on
Works beautifully, even better than HLOOKUP or VLOOOKUP
but... Be warned - there is a limit to the number of nested if statements excel can handle.
Microsoft replace SWITCH, IFS and IFVALUES with CHOOSE only function.
=CHOOSE($L$1,"index_1","Index_2","Index_3")
Recently I unfortunately had to work with Excel 2010 again for a while and I missed the SWITCH function a lot. I came up with the following to try to minimize my pain:
=CHOOSE(SUM((A1={"a";"b";"c"})*ROW(INDIRECT(1&":"&3))),1,2,3)
CTRL+SHIFT+ENTER
where A1 is where your condition lies (it could be a formula, whatever). The good thing is that we just have to provide the condition once (just like SWITCH) and the cases (in this example: a,b,c) and results (in this example: 1,2,3) are ordered, which makes it easy to reason about.
Here is how it works:
Cond={"c1";"c2";...;"cn"} returns a N-vector of TRUE or FALSE (with behaves like 1s and 0s)
ROW(INDIRECT(1&":"&n)) returns a N-vector of ordered numbers: 1;2;3;...;n
The multiplication of both vectors will return lots of zeros and a number (position) where the condition was matched
SUM just transforms this vector with zeros and a position into just a single number, which CHOOSE then can use
If you want to add another condition, just remember to increment the last number inside INDIRECT
If you want an ELSE case, just wrap it inside an IFERROR formula
The formula will not behave properly if you provide the same condition more than once, but I guess nobody would want to do that anyway
If your using Office 2016 or later, or Office 365, there is a new function that acts similarly to a CASE function called IFS. Here's the description of the function from Microsoft's documentation:
The IFS function checks whether one or more conditions are met, and returns a value that corresponds to the first TRUE condition. IFS can take the place of multiple nested IF statements, and is much easier to read with multiple conditions.
An example of usage follows:
=IFS(A2>89,"A",A2>79,"B",A2>69,"C",A2>59,"D",TRUE,"F")
You can even specify a default result:
To specify a default result, enter TRUE for your final logical_test argument. If none of the other conditions are met, the corresponding value will be returned.
The default result feature is included in the example shown above.
You can read more about it on Microsoft's Support Documentation