gnuplot: how to label points in multiplot - gnuplot

Question

I want to label points on the plot using 'with labels' command but I get 'not enough columns for this style' error. My datafile looks like this:
method ∆G
A 0
B 15.01
C -1.4
D 12.2
E -3.9
method ∆H
A 0
B 8.4
C -2.58
D 3.6
E -2.12
method ∆SCF
A 0
B 11.66
C -0.96
D 6.28
E -1.3
I use this command to create a plot:
plot 'file.dat' using 2:xticlabel(1) index 0 pointtype 18 wth labels,''using 2 index 1 pointtype 18 with labels,''using 2 index 2 pointtype 18 with labels
I know that 'with labels' command requires 3 arguments, so the problem is probably lack of the third argument, but I've checked many combination and there was always some error. What am I doing wrong?

Answer 1

For your "missing" 3rd column you can use the pseudocolumn 0 (check help pseudocolumns).
If you want to address blocks via index you need to have two empty lines as separator. If you change your datafile format a bit it will make your script simpler.
The labels will have an offset depending on the sign. You can achieve this with the ternary operator, e.g. ($2<0?-1:1), (check help ternary). You could add another fixed offset via offset (check help label).
Data: SO24044166.dat
method ∆G
A 0
B 15.01
C -1.4
D 12.2
E -3.9
method ∆H
A 0
B 8.4
C -2.58
D 3.6
E -2.12
method ∆SCF
A 0
B 11.66
C -0.96
D 6.28
E -1.3
Script: (works with gnuplot 4.6.0, March 2012)
### use of pseudocolumn as x-value
reset
FILE = "SO24044166.dat"
set key title "methods" noautotitle
set style fill solid 0.3
set grid y
set yrange[-6:18]
set boxwidth 0.23
plot for [i=0:2] FILE u ($0+i/3.5):2 index i w boxes ti columnhead, \
for [i=0:2] '' u ($0+i/3.5):($2+($2<0?-1:1)):2 index i every ::1 w labels offset 0,0 notitle, \
'' u ($0+1/3.5):(NaN):xtic(1) index 0 every ::1
### end of script
Result: (created with gnuplot 4.6.0)