Simplify Multiple COUNTIFS Used for Search in Excel 2010 - excel

Question

Introduction:
I have an Excel workbook I'm using to track stats for the game Hearthstone. One sheet contains the data of each individual game (wins losses, etc.). The other sheet allows the user to search for win/loss statistics based on user input search criteria.
My Question:
In the search sheet I am using COUNTIFS formulas. These formulas are getting rather long. Is there any way to simplify the COUNTIFS formulas?
The Setup: How the Excel Search Sheet Looks:
| Column K | Column L |
|____________________|______________________________|
Row 5 |Date Start | User input goes in Column L |
Row 6 |Date End | |
Row 7 |Player's Class | |
... |Turn Number | |
|Deck Name | |
|Opponent's Class | |
|Opponent's Username | |
|Match Type 1 | |
|Match Type 2 | |
|Match Type 3 | |
|Match Type 4 | |
... |Match Type 5 | |
Row 17 |Match Type 6 | |
|____________________|______________________________|
| Column K | Column L |
|______________________|_______________________________________________|
Row 21 | Total Matches Played | Data is displayed based on the user's input. |
Row 22 | Total Wins | The code that needs simplifying is goes here. |
Row 23 | Total Losses | |
Row 24 | Win to Loss Ratio | |
Row 25 | Win Percentage | |
Row 26 | Loss Percentage | |
|______________________|_______________________________________________|
The code that needs simplifying. This Code goes in Row 22 Column L:
=(COUNTIFS('Indiv. Match Stats'!I:I,"Win",'Indiv. Match Stats'!H:H,L12,
'Indiv. Match Stats'!L:L,L7,'Indiv. Match Stats'!T:T,L9,'Indiv. Match
Stats'!Q:Q,L10,'Indiv. Match Stats'!P:P,L11,'Indiv. Match Stats'!C:C,
">="&L5,'Indiv. Match Stats'!C:C,"<="&L6,'Indiv. Match Stats'!N:N,L8))
+
(COUNTIFS('Indiv. Match Stats'!I:I,"Win",'Indiv. Match Stats'!H:H,L13,
'Indiv. Match Stats'!L:L,L7,'Indiv. Match Stats'!T:T,L9,'Indiv. Match
Stats'!Q:Q,L10,'Indiv. Match Stats'!P:P,L11,'Indiv. Match Stats'!C:C,
">="&L5,'Indiv. Match Stats'!C:C,"<="&L6,'Indiv. Match Stats'!N:N,L8))
+
(The code repeats the above four more times. Basically each block of code
stands for one Match Type in Column K)
Explanation of Worksheet and Code:
The user inputs criteria in Rows 5 through 17, Column L. Anything left blank is treated as a wildcard. The user input criteria narrows the search results and determines the data displayed in Rows 21 through 26, Column L.
The code shown above, references a separate sheet named Indiv. Match Stats many times. The COUNTIFS narrow down the search by date, player class, turn number, deck name, ..., and match type. Unfortunately all those criteria must be repeated, once for each match type and then the code adds the results, giving the final result (the proper amount of wins, losses, etc. for the given criteria). It is a large block of code, being added to another block of code.
Is there any better way to do this or just some way to visually simply the code? Is there a way to make similar blocks of the code equal some variable, so that those similar parts don't have to be typed of and over?

Answer 1

