Apply exclusionary criteria for multiple criteria - excel

Question

I am trying to have some VBA code that will apply an advanced/autofilter to exclude three variables in particular. For instance, `In this entire data set, hide entries for which Column A has values X, Y, or Z.
This code works for inclusions as far as I can tell
Sheets(sheetName).Range("$A:$" & finalCol).AutoFilter Field:=fieldIndex, criteria1:=Array("=" & crit1, "=" & crit2, "=" & crit3), Operator:=xlFilterValues
But this does not work for exclusions:
Sheets(sheetName).Range("$A:$" & finalCol).AutoFilter Field:=fieldIndex, criteria1:=Array("<>" & crit1, "<>" & crit2, "<>" & crit3), Operator:=xlFilterValues
Data validation code
Dim Arr() As Variant
Arr = Range(Cells(10, 2).Validation.Formula1)
For R = 1 To UBound(Arr, 1)
For C = 1 To UBound(Arr, 2)
Debug.Print Arr(R, C)
Next C
Next R
Is there a way to make this array "one dimensional" like in the answer?

Answer 1

Let's say your worksheet looks like this
LOGIC:
What we are doing is creating the array of values that we want and then passing that array to the autofilter.
CODE:
Try this code
Option Explicit
Sub Sample()
Dim ws As Worksheet
Dim Ar() As String, itm
Dim Lrow As Long, n As Long, i As Long
Dim rng As Range
Dim Col As New Collection
Dim TempAr
Dim ExclusionList As String
Dim doNotAdd As Boolean
'~~> Exclusion List
ExclusionList = "X,Y,Z"
TempAr = Split(ExclusionList, ",")
'~~> Change this to the relevant worksheet
Set ws = ThisWorkbook.Sheets("Sheet1")
With ws
.AutoFilterMode = False
Lrow = .Range("A" & .Rows.Count).End(xlUp).Row
Set rng = .Range("A1:A" & Lrow)
'~~> Get unique collection of items
For i = 2 To Lrow
On Error Resume Next
Col.Add .Range("A" & i).Value, CStr(.Range("A" & i).Value)
On Error GoTo 0
Next i
'~~> Create an array which doesn't have the items that we don't need
For Each itm In Col
For i = LBound(TempAr) To UBound(TempAr)
If itm = TempAr(i) Then
doNotAdd = True
Exit For
End If
Next
If doNotAdd = False Then
ReDim Preserve Ar(n)
Ar(n) = itm
n = n + 1
End If
doNotAdd = False
Next
'~~> Autofilter
rng.AutoFilter Field:=1, Criteria1:=Ar(), Operator:=xlFilterValues
End With
End Sub
OUTPUT: