Changing Target.Address location based on iterations vba - excel

Question

I have code that inserts rows based on a cell value in cell J17 using Target.Address. I'd like to use the similar code on the line below it; however, the location of the line below it is dependent on the number of rows that are added.
Does anyone know of a method to add the number of iterations to the rows of an address?
I know how to do this using Cells function, but I like the automatic running of the Target.Address
Here is my code:
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$J$17" Then
Dim i As Integer
For i = 1 To Target.Value
Cells(18, 9).EntireRow.Insert
Cells(18, 9).Value = i
Next i
End If
End Sub

Answer 1

Does anyone know of a method to add the number of iterations to the rows of an address?
Sure. That part is elementary. You could compute the range's new address using the Offset method. But then you need to store it somewhere. You could create a CustomDocumentProperty, a hidden worksheet or a named range variable. All of these would work just fine.
But probably the best solution is just to define that cell initially as a named range. Named ranges are neat because they are dynamic. If you insert rows/columns or delete rows/columns, the Name moves with the cell. Then, in your code, just compare versus that range's .Address property, instead of hard-coding in a value like "$J$18".
Here's how:
First, define a named range for cell J18. I named it "insert", but you can name it (almost) anything you want. Just make sure to update the reference to it in the code.
Use something like this if you are going to do different operations depending on which Target is changing.
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
'This handles your original J17
If Target.Address = "$J$17" Then
For i = 1 To Target.Value
Cells(18, 9).EntireRow.Insert
Cells(18, 9).Value = i
Next i
End If
'This handles the new named range:
If Target.Address = Range("insert").Address Then
'Do something else, here:
MsgBox "Success!!"
End If
Application.EnableEvents = True
End Sub
If you are doing the same insertion and numbering, then I would fancy it up like this:
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
With Target
If .Address = "$J$17" Or .Address = Range("insert").Address Then
For i = 1 To .Value
.Offset(1, -1).EntireRow.Insert
.Offset(1, -1).Value = i
Next i
End If
End With
Application.EnableEvents = True
End Sub