Borders Object in Excel 2010, pass by reference? - excel

Question

I've been working on a formats encoder that grabs the format of a given range, and then provides the ability to paste that format on another given range (basically emulating "Paste Formats", but storable). I'm trying to set the Borders object of a range (in the set routine), but it seems that a Borders Object is passed by value, and not reference?
I can get the current values of the Borders object just fine, but if I try to set any value to it, it's straight up ignored (without even an "Read only" error). Follows is a snippet of my code:
Sub SetBorders(sInput As String, ByRef Target As Borders)
Dim resultPart() As String
'Border indexes go from 5 to 12
For i = 5 To 12
'Set resultPart
resultPart = Split(Split(sInput, CharEOList)(i - 5), CharEORecord)
If Len(resultPart(0)) > 0 Then
Target(i).ColorIndex = CLng(resultPart(0))
...
What am I doing wrong? Should I be using a higher Range object and drilling down to the Borders object inside it?

Answer 1

Apparently, access order is very important to the Borders object. I had been setting .LineStyle at the top, when it should have been more at the bottom. Setting LineStyle first (ie, to None), and then setting a Color, reverts the LineStyle to the one in the Borders Object.
Finished portion of that code:
Sub SetBorders(sInput As String, ByRef Target As Borders)
Dim resultPart() As String
'Border indexes go from 5 to 12
For i = 5 To 12
'Set resultPart
resultPart = Split(Split(sInput, CharEOList)(i - 5), CharEORecord)
'If index is empty, set that property to Variant/Null
If Len(resultPart(0)) > 0 Then Target(i).ColorIndex = CLng(resultPart(0)) Else Target(i).ColorIndex = Null
If Len(resultPart(1)) > 0 Then Target(i).color = CDbl(resultPart(1)) Else Target(i).color = Null
If Len(resultPart(2)) > 0 Then Target(i).ThemeColor = CDbl(resultPart(2)) Else Target(i).ThemeColor = Null
If Len(resultPart(3)) > 0 Then Target(i).TintAndShade = CDbl(resultPart(3)) Else Target(i).TintAndShade = Null
'Weight and LineStyle seem to always be set
Target(i).Weight = CLng(resultPart(4))
Target(i).LineStyle = CLng(resultPart(5))
On Error GoTo 0
Next i
End Sub
Function GetBorders(b As Borders)
Dim Result As String
Result = ""
Dim resultPart() As String
'Border indexes go from 5 to 12
For i = 5 To 12
'Reset resultPart
resultPart = Split(",,,,,", ",")
'Skip errors. This will leave that index blank, which equates to a Null when using Borders
On Error Resume Next
resultPart(0) = b(i).ColorIndex
resultPart(1) = b(i).color
resultPart(2) = b(i).ThemeColor
resultPart(3) = b(i).TintAndShade
resultPart(4) = b(i).Weight
resultPart(5) = b(i).LineStyle
On Error GoTo 0
Result = Result + Join(resultPart, CharEORecord) + CharEOList
Next i
GetBorders = Result
End Function

Answer 2

This worked for me (XL2010), so there must be some other issue going on with your code.
EDIT - I see you figured it out.
Sub tester()
SetBorders Selection.Borders
End Sub
Sub SetBorders(obj As Borders)
Dim arr, x
arr = Array(xlEdgeBottom, xlEdgeLeft, xlEdgeRight, xlEdgeTop)
For x = LBound(arr) To UBound(arr)
With obj(arr(x))
.LineStyle = xlContinuous
End With
Next x
End Sub