You can effectively use an "OR" in COUNTIFS - assuming you want to count if column H = any of L12:L17 then use this version
=SUMPRODUCT(COUNTIFS('Indiv. Match Stats'!I:I,"Win",'Indiv. Match Stats'!H:H,L12:L17,
'Indiv. Match Stats'!L:L,L7,'Indiv. Match Stats'!T:T,L9,'Indiv. Match
Stats'!Q:Q,L10,'Indiv. Match Stats'!P:P,L11,'Indiv. Match Stats'!C:C,
">="&L5,'Indiv. Match Stats'!C:C,"<="&L6,'Indiv. Match Stats'!N:N,L8))
The COUNTIFS now returns an array of 6 values (one each for L12:L17) and then SUMPRODUCT is used to sum that array because it doesn't require "array entry" as SUM would.
Note1: SUMPRODUCT is simply summing 6 values, so there is no performance "hit" from using it in this context - all the "heavy lifting" is done by COUNTIFS
Note2: If any value is repeated in L12:L17 then you will get "double-counting" just as your original formula does
To avoid double-counting use this formula - note the additional COUNTIF function at the end:
=SUMPRODUCT(COUNTIFS('Indiv. Match Stats'!I:I,"Win",'Indiv. Match Stats'!H:H,L12:L17,
'Indiv. Match Stats'!L:L,L7,'Indiv. Match Stats'!T:T,L9,'Indiv. Match
Stats'!Q:Q,L10,'Indiv. Match Stats'!P:P,L11,'Indiv. Match Stats'!C:C,
">="&L5,'Indiv. Match Stats'!C:C,"<="&L6,'Indiv. Match Stats'!N:N,L8),1/COUNTIF(L12:L17,L12:L17&""))

Answer 2

Dead simple approach to shorten the code is the shorten the title of the tab "Indiv. Match Stats" to say IMS. That shortens things significantly:
=(COUNTIFS('IMS'!I:I,"Win",'IMS'!H:H,L12,'IMS'!L:L,L7,'IMS'!T:T,L9,'IVM'!Q:Q,L10,'IMS'!P:P,L11,'IMS'!C:C,">="&L5,'IMS'!C:C,"<="&L6,'IMS'!N:N,L8))
+ (COUNTIFS('IMS'!I:I,"Win",'IMS'!H:H,L13,'IMS'!L:L,L7,'IMS'!T:T,L9,'IMS'!Q:Q,L10,'IMS'!P:P,L11,'IMS'!C:C,">="&L5,'IMS'!C:C,"<="&L6,'IMS'!N:N,L8))
Another prettier way to do this is to used Excel named ranges. Highlight each range like 'Indiv. Match Stats'!I:I and click in the Name box, to the left of the formula bar, type a name for the list like IMSI. Repeat with 'Indiv. Match Stats'!N:N -> IMSN and so on.
That would give you code like this:
=(COUNTIFS(IMSI,"Win",IMSH,L12,IMSL,L7,IMST,L9,IVMQ,L10,IMSP,L11,IMSC,">="&L5,IMSC,"<="&L6,IMSN,L8))
+ (COUNTIFS(IMSI,"Win",IMSH,L13,IMSL,L7,IMST,L9,IMSQ,L10,IMSP,L11,IMSC,">="&L5,IMSC,"<="&L6,IMSN,L8))

Answer 3

I post this answer not as my suggestion, but to show what the problem is. The problem is, that there is no OR shortcut functionality in COUNTIFS. So you can't say COUNTIFS('Indiv. Match Stats'!H:H;L12 OR L13 OR L14...).
There is a possibility to get the formula shorter with an array formula with SUMPRODUCT. This will work, because there is a possibility to perform OR shortcuts by sum boolean results so that the sum is 1 if only one boolean is true. The formula would be:
=SUMPRODUCT(
('Indiv. Match Stats'!I:I="win")
*(
('Indiv. Match Stats'!H:H=L12)+('Indiv. Match Stats'!H:H=L13)
+('Indiv. Match Stats'!H:H=L14)+('Indiv. Match Stats'!H:H=L15)
+('Indiv. Match Stats'!H:H=L16)+('Indiv. Match Stats'!H:H=L17)
)
*('Indiv. Match Stats'!L:L=L7)
*('Indiv. Match Stats'!T:T=L9)
*('Indiv. Match Stats'!Q:Q=L10)
*('Indiv. Match Stats'!P:P=L11)
*('Indiv. Match Stats'!C:C>=L5)
*('Indiv. Match Stats'!C:C<=L6)
*('Indiv. Match Stats'!N:N=L8)
)
But this will have a very bad performance. Such array formulas are very slow especially for whole columns.
So BKays suggestions are the best ones also in my opinion.
Greetings
Axel