Delete Rows - code does works, but not within existing macro - excel

Question

I'm trying to use the following code to delete empty rows in a worksheet.
Columns("E:E").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
It works perfectly as a standalone, but when I try to use it in a larger marco, it fails. Here is the full code:
Sub liquidVolume()
Dim dateTime As String
Dim MyPath As String
MyPath = ThisWorkbook.Path
Sheets("Volume").Select
dateTime = Range("i1")
Sheets("Volume").Select
Range("A1:E10000").Select
Selection.Copy
Workbooks.Add
Selection.PasteSpecial Paste:=xlPasteValues
Columns("B:B").Select
Selection.NumberFormat = "dd/mm/yyyy h:mm"
**Columns("E:E").SpecialCells(xlCellTypeBlanks).EntireRow.Delete**
ActiveWorkbook.SaveAs Filename:=MyPath & dateTime, FileFormat:=xlCSV
End Sub
All the code really does is take a worksheet in one workbook, copy the contents into a new workbook's worksheet and formats the date. However, I can't for the life of me figure out how to get the little snippet of code that deletes the row to work.

Answer 1

Try this one for size. It is not efficient and it only works from version 2010 and newer.
Option Explicit
Public Sub liquidVolume()
Dim dateTime As String
Dim MyPath As String
Dim shtSource As Worksheet
Dim shtTarget As Worksheet
Dim rngSource As Range
Dim rngTarget As Range
Dim wb As Workbook
MyPath = ThisWorkbook.Path
dateTime = Range("i1")
Set shtSource = ThisWorkbook.Sheets("volume")
Set rngSource = shtSource.Range("A1:E10000")
Set wb = Workbooks.Add
Set shtTarget = wb.Sheets(1)
Set rngTarget = shtTarget.Range("A1:E10000")
rngSource.Copy
rngTarget.PasteSpecial Paste:=xlPasteValues
shtTarget.Columns("B").NumberFormat = "dd/mm/yyyy h:mm"
' Set rngTarget = shtTarget.Columns("E:E").SpecialCells(xlCellTypeBlanks)
Set rngTarget = EmptyCells(shtTarget.Columns("E:E"))
If Not rngTarget Is Nothing Then
rngTarget.EntireRow.Delete
End If
'wb.SaveAs Filename:=MyPath & dateTime, FileFormat:=xlCSV
End Sub
Public Function EmptyCells(ByVal rngColumn As Range) As Range
Dim shtSheet As Worksheet
Dim lngLastRow As Long
Dim lngRow As Long
Dim rngEmptyCells As Range
Dim intColumn As Integer
'Determine the sheet the column belongs to
Set shtSheet = rngColumn.Parent
'Determine last used row
lngLastRow = shtSheet.UsedRange.Rows(1).Row + shtSheet.UsedRange.Rows.Count - 1
'Determine column
intColumn = rngColumn.Columns(1).Column
'Determine range with empty cells.
Set rngEmptyCells = Nothing
For lngRow = 1 To lngLastRow
If Len(Trim(shtSheet.Cells(lngRow, intColumn))) = 0 Then
If rngEmptyCells Is Nothing Then
Set rngEmptyCells = shtSheet.Cells(lngRow, intColumn)
Else
Set rngEmptyCells = Union(rngEmptyCells, shtSheet.Cells(lngRow, intColumn))
End If
End If
Next lngRow
Set EmptyCells = rngEmptyCells
End Function

Answer 2

While I was not able to actually delete rows and would like to further understand why formulas are interfering with the deletion of blank rows, I was able to remove the blank rows by sorting the data so that the blank rows are moved to the bottom of the sheet.