VBscript No output attempting query AD users last 30 days - excel

Question

I had a working query but it was grabbing all users in AD and I am attempting to narrow this down to the last 90 days. The problem is that I no longer have any outputs even though the query does run. I know that my math is wrong and does not take off 90 days. Can anyone offer assistance with this?
Dim currentDate
currentDate = DateDiff("s", CDate("1/1/1970"), Now()) * 1000#
currentDate = currentDate - 7776000000# 'Subtracts 90 days
'Does the query
objCommand.CommandText = _
"<LDAP://" & strDN & ">;" & _
"(&(objectclass=user)(objectcategory=person)(lastLogonTimestamp<=" & currentDate & "));" & _
"adspath,distinguishedname,sAMAccountName,lastLogonTimestamp,DisplayName,WhenCreated,userAccountControl;subtree"
'Output the query info
Set objRecordSet = objCommand.Execute
rngOut.CurrentRegion.Offset(2).ClearContents
While Not objRecordSet.EOF
rngOut.value = objRecordSet.Fields("DisplayName").value
Set rngOut = rngOut.Offset(0, 1)
rngOut.value = objRecordSet.Fields("sAMAccountName").value
Set rngOut = rngOut.Offset(0, 1)
rngOut.value = objRecordSet.Fields("WhenCreated").value
Set rngOut = rngOut.Offset(0, 1)
On Error Resume Next
Set objDate = objRecordSet.Fields("lastLogonTimestamp").value
If (Err.Number <> 0) Then
On Error GoTo 0
dtmDate = ""
Else
On Error GoTo 0
lngHigh = objDate.HighPart
lngLow = objDate.LowPart
If (lngLow < 0) Then
lngHigh = lngHigh + 1
End If
If (lngHigh = 0) And (lngLow = 0) Then
dtmDate = ""
Else
dtmDate = #1/1/1601# + (((lngHigh * (2 ^ 32)) _
+ lngLow) / 600000000) / 1440
End If
End If
rngOut.value = dtmDate
Set rngOut = rngOut.Offset(0, 1)
rngOut.value = objRecordSet.Fields("distinguishedName").value
Set rngOut = rngOut.Offset(0, 1)
Set Uservar = objRecordSet.Fields("userAccountControl")
If Uservar And 2 Then
rngOut.value = "Disabled"
rngOut.Font.ColorIndex = 3
Else
rngOut.value = "Enabled"
rngOut.Font.ColorIndex = 0
End If
Set rngOut = rngOut.Offset(1, -5)
objRecordSet.MoveNext
Wend
I have this working but only when I change (lastLogonTimestamp<=" & currentDate & ")); to (lastLogon<=" & currentDate & ")); and for what I am wanting this does not display the correct user base. Can anyone tell me why?

Answer 1

As documented in the VBScript tag wiki VBScript doesn't expand variables inside strings, so you need to change this:
objCommand.CommandText = _
"<LDAP://" & strDN & ">;" & _
"(&(objectclass=user)(objectcategory=person)(lastLogonTimestamp>=currentDate));" & _
"adspath,distinguishedname,sAMAccountName,lastLogon,DisplayName,WhenCreated,userAccountControl;subtree"
into this:
objCommand.CommandText = _
"<LDAP://" & strDN & ">;" & _
"(&(objectclass=user)(objectcategory=person)(lastLogonTimestamp>=" & currentDate & "));" & _
"adspath,distinguishedname,sAMAccountName,lastLogon,DisplayName,WhenCreated,userAccountControl;subtree"
Also, I'd recommend calculating currentDate as a normal Date value, e.g. like this:
maxAge = 30 'days
currentDate = Now - maxAge
or like this:
maxAge = 30 'days
currentDate = DateAdd("d", -maxAge, Now)
and then convert it to an integer8 value using this code from Richard L. Mueller:
Function DateToInt8(d)
biasKey = CreateObject("Wscript.Shell").RegRead("HKLM\System" & _
"\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")
If (UCase(TypeName(biasKey)) = "LONG") Then
bias = biasKey
ElseIf (UCase(TypeName(biasKey)) = "VARIANT()") Then
bias = 0
For k = 0 To UBound(biasKey)
bias = bias + (biasKey(k) * 256^k)
Next
End If
DateToInt8 = CStr(DateDiff("s", #1/1/1601#, DateAdd("n", bias, d))) & "0000000"
End Function
...
objCommand.CommandText = "<LDAP://" & strDN & ">;" & _
"(&(objectclass=user)(objectcategory=person)(lastLogonTimestamp>=" & _
DateToInt8(currentDate) & "));adspath,distinguishedname,sAMAccountName," & _
"lastLogon,DisplayName,WhenCreated,userAccountControl;subtree"