Dump output of macro to null - nsis

Question

This mainly a curiosity question, but nevertheless. Imagine I have a macro with the declaration:
!define foo "!insertmacro foo"
!macro foo in1 in2 out1 out2 out3
; the code here
!macroend
with inX for inputs and outX for outputs. Now, I don't need all three outputs too often (e.g. one of them is an exit status returned by a winapi call), but still have to pass variables as placeholders to please the macro syntax:
${foo} $1 $2 $R1 $R2 $R3
Is there any syntax like
${foo} $1 $2 $R1 nul nul
to drop the unneeded output?
EDIT: Please also explain how to handle variable arguments for hybrids. SCCE:
OutFile sccce.exe
!define foo "!insertmacro foo"
!macro foo in1 out1 out2
Push "${in1}"
Call bar
Pop "${out1}"
!macroend
Section
${foo} $0 $1 $2 ; compilable
${foo} $0 $1 "" ; not compilable
SectionEnd
Function bar
Pop $0
IntOp $0 $0 + 1
Push $0
FunctionEnd

Answer 1

You can use any magic string you like to signal a unused macro parameter and then check for this in the macro implementation. The other alternative would be to create your own $null variable at the top of your script.
!macro Foo always maybe
IntOp ${always} 666 * 1337
!if "${maybe}" != ""
IntOp ${maybe} 1234 * 1337
!endif
!macroend
!insertmacro Foo $0 ""
!insertmacro Foo $0 $1
Edit:
There is no $optimize_me_away variable and no way to PopAndDiscard so you have to find a way to throw away the result:
!macro foo_alt1 in1 out1 ; The disadvantage with this method is that the common case is "bloated"
Push "${in1}"
Call bar_alt1 ; Will store result in $0
!if "${out1}" == ""
Pop $0
!else if "${out1}" != $0
StrCpy ${out1} $0
Pop $0
!endif
!macroend
Function bar_alt1
Exch $0
IntOp $0 $0 + 1
FunctionEnd
!include LogicLib.nsh
!macro foo_alt2 in1 out1
Push "${in1}"
Call bar_alt2
!if "${out1}" == ""
!insertmacro _LOGICLIB_TEMP ; LogicLib has a internal varible we can use, or you can make your own
Pop $_LOGICLIB_TEMP
!else
Pop ${out1}
!endif
!macroend
Function bar_alt2
Exch $0
IntOp $0 $0 + 1
Exch $0
FunctionEnd
Section
!macro test alt
StrCpy $0 PreserveMe
!insertmacro foo_alt${alt} 1337 $1
DetailPrint r0=$0,r1=$1
!insertmacro foo_alt${alt} 1337 $0
DetailPrint r0=$0
!insertmacro foo_alt${alt} 1337 ""
DetailPrint NoResult
!macroend
!insertmacro test 1
!insertmacro test 2
SectionEnd