Autocmd seems to not trigger cinkeys - vim

Question

I have the following lines in my vimrc
" Python indenting and folding
au! FileType python set foldmethod=indent
au! FileType python set nosmartindent
" C++ indenting and folding
au! FileType cpp set cino=i-s
au! FileType cpp set cinkeys=0{,0},0),:,!^F,o,O,e
au! FileType cpp set cinkeys-=0#
au! FileType cpp set smartindent
au! FileType cpp set foldmethod=syntax
fu! FUNC_ECHOVAR(varname)
:let varstr=a:varname
:exec 'let g:foo = &'.varstr
:echo varstr.' = '.g:foo
endfu
command! -nargs=1 ECHOVAR :call FUNC_ECHOVAR(<f-args>)
func! MYINFO()
:ECHOVAR cino
:ECHOVAR cinkeys
:ECHOVAR foldmethod
:ECHOVAR filetype
:ECHOVAR smartindent
endfu
command! MYINFOCMD call MYINFO() <C-R>
when I open a C++ file and execute the MYINFOCMD command I see this printout
cino = {1s
cinkeys = 0{0,},),:,0#,!^F,o,O,e
foldmethod = syntax
filetype = cpp
smartindent = 0
I don't understand why the autocmd FileType cpp has failed to set these variables correctly, or at least the way I expected them to be set.
Does anyone know why my au! commands are not triggering when I load a .cpp file?

Answer 1

Use :au! at most once for each autocommand event and pattern, since it removes previously defined autocommands. (Use it in case your vimrc file gets sourced more than once, so the autocommands are not duplicated.) From :help autocmd-remove:
:au[tocmd]! [group] {event} {pat} [nested] {cmd}
Remove all autocommands associated with {event} and
{pat}, and add the command {cmd}. See
|autocmd-nested| for [nested].
Alternatively, put all your autocommands in a group and use :au! just once (:help autocmd-groups):
augroup Erotemic
au!
" Python indenting and folding
au FileType python set foldmethod=indent
au FileType python set nosmartindent
" C++ indenting and folding
au FileType cpp set cino=i-s
au FileType cpp set cinkeys=0{,0},0),:,!^F,o,O,e
au FileType cpp set cinkeys-=0#
au FileType cpp set smartindent
au FileType cpp set foldmethod=syntax
augroup END
Here is what happens when I try the first two of your autocommand lines, and then list the FileType python autocommands after each one:
:au! FileType python set foldmethod=indent
:au FileType python
--- Auto-Commands ---
FileType
python set foldmethod=indent
:au! FileType python set nosmartindent
:au FileType python
--- Auto-Commands ---
FileType
python set nosmartindent