Working on a timesheet (duplicate of sheet 1 in link).
The current function to handle the calculations is:
B4=6:00am
C4=6:00pm
X4=0:30:00
=IF(OR(B4="",C4=""),"",IFERROR(C4-B4-X4,""))
The thing is we don't subtract 30 minutes for lunch unless an employee works longer than 6 hours and 15 minutes.
How can I fix my function to only subtract 30 mins for lunch if the total time for that day is over 6 hours and 15 mins?
Provided there is no risk of times spanning midnight, please try:
=IF(OR(B4="",C4=""),"",IF(C4-B4>6.25/24,C4-B4-X4,C4-B4))
Related
I have a issue with my excel project. What I want to do is to divide number of working hours to cells when particular person has a working day. Right now I use QUOTIENT formula with combination with others but the problem is I'm not getting the right split of the total. So set up looks like that
Number of hours = 72
Number of Working days = 7
So I need to divide 72/7 but I need to have the result rounded to full figure (hour). So for example I need day 1 = 10h day 2=12h and day 3 to 7 each = 10h. The QUOTIENT is resulting 10h in every single day giving me result of total 70 not 72.
The problem is that the variables will change when the employee will be switched so for example the next employee will have 94 hours and 11 days. Generally its look like that that I have range of full month so from 1 to 31 and the working days are collected from "working schedule". The idea is to sum up the hours to a month normative working hours. So for example employee has 104 hours and he is working 12 days in working schedule but the monthly norm is 176 so we have 72 hours missing and those hours should be added to those days that he is working.
Example.
You can use MOD function to calculate the remainder.
so day 1 and 3 to 7 should have =quotient(72,7)
and day 2 should have =quotient(72,7)+mod(72,7)
I suppose from your question that you want the remaining hours to be added to day 2.
Let's say i logged in today 9:00 AM and end up 5:00 PM i have to produce 4000 items i know it will exceed the time because my software will stop working at 5 PM so tomorrow when i start working again what would be date and time of completion work
What i did
bring working hour =SUM(B2-A2)
total complete work=ROUND(D2/C2, 2)
If i understood correctly you can use the simple difference of times and correct formatting for the time cells to get the remaining hours
The Formula in cell C5 is simple =C1-C3
The formatting applied to the cells is as below
10.95 hours is equal to 10 hours and 57 (95% of 60) minutes
You can write 10:57:00 instead of 10.95
To convert the time to again a number you can divide the time by 0.041666667 and set the format to general
I am trying to have a cell which has a given number of hours and minutes allocated and then add events which deduct from that time and show the total hours and minutes left. For example if I had 240 hours & 40 minutes and took 40 minute appointment and another 36 minute appointment I should be left with 239 hours and 24 minutes. But I am doing something wrong with my excel formula, is there another better way of doing this?
Try something like this
=E3-SUM(E4:E11)
You also need to list your times as hh:mm:ss
E4 should be 00:40:00, E5 should be 00:36:00. They way you have them, it looks
like 40 seconds and 36 seconds (depending on formatting)
Also note that working with days you must multiply by 24 and hours multiply by 60
I have a spreadsheet column with durations of hours, minutes, and seconds. For example, 0:01:00 is 1 minute. 1:06:28 is 1 hour, 6 minutes, and 28 seconds.
I'm trying to convert this data into increments of 10% of an hour (6 minutes). So, 0:00:01 (a second) would be converted to 0.1. 0:06:00 (6 minutes) would also be 0.1. 1:12:01 (1 hour, 12 minutes and 1 second) would be 1.3.
Any ideas on how to handle this in Excel (or Google Sheets)? Thanks very much.
The formula is:
=ROUNDUP(A1*24, 1)
Intervals (time) in Excel are stored as fractions of a 24 hour day, so converting the day fraction to an hour fraction just means multiplying by 24.
=ROUNDUP(A1*24, 1) won't work in OpenOffice Calc nor in some configurations of Google Sheets and Excel, but
=ROUNDUP(A1*24;1)
will (in OpenOffice Calc and some configurations of Google Sheets and Excel).
This one's confusing, I have a user who has requested an excel sheet that allows them to enter a time in minutes into cell A1 that will calculate a value to charge another company in cell C1. However the charging criteria is as follows:
£355.68 for the first hour,
£88.92 for every 15 minutes after that
AND if during one of those 15 minute increments the time goes over 7 minutes, it gets rounded up to a full 15 minutes or down if it's under 7 minutes. I have literally no idea where to even begin on this one.
Assuming the value in A1 is simply a number of minutes and the charge is £355.68 for any time between 1 and 60 minutes, I think the following should work:
=355.68+IF(A1>60,88.92*(FLOOR((A1-60)/15,1)+IF(A1-60-15*FLOOR((A1-60)/15,1)>7,1,0)),0)
Explanation:
We start with the base cost of £355.68. The use of FLOOR((A1-60)/15,1) gives us the number of completed 15 minute intervals we have after the first hour. We initially multiply this by £88.92, and then we check how many minutes are left over once we take into account the first hour and any completed 15 minute period - A1-60-15*FLOOR((A1-60)/15,1). If this is greater than 7, we add an extra £88.92 for the "partial completion".
To round to the "closest" 15 minute interval, where the "split" occurs at 7 minutes, and you are entering your time as "Excel Minutes" (e.g. the difference between a starting and ending time in minutes, or entered as, for example 00:42, just add a bit less than 30 seconds to the time (e.g. 29 seconds), and then round to the nearest 15 minutes.
e.g: (one of the below)
=MROUND(A1+TIME(0,0,29),TIME(0,15,0))
=MROUND(A1+29/86400,15/1440)
or, using ROUND
=ROUND((A1+TIME(0,0,29))/TIME(0,15,0),0)*TIME(0,15,0)
=ROUND((A1+29/86400)/15*1440,0)*15/1440
You should be able to work out the rest. If you can't, post what you have tried and where you are running into problems.