Import multiple .CSV's to a macro enabled sheet - excel

Question

I have multiple (5 to be exact) .csv's in a folder, and I would like to make a macro that lets me select the csv files in a folder and import them to a macro enabled blank file. Here is a step by step for what I want to do:
Open the main.xlsm
Press a macro button in the toolbar that says "Import the CSV's"
This will automatically open a browser window and let you find the CSV's somewhere
Press Ok and BOOM! just like that all your csv's are exported as xlsm and are separate sheets in the current blank sheet
I tried many different methods of doing this, but I don't think I am on the right path. here is one:
Sub convert_to_macro()
'This first line is crap though. It only lets you export it to a certain place
ChDir "C:\Users\pal\Documents\CMSe\Lucys Computer"
With Application.FileDialog(msoFileDialogFilePicker)
.Show
If .SelectedItems.Count = 0 Then
MsgBox "Cancel Selected"
Exit Sub
End If
something = .SelectedItems(1)
End With
ActiveWorkbook.SaveAs Filename:= _
"something.xltm", _
FileFormat:=xlOpenXMLTemplateMacroEnabled, Password:="", WriteResPassword _
:="", ReadOnlyRecommended:=False, CreateBackup:=False
End Sub
Thanks for any help given

Answer 1

Something like this which adds all the csvs to a single file.
Sub convert_to_macro()
Dim Wb As Workbook
Dim Wb1 As Workbook
Dim fd As FileDialog
Dim strWB
Set fd = Application.FileDialog(msoFileDialogFilePicker)
With fd
'set initial directory to search
.InitialFileName = "c:\temp"
.Filters.Clear
.Filters.Add "csv files", "*.csv"
.Show
If .SelectedItems.Count = 0 Then
MsgBox "No selection, exiting"
Exit Sub
End If
End With
With Application
.ScreenUpdating = False
.EnableEvents = False
.DisplayAlerts = False
End With
Set Wb = Workbooks.Add(1)
For Each strWB In fd.SelectedItems
Set Wb1 = Workbooks.Open(strWB)
Wb1.Sheets(1).Copy after:=Wb.Sheets(Wb.Sheets.Count)
Wb1.Close False
Next
Wb.Sheets(1).Delete
With Application
.ScreenUpdating = True
.EnableEvents = True
.DisplayAlerts = True
End With
End Sub