Find same value and paste data at side of it - excel

Question

I've searched everywhere and can't seem to find help on a macro I'm trying to get working to make life a little easier at work.
We have laser scanners and what I'm trying to do, is use a search box so we can scan a code, this will then check the full A column.
If something the code is found from A3, it will paste the data say from A3, B3 & C3 to say E3, F3, G3.
Currently the macro I have, Finds the data (say in A1) then copies the complete A ROW to sheet 2, yet I want it all to be on one sheet.
BEFORE SEARCHING 1111111
AFTER SEARCHING 1111111
USING THIS CODE
Option Explicit
Sub Main()
Application.ScreenUpdating = False
Dim rangeToSearch As range
Set rangeToSearch = Sheets(1).range("A2:A" & Sheets(1).range("A" & Rows.Count).End(xlUp).Row)
Dim searchAmount As String
searchAmount = InputBox("Type in the amount to search for:")
Dim cell As range
For Each cell In rangeToSearch
If cell = CLng(searchAmount) Then
Sheets(1).Rows(cell.Row & ":" & cell.Row).Copy
Sheets(2).Rows( _
Sheets(2).range("A" & Rows.Count).End(xlUp).Row + 1 & _
":" & _
Sheets(2).range("A" & Rows.Count).End(xlUp).Row + 1 _
).PasteSpecial _
Paste:=xlPasteValues, Operation:=xlNone, _
SkipBlanks:=False, Transpose:=False
Application.CutCopyMode = False
End If
Next
Application.ScreenUpdating = True
End Sub

Answer 1

I've slightly modified your code, now it's more simple and without loop statement:
Option Explicit
Sub Main()
Application.ScreenUpdating = False
Dim rangeToSearch As Range
With Sheets(1)
Set rangeToSearch = .Range("A2:A" & .Range("A" & .Rows.Count).End(xlUp).Row)
End With
Dim searchAmount As String
searchAmount = InputBox("Type in the amount to search for:")
Dim cell As Range
Set cell = rangeToSearch.Find(searchAmount, LookIn:=xlValues)
With Sheets(1)
If Not cell Is Nothing Then
.Range("E" & cell.Row & ":G" & cell.Row).Value = _
.Range("A" & cell.Row & ":C" & cell.Row).Value
Else
MsgBox "Value " & searchAmount & " not found"
.Range("L4").Value = searchAmount
End If
End With
Application.ScreenUpdating = True
End Sub