write in next available cell in a row - excel

Question

Right now, I have a code that will generate a name for a folder in a network drive. Once the user types in the name for the new folder in a prompt box, I am trying to add the name into two places: the bottom of a list in a column, and to the end of the list in the first row (the first empty cell in the row)
Currently, my code to put the name at the bottom of the list in column D works:
lMaxRows = Cells(Rows.Count, "D").End(xlUp).Row
Range("D" & lMaxRows + 1) = accountname
where "accountname" is the input that the prompt asks for. Then the code goes to the last cell that was used in the column, goes one additional cell, and fills it with the "accountname".
Is there a way to convert this code to work for a list in a row? I'm trying to build the list from left to right starting in column X of row 1. This is what I have right now, but it's not working and I'm not sure if it's a language issue or something more.
lMaxCol = Cells(1, Columns.Count).End(xlToRight).Column
Range("X1" & lMaxCol + 1) = accountname
Any ideas? Is this a quick fix or will it require a more sophistacted code?
-AC

Answer 1

lMaxCol = Cells(1, Columns.Count).End(xlToRight).Offset(0,1).Column
If lMaxCol<26 Then lMaxCol=26
Cells(1, lMaxCol) = accountname

Answer 2

Dim lMaxCol As Long
With ActiveSheet.Rows(1) 'might want a different sheet
lMaxCol = .Find(what:="", after:=[w1], LookIn:=xlValues, searchdirection:=xlNext).Column
End With
Cells(1, lMaxCol) = AccountName
Note that this should, indeed, find the first empty cell at or after X1. If there is, for example, data in X1 and AA1, the above will return 25, not 28. If this might be an issue, and you prefer to return 28 in that case, you could use something like:
Dim lMaxCol As Long
With ActiveSheet.Range("x1", Cells(1, Columns.Count))
On Error Resume Next
lMaxCol = .Find(what:="*", after:=.Cells(1, .Columns.Count), LookIn:=xlValues, _
searchdirection:=xlPrevious).Column + 1
If Err.Number <> 0 Then lMaxCol = 24
On Error GoTo 0
End With
Cells(1, lMaxCol) = AccountName
If you don't need to know lMaxCol for some other part of the code, this code can be simplified.
Dim C As Range
With ActiveSheet.Range("x1", Cells(1, Columns.Count))
Set C = .Find(what:="*", after:=.Cells(1, .Columns.Count), LookIn:=xlValues, _
searchdirection:=xlPrevious)
If Not C Is Nothing Then
C.Offset(0, 1) = AccountName
Else
Cells(1, 24) = AccountName
End If
End With