I have an Excel table with my banks account like this
A B C E
1 Currency Percent Value Banks Account
2 USD 5 100 8923781
3 Eur 7 200 Ea84382
4 USD 6 900 PayY8908
So I need to calculate how much USD I will earn in current month from all deposits (Value) if we know interest rate's (Percent) for each of bank's acoounts.
For first account the formula will be =C2/100*B2/12 and for second =C4/100*B4/12
The problem that I don't understand how to automatically filter only USD accounts (SUMIF???). And I can't figure out how to do this using only one cell.
You could use SUMIF, if you would use a helper Column:
A B C D E
1 Currency Percent Value Banks Account Monthly earned
2 USD 5 100 8923781 0,416666667
3 Eur 7 200 Ea84382 1,166666667
4 USD 6 900 PayY8908 4,5
Formula in E2:
=C2/100*B2/12
fill down.
Now you could have:
=SUMIF($A$2:$A$10,"USD",$E$2:$E$10)
to sum the USD.
Or, without helper Column, you could use the "swiss army knife" SUMPRODUCT:
=SUMPRODUCT(($A$2:$A$10="USD")*($C$2:$C$10/100*$B$2:$B$10/12))
Greetings
Axel
Related
This is what I tried.
For below table
A B C
1 Expenses Cost Status
2 Expense1 30000 PAID
3 Expense2 20000
4 Expense3 7500
5 Expense4 520
6 Expense5 2300
7 Expense6 1000
8 Expense7 11618
9 Expense8 7939
10 Expense9 6473
11 Total 87350
12 **Remaining Amount ??**
if a column C cell has "PAID", then Substract Total amount(B11) from the PAID(B2) amount.
=IF(C2:C10="PAID",MINUS(B11,B2:B10),B11)
But this code only subtracts the first PAID amount, do not consider for other cells with PAID
Hoping for help!
You can use the formula SUMIF in it.
Considering that the Total is on column B11 and the Remaining would be on column B12, you can use the formula on B12:
=B11-(SUMIF(C2:C10, "PAID", B2:B10))
The number on the remaining will be going down after each expense gets paid.
I have a tiered commission rate based on the number of sales that I cribbed from a couple of Excel Formulas:
Min Max Payout Differential
1 5 $3.00 $3.00
5 $4.00 $1.00
Starts at A1 and ends at D3. Sheet is named Tiered Bonus
On another sheet I have the following program referencing Tiered (row 2):
=IF(ISBLANK($A2),"",SUMPRODUCT(--($K2>'Tiered Bonus'!$A$2:$A$3),--($K2-'Tiered Bonus'!$A$2:$A$3),'Tiered Bonus'!$D$2:$D$3))
Putting 5 in sales, however, yields only $12 when it should yield $16 (4*3)+(1*4). I know there's something obvious that I am missing but I can't see it
First, make sure that A1:D3 is set up this way...
Min Max Payout Differential
0 5 $3.00 $3.00
4 $4.00 $1.00
Then, with K2 containing 5, the following formula will return 16...
=SUMPRODUCT(--($K2>$A$2:$A$3),--($K2-$A$2:$A$3),$D$2:$D$3)
Note that the calculation takes place this way...
(5 - 0) x 3 = 5 x 3 = 15 '$3.00 for anything over 0
(5 - 4) X 1 = 1 x 1 = 1 '$1.00 for anything over 4
Hope this helps!
I have a column "Uni"
E.g.
Person Uni Round 1 Round 2 Total Rank
Leia Notts 5 5 10
Hailey Notts 6 5 11
Bobby Bath 8 1 9
James Liverpool 9 1 10
Then another table:
University Total Score Rank
Notts =sum(vlookup(...))
Bath =sum(vlookup(...))
Currently, my formula returns the 'first' lookup of the keyword - e.g. for notts, it returns '10' - rather than looking up the 10 and the 11 and summing them.
How do I make it lookup and sum both values?
My current formula is =sum(vlookup(S7,B$3:Q$40,15,FALSE)) where S7 is "Notts", range, index column 15 is "total score"
There's about 8-10 of each university.
Vlookup only returns one value, you can't sum over that.
Maybe use instead something like
=SUMIF(B$3:B$40,S7,$P3:$P40)
I have a data which looks like below.
ID Date Currency
1 9/29/2015 INR
1 10/28/2015 INR
1 10/29/2015 INR
1 11/8/2015 EUR
1 11/11/2015 EUR
1 11/23/2015 EUR
1 11/24/2015 EUR
1 11/25/2015 INR
1 11/27/2015 EUR
1 12/1/2015 EUR
1 12/2/2015 CEZ
1 12/3/2015 CEZ
1 12/15/2015 CEZ
1 12/18/2015 INR
1 12/29/2015 INR
I want to calculate the difference between the date when the given the currency is same. For example, the first three are of same currency and therefor the difference will be calculated for the date 1 and date 3. Similarly, for rest of the rows I need to calculate. Precisely, the output looks like below.
ID Date Date2 Currency Difference
1 9/29/2015 10/29/2015 INR 30
1 11/8/2015 11/24/2015 EUR 16
1 11/25/2015 11/25/2015 INR 0
1 11/27/2015 12/1/2015 EUR 4
1 12/2/2015 12/15/2015 CEZ 13
1 12/18/2015 12/29/2015 INR 11
I really appreciate if someone helps me to achieve this using excel
Assuming the three columns are placed in column A, B and C and you start in row 1, then you can append two additional columns.
Cell D2, pull formula down:
=IF(C2=C1,D1,B2)
Cell E2, pull formula down:
=IF(C2=C3,"",B2-D2)
Column E now contains the desired result. For convenience, you can place a filter on the table to filter out the empty values in that column.
Hi I have encountered a problem and I do not know how to solve:
Clients deposited in four types of currencies: SGD, EUR, HKD and USD. I need to find out the amount to be credited to them (Column D).
The credit condition are:
If they deposit less or equal to USD2000, they are credited with 15% of their deposit.
If they deposit more than USD2000, their credit will be capped at USD300.
For currencies other than USD, I have to do a conversion, and the conversion table is below for your reference. It is based on USD2000 deposit for USD300 credit.
Sample data:
A B C D
1 Currency Initial Deposit Credit Amount
2 SGD 2650 (Should be G2, since C2>f3)
3 EUR 3000 (Should be G4, since C3>f4)
4 HKD 200 (Should be C4*0.15, since C4<f5)
5 USD 790 (Should be C5*0.15)
Conversion table:
E F G
1 Currency Deposit Credit
2 USD 2000 300
3 SGD 2540 381
4 EUR 1580 237
5 HKD 15520 2328
I do not want to use filter as the list is continuously expanding at the moment. Any one can help? Thank you in advance!
Since the credits are in the deposited currency, a simple VLOOKUP to determine the maximum credit is all you need:
=MIN(15%*B2,VLOOKUP(A2,ConversionTbl,3,FALSE))