Haskell - count most repeated element in a list with interact - haskell

Question

I'm trying to make a Haskell program using interact, that returns the most used word and the # of times it appears. I've seen examples with sort- but I don't need to know the counts for all words, I only need the most repeated word. So far I have:
import Data.List -- (sort)
import Data.Char -- (isAlpha, toLower)
import Data.Ord -- (maximumBy)
main =
interact
$ unwords
-- comment: here show the size of the list and the word (probably head)
. maximumBy(comparing length)
. group
. sort
. words
. map (\char -> if isAlpha char then toLower char else ' ')
The above compiles. maximumBy gives the most used word like this:
[the, the, the, the, the, the, the, the...]
for the number of times the word "the" appears in the text; and I have verified that "the" is the most used word for the text I've supplied.
What I want to output is something like this: "the, 318"
I tried the following which only gives the first letter "t" and 3:
import Data.List -- sort
import Data.Char -- isAlpha, toLower
import Data.Ord -- maximumBy
main =
interact
$ unwords
. map (\(n, w) -> show n ++ ", " ++ show w)
. map (\s -> (length s, head s))
. maximumBy(comparing length)
. group
. sort
. words
. map (\char -> if isAlpha char then toLower char else ' ')
Which gives the output:
"3, 't' 3, 't' 3, 't' 3, 't' ..."
Anyone know what I'm doing wrong?

Answer 1

The map in map (\s -> (length s, head s)) means that the function \s -> (length s, head s) is applied to each "the" instead of to the list of "the"'s, repeatedly giving the length and the first character of "the". So removing the map should work better. You will also need to fix up the final two steps (remove the unwords and the map):
$ (\(n, w) -> show n ++ ", " ++ show w)
. (\s -> (length s, head s))
. maximumBy(comparing length)
More efficiently, you can apply map (\s -> (length s, head s)) earlier in the pipeline than the maximum, which allows you to
Avoid recomputing the length in each comparison the maximum function does
Use just plain maximum instead of maximumBy. (This may be slightly different in which word is chosen if there are two equally frequent ones, since it then compares the actual strings.)
In other words, you can use
$ (\(n, w) -> show n ++ ", " ++ show w)
. maximum
. map (\s -> (length s, head s))
Or to put it all together:
import Data.List (group, sort)
import Data.Char (isAlpha, toLower)
main =
interact
$ (\(n, w) -> show n ++ ", " ++ show w)
. maximum
. map (\s -> (length s, head s))
. group
. sort
. words
. map (\char -> if isAlpha char then toLower char else ' ')
Note also how I changed the import statements to use the official syntax for explicitly naming what you are importing. I'd strongly recommend that over using comments, as this actually gave me error messages pointing out one function (group) you had missed and one (maximumBy) you had listed with the wrong module.