Excel pivot connection renamed to "Connection" in VBA - excel

Question

I have been battling with this issue for a couple of days and read a lot of posts about renaming connections and still cannot achieve what I need to.
Essentially I have a workbook that has multiple sheets each with a different pivot table using a different connection.
I need to use VBA to insert date range criteria from a "Control" tab into the sql statement of each connection because as we all know pivots can't use the ? parameter.
However, as we also know, Excel renames the connection when you modify it, so changing the command text with VBA ends up creating new connections and leaving redundant ones.
Using some other very useful posts in this forum I have successfully managed to
- change the command text
- delete the old connection and rename the new one assuming its name to be "Connection"
thus:
text = "... new SQL query here..."
ActiveWorkbook.Connections("GLCosts").ODBCConnection.CommandText = text
' assume excel has renamed the "GLCosts" connection to "Connection"
ActiveWorkbook.Connections("Connection").Refresh
' delete the original and rename the new one to the old name
ActiveWorkbook.Connections("GLCosts").Delete
ActiveWorkbook.Connections("Connection").name = "GLCosts"
As long as each Sub() does this in turn then it should be fine as the "new" connection name will always be "Connection" (i.e. not "Connection1" etc)
HOWEVER
What I have found is that Excel only renames the connection IF THERE IS A CHANGE TO THE COMMAND.TEXT
Therefore, if the user doesn't actually change the date criteria values (held in Sheets("Control").Range("D4")) but DOES run the macro to refresh the pivots then the macro fails because the command text hasn't been modified, and there's no new connection string to rename as the old name.
So....
I tried to be clever. In each Sub() I first set text = "... a valid sql query but not the one i want...", then replace the command.text of the connection with this dummy query thus forcing excel to create a new connection which I can rename. Then when i set text = "...the correct sql query" excel will again create a new connection called "Connection" and I can repeat the renaming and deleting steps.
This should have been fine but for some reason it just crashed excel and I haven't tried it again
Does anyone have an actual solution to this? Should I try the clever stuff bit again?
Any ideas gratefully received

Answer 1

I have also encountered this bug when updating the CommandText property of an ODBC connection. I found that if you temporarily switch to an OLEDB connection, update your CommandText property and then switch back to ODBC it does not create the new connection. Don't ask me why... this just works for me.
Create a new module and insert the following code:
Option Explicit
Sub UpdateWorkbookConnection(WorkbookConnectionObject As WorkbookConnection, Optional ByVal CommandText As String = "", Optional ByVal ConnectionString As String = "")
With WorkbookConnectionObject
If .Type = xlConnectionTypeODBC Then
If CommandText = "" Then CommandText = .ODBCConnection.CommandText
If ConnectionString = "" Then ConnectionString = .ODBCConnection.Connection
.ODBCConnection.Connection = Replace(.ODBCConnection.Connection, "ODBC;", "OLEDB;", 1, 1, vbTextCompare)
ElseIf .Type = xlConnectionTypeOLEDB Then
If CommandText = "" Then CommandText = .OLEDBConnection.CommandText
If ConnectionString = "" Then ConnectionString = .OLEDBConnection.Connection
Else
MsgBox "Invalid connection object sent to UpdateWorkbookConnection function!", vbCritical, "Update Error"
Exit Sub
End If
If StrComp(.OLEDBConnection.CommandText, CommandText, vbTextCompare) <> 0 Then
.OLEDBConnection.CommandText = CommandText
End If
If StrComp(.OLEDBConnection.Connection, ConnectionString, vbTextCompare) <> 0 Then
.OLEDBConnection.Connection = ConnectionString
End If
.Refresh
End With
End Sub
This UpdateWorkbookConnection subroutine only works on updating OLEDB or ODBC connections. The connection does not necessarily have to be linked to a pivot table. It also fixes another problem and allows you to update the connection even if there are multiple pivot tables based on the same connection.
To initiate the update just call the function with the connection object and command text parameters like this:
UpdateWorkbookConnection ActiveWorkbook.Connections("Connection"), "exec sp_MyAwesomeProcedure"
You can optionally update the connection string as well.

Answer 2

Here's what I do, which doesn't rely on hard-coded references, to manage the annoying process of programmatically updating the pivotCache in Excel.
First, before you have VBA alter your existing Pivot Cache/Connections, declare a string variable (currentPvtConn) in your code and set value to the current Pivot Cache name for the Pivot you intend to refresh. Also, delcare a second string variable (newPvtConn) to hold the name of the new connection Excel will undoubtedly generate...
Dim currentPvtConn As String
Dim newPvtConn As String
currentPvtConn = ActiveSheet.PivotTables("pvtUser").PivotCache.WorkbookConnection
...Now place your code to modify the CommandText...
After the refresh commands execute, Excel will create that dastardly new connection named "Connection#" and you'll be left with the old, untouched one as well. To clean up this mess, we'll need to capture the newly created connection name and store in the newPvtConnection variable we created earlier...
newPvtConn = ActiveSheet.PivotTables("pvtUser").PivotCache.WorkbookConnection
Since you now have both names stored as local variables, you can actually comare the two strings and
Finally, delete the orignal connection and rename the newly-created one. IF statement ensures a new connection was acually created before deleting/renaming anything.
If (StrComp(currentPvtConn, newPvtConn) <> 0) Then
ActiveWorkbook.Connections(currentPvtConn).Delete
ActiveWorkbook.Connections(newPvtConn).Name = "[My Original Connection Name]"
End If
... put rest of code
I'm exactly not sure why yours is crashing. I did find an obscure reference/solution to a problem where the following occurs:
Create Excel file with parameterized queries that load directly to Pivot Cache (i.e. using parameters in the command text "?")
Save beatufully-crafted file and close
Re-open and try to refresh
Excel crashes hard and closes; no chance of "repairing"
/***
Apparently, parameters aren't supported in Pivots. The problem lies in the parameter cells in a spreadsheet. Actually, when you close the file, query "forgets" what the parameter cells are, and uses blanks instead. That is why Excel crashes. I guess this is caused by the fact that pivot tables "can not be used" against parameter queries. However... Here is my workaround: no additional table necessary - only pivot table.
Create common query first (no parameters.)
Create pivot table based on query results.
Change query to parameter query.
Before refreshing data in Excel do not select cell values as parameters.
Instead, use prompt: Connection Properties=> Parameters=> "Prompt for value using following string:".
So, when you click "Refresh" on your pivot table, you will be prompted to enter parameters.
I know it is not as elegant as referring to a cell, but in this way Excel will not crash. Besides, you will not have to refresh both result and pivot table, but only pivot table.
Source MSDN: (bottom-of-page comment)
***/

Answer 3

I have also encountered this problem. I know the thread is old but I thought I'd share a workaround anyway.
I am using Excel 2013 (although it may also work in earlier versions), and discovered that when changing the ODBCconnection.commandtext in VBA I get the same effect, where a new connection called 'Connection' is created with the old command text and is linked to the pivot table. But the original connection has the new command text however it's not connected to the pivot any more.
If the connection you want to change in VBA is linked to an excel table rather than a pivot table, I found that the new 'connection' is not created, and instead the original connection is changed by the code yet remains linked to the table.
So I created a connection linked to an excel table on a hidden worksheet, then used this table as the source of the pivot table.
I hope this helps someone, as I was scratching my head over this for days.