Cleaner way of "finding" a range of values - excel

Question

So I currently a macro that assigns a cell value to a variable and then search for this variable on a another sheet. The problem is that I am having to do this a large number values so I currently have the same code copied 20 times allowing for 20 values to be search in series. Is there a cleaner method of running a repeatable operation like this? Also is it possible to set the upper limit based on the number of values entered. E.g. my current setup looks cells M8:M27 for it's variables, is it possible however to write it so that it is repeated continuously until it hits a blank cell? Thereby letting the user enter as many values as required?
Here is an extract for a single variable. This is then repeated up to reverse_id_20
Sheets("GR Input").Select
reverse_id_1 = Range("O8")
Sheets("PchOrds").Select
Columns("A:A").Select
Selection.Find(What:=reverse_id_1, After:=ActiveCell, LookIn:= _
xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
xlNext, MatchCase:=False, SearchFormat:=False).Select
Rows(ActiveCell.Row).Select
Selection.Delete Shift:=xlUp
Sheets("GR Input").Select
Thanks in advance guys,
Dan

Answer 1

Is there a cleaner method of running a repeatable operation like this?
Yes, it is. You can use loop for it:
Sub test()
Dim reverse_id As Variant
Dim rng As Range
Dim r_id As Variant
With Sheets("GR Input")
reverse_id = .Range("O8:O11")
End With
For Each r_id In reverse_id
Set rng = Sheets("PchOrds").Columns("A:A").Find( _
What:=r_id, _
LookIn:=xlFormulas, _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
MatchCase:=False)
If Not rng Is Nothing Then
rng.EntireRow.Delete Shift:=xlUp
End If
Next r_id
End Sub
Btw, code above deletes only first row that meet criteria. If you'd like to delete all values from sheet "PchOrds", that meet criteria, use this code:
Sub test1()
Dim reverse_id As Variant
Dim rng As Range
Dim lastrow As Long
Dim r_id As Variant
With Sheets("GR Input")
reverse_id = .Range("O8:O11")
End With
For Each r_id In reverse_id
If r_id <> "" Then
With Sheets("PchOrds")
lastrow = Application.Max(2, .Cells(.Rows.Count, "A").End(xlUp).Row)
.AutoFilterMode = False
With .Range("A1:A" & lastrow)
.AutoFilter Field:=1, Criteria1:="=*" & r_id & "*"
.Offset(1, 0).Resize(lastrow - 1, 1).EntireRow.Delete
End With
.AutoFilterMode = False
End With
End If
Next r_id
End Sub