Access insert opened query in excel below existing data - excel

Question

Ok, so I have an Excel-file with data. This data comes from a query that has been manually copied from an Access database. Since this has to be done every day we want to make it automatically.
I already have VBA code inside the Access database that opens the query and writes it away into the Excel-file on the right sheet.
However, it works when I put a static range for the insert so it actually just overwrites the range I say:
Dim rst As DAO.Recordset
Dim ApXL As Object
Dim xlWBk As Object
Dim xlWSh As Object
Set rst = CurrentDb.OpenRecordset("Query name")
Set ApXL = CreateObject("Excel.Application")
ApXL.Application.ScreenUpdating = False
ApXL.Visible = True
Set xlWBk = ApXL.Workbooks.Open("C:\blabla.xlsm", True, False)
Set xlWSh = xlWBk.Worksheets(1)
xlWSh.Activate
xlWSh.range("A1341").CopyFromRecordset rst
xlWBk.Save
xlWBk.Close False
ApXL.Quit
rst.Close
Set rst = Nothing
Notice the xlWSh.range("A1341").CopyFromRecordset rst.
It just pastes the query from this row because I know this is the first empty row.
I already tried lots of other codes but I always get errors:
TheLastRow = ActiveSheet.UsedRange.SpecialCells(xlCellTypeLastCell).Row
=> Error 424: Object required
Dim MyRange As range
Dim lngLastRow As Long
Set MyRange = xlWSh.range(strColum & "1")
lngLastRow = xlWSh.Cells(65536, MyRange.Column).End(xlUp).Row
=> Compilation-error on Dim MyRange As range: user-defined type not defined
Dim MyRange As Object
Dim lngLastRow As Long
Set MyRange = xlWSh.range(strColum & "1")
lngLastRow = xlWSh.Cells(65536, MyRange.Column).End(xlUp).Row
=> Error 1004: Application-defined or object-defined error
With xlWBk.Sheets("Sheetname")
lastrow = .range("A" & .Rows.Count).End(xlUp).Row
=> Error 1004: Application-defined or object-defined error
End With
With xlWSh
lastrow = .Cells.Find(What:="*", After:=.range("A1"), SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
=> Error 9: Subscript out of range
End With
So I have no idea anymore what to do.
The only other option is by reading the entire sheet into the Access database as a List or Array or Table and then do a .Count or something but inserting into lastRow+1 or firstEmptyRow should be quicker, doable and much easier to program.
Thanks in advance!

Answer 1

The problem is that Access doesn't know anything about Excel constants, such as xlUp, xlByRows and so on (until you add reference to excel library).
There are to ways for you:
1) Go to TOOLS->REFERENCES and add reference to Microsoft Excel 1x.0 Object Library (version may vary)
2) change all excel constants to their values (e.g. change SearchOrder:=xlByRows to SearchOrder:=1 and so on):
xlUp equals to -4162
xlByRows eqals to 1
xlPrevious eqals to 2
xlCellTypeLastCell equals to 11
Here is link with values of excel constants: xlConstants (or another way to determine constants values - is to use this line in EXCEL VBA : MsgBox xlCellTypeLastCell)