VBA use recrusive instead of looping - excel

Question

I would like to ask your help to resolve an issue I'm facing building an algorithm.
Available data
We have a table of data with 10 rows and 30 columns.
Each row corresponds to the variable linkied to a specific parameter (for example weight of Apples, weight of Pears,weight of Oranges... Paramter10)
Each column corresponds to the value the variable can take.
This how we have 30 possible values for each variable/parameter.
Goal of the algorithm
Give the sum of all possible combinations of these parameters (Apples+Pears+ Oranges+...+Paramter10), normally there should be 30^10 possible combinations
Description of my version of the algorithm
It is to create an array of 10, let's say, indexes. Each index is corresponding to the variable/parameter. Each index is filled by one out of 30 possible values.
Create a loop passing through the columns in the same row. Each value of the cell in the table is placed in the corresponding index (row 1, for index 1)
Each change corresponds to the next available value (on the right) in the same row but with a different column. While the column is terminated, the algorithm starts to do the same for the next row.
Every change in the array varlues has to give as result a new sum, copied in a new cell somewhere in the table.
Sub AlgoSum()
Dim rw As Long, column1 As Long
Dim Sum1(9) As Long 'The array with 10 index 'First difficulty is to find a way how to synchornize the sum with every change in array Sum1.
Do While i <= 8 'My version is to place it in first but not sure it is right
For rw = 1 To 9
For column1 = 1 To 30
If Not IsEmpty(Worksheets("Sheet1").Cells(rw, column1)) Then 'verify that the cell is not empty
Sum1(i) = Worksheets("Sheet1").Cells(rw, column1).Value
Worksheets("Sheet1").Cells(rw+30, column1+30).Value = Application.WorksheetFunction.Sum(Sum1)
Else 'normally if it is empty it should move to the next value but I didn't find the appropriate way to do it, this why I thought about this compromise
Sum1(i) = 0
Worksheets("Sheet1").Cells(rw+30, column1+30).Value = Application.WorksheetFunction.Sum(Sum1)
End If
Next column1
Next rw
i = i + 1
Loop
End Sub
This code is not giving the appropriate results. It's not giving the sum for every change in the array, and it's not making the change in the array in the way it has to.
I've seen possible solution with a recursive, but didn't find the right way to do it.
Some help is very welcome!
Thank you in advance!

Answer 1

Try this. It's recursive (although it does use a loop as well).
Use the constants at the top to adjust to your data.
Try it with a few rows and a few columns.
The current constants assume that your data starts in cell A1, and that there are 3 "variables" and 2 "values".
It will print the results to the immediate window as it goes, but you could certainly adjust it to store in an array or print to another sheet.
' number of "variables"
Const ROWS As Integer = 3
' number of "values"
Const COLS As Integer = 2
' upper left cell of table
Const CELL_UPPER_LEFT As String = "A1"
' Recursive method to sum the values of all the combinations of all the rows.
' Method will print the result in the immediate window for now.
' #param row_number Integer Number of rows of data
' #param sum Double Running sum of previous rows
Private Sub recursiveSum(ByVal row_number As Integer, ByVal sum As Double)
' if we've reached the bottom, then print the result and go back up
If row_number = ROWS Then
Debug.Print sum
Exit Sub
End If
' loop over the number of columns
Dim col_number As Integer
For col_number = 0 To COLS - 1
' make a recursive call, increasing the sum by the current row and increasing the row number by 1
recursiveSum row_number + 1, Range(CELL_UPPER_LEFT).Offset(row_number, col_number).Value + sum
' when we return from the recursive call we will be here - ready to start the next time through the loop
Next
End Sub
' Wrapper function for the recursive method.
Public Sub recursiveSumWrapper()
' make the initial recursive call
recursiveSum 0, 0
End Sub

Answer 2

Thank you really for your reply. Your solution is working perfectly with debug.print!
I was able to add an automatic dimensioning of the table:
' number of "variables"
Dim ROWS As Integer
' number of "values"
Dim COLS As Integer
' upper left cell of table
Const CELL_UPPER_LEFT As String = "A1"
ROWS = Worksheets("Sheet1").UsedRange.ROWS.Count
COLS = Worksheets("Sheet1").UsedRange.Columns.Count
a = (ROWS) ^ (COLS) 'The number of possible combinations
However I spent all the morning to change debug.print for another option:
If row_number = ROWS Then
Debug.Print sum
Exit Sub
End If
For a more convenient possibility for the following use of obtained data
If row_number = ROWS Then
For i = 1 To a
Worksheets("Sheet2").Cells(20, a).Value = sum
Exit Sub
Next
End If
As I understand, it's not the right place to use a loop, because I get the error: «Subscript out of range». My intuition is telling me it's ROWS which doesn't correspond to a.
Do you have any idea about this detail? Is it possible to use debug.print information directly?