Trouble Defining a 6th Range Object - excel

Question

I defining different ranges so that I can use them for graphs:
Sub rangesGRAPHS()
Dim count, counter, Erow, Prow1, Prow2, Urow1 As Long
Dim Dsrc1, Dsrc2, Dsrc3, Xsrc1, Xsrc2, Xsrc3 As Range
counter = 5
count = Application.CountA(Range("A:A"))
count = count + 3
While counter < count
If Range("Q" & CStr(counter)) = "ECO_BS" Then Erow = counter
If Range("Q" & CStr(counter)) = "PHO_BS" Then Prow2 = counter
counter = counter + 1
Wend
Prow1 = Erow + 1
Urow1 = Prow2 + 1
Dsrc1 = ("P5:P" & CStr(Erow))
Dsrc2 = ("P" & CStr(Prow1) & ":P" & CStr(Prow2))
Dsrc3 = ("P" & CStr(Urow1) & ":P" & CStr(count))
Xsrc1 = ("$C$5:$C$" & CStr(Erow))
Xsrc2 = ("$C$" & CStr(Prow1) & ":$C$" & CStr(Prow2))
Xsrc3 = ("$C$" & CStr(Urow1) & ":$C$" & CStr(count))
ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlColumnClustered
ActiveChart.SetSourceData Source:=Range(Dsrc1)
ActiveChart.SeriesCollection(1).XValues = ("=SICALIS_Detail!" & Xsrc1)
ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlColumnClustered
ActiveChart.SetSourceData Source:=Range(Dsrc2)
ActiveChart.SeriesCollection(1).XValues = ("=SICALIS_Detail!" & Xsrc2)
ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlColumnClustered
ActiveChart.SetSourceData Source:=Range(Dsrc3)
ActiveChart.SeriesCollection(1).XValues = ("=SICALIS_Detail!" & Xsrc3)
Everything works except the line Xsrc3 = ("$C$" & CStr(Urow1) & ":$C$" & CStr(count)), which gives a error 91: object variable not set.
Upon debugging, I notice that Xsrc3 is set to nothing. However, all the other stuff works and it's written THE SAME WAY. If I comment it out the other stuff still works. I don't understand what is going on - let me know what's up!

Answer 1

It's not actually written the same way. In this line:
Dim Dsrc1, Dsrc2, Dsrc3, Xsrc1, Xsrc2, Xsrc3 As Range
the first 5 variables are actually declared as Variant and only the last is declared as a Range. You actually want them all to be String anyway, so use:
Dim Dsrc1 As String, Dsrc2 As String, Dsrc3 As String, Xsrc1 As String, Xsrc2 As String, Xsrc3 As String