How to get column names in awk? - linux

Question

I have a data file in the following format:
Program1, Program2, Program3, Program4
0, 1, 1, 0
1, 1, 1, 0
Columns are program names, and rows are features of programs. I need to write an awk loop that will go through every row, check if a value is equal to one, and then return the column names and put them into a "results.csv" file. The desired output should be this:
Program2, Program3
Program1, Program2, Program3
I was trying this code, but it wouldn't work:
awk -F, '{for(i=1; i<=NF; i++) if ($i==1) {FNR==1 print$i>>results}; }'
Help would be very much appreciated!

Answer 1

awk -F', *' '
NR==1 {for(i=1;i<=NF;i++) h[i]=$i; next}
{
sep="";
for(x=1;x<=NF;x++) {
if($x) {
printf "%s%s", sep, h[x];
sep=", ";
}
}
print ""
}' file
outputs:
Program2, Program3
Program1, Program2, Program3

Answer 2

$ cat tst.awk
BEGIN { FS=", *" }
NR==1 { split($0,a); next }
{
out = ""
for (i=1; i<=NF; i++)
out = out ($i ? (out?", ":"") a[i] : "")
print out
}
$ awk -f tst.awk file
Program2, Program3
Program1, Program2, Program3

Answer 3

My take on things is more verbose, but should handle the trailing comma. Not really a one-liner, though.
BEGIN {
# Formatting for the input and output files.
FS = ", *"
OFS = ", "
}
FNR == 1 {
# First line in the file
# Read the headers into a list for later use.
for (i = 1; i <= NF; i++) {
headers[i] = $i
}
}
FNR > 1 {
# Print the header for each column containing a 1.
stop = 0
for (i = 1; i <= NF; i++) {
# Gather the results from this line.
if ($i > 0) {
stop += 1
results[stop] = headers[i]
}
}
if (stop > 0) {
# If this input line had no results, the output line is blank
for (i = 1; i <= stop; i++) {
# Print the appropriate headers for this result.
if (i < stop) {
# Results other than the last
printf("%s%s", results[i], OFS)
} else {
# The last result
printf("%s", results[i])
}
}
}
printf("%s", ORS)
}
Save this as something like script.awk, and then run it as something like:
awk -f script.awk infile.txt > results