Function doesn't work when form embedded in excel sheet - excel

Question

Why the below code doesn't work in excel sheet? This code is covert an excel file to text file based on user selection, the selection can be export full excel sheet or selected range and user also can choose delimiter of the text file. I've tested this code in excel sheet form and it works well however if change the userform to embedded in excel sheet, it doesn't work completely. It does generate text file but all value are blank, any idea ?
Public Sub ExportToTextFile(FName As String, SourceFile As String, _
Sep As String, SelectionOnly As Boolean, _
AppendData As Boolean)
Dim wb As Workbook
Dim ws As Worksheet
Dim WholeLine As String
Dim FNum As Integer
Dim RowNdx As Long
Dim ColNdx As Integer
Dim StartRow As Long
Dim EndRow As Long
Dim StartCol As Integer
Dim EndCol As Integer
Dim CellValue As String
StarRange = StrCol & StrRow
EndRange = EndCols & endrows
Application.ScreenUpdating = False
On Error GoTo EndMacro:
FNum = FreeFile
Set wb = Workbooks.Open(SourceFile)
Set ws = wb.Sheets("Sheet1")
If SelectionOnly = True Then
With ActiveSheet.UsedRange
StartRow = .Cells(1).Row
StartCol = .Cells(1).Column
EndRow = .Cells(.Cells.Count).Row
EndCol = .Cells(.Cells.Count).Column
End With
Else
With ActiveSheet.Range(StarRange & ":" & EndRange)
StartRow = .Cells(1).Row
StartCol = .Cells(1).Column
EndRow = .Cells(.Cells.Count).Row
EndCol = .Cells(.Cells.Count).Column
End With
End If
If AppendData = True Then
Open FName For Append Access Write As #FNum
Else
Open FName For Output Access Write As #FNum
End If
For RowNdx = StartRow To EndRow
WholeLine = ""
For ColNdx = StartCol To EndCol
If Cells(RowNdx, ColNdx).Value = "" Then
CellValue = Chr(34) & Chr(34)
Else
CellValue = Cells(RowNdx, ColNdx).Value
End If
WholeLine = WholeLine & CellValue & Sep
Next ColNdx
WholeLine = Left(WholeLine, Len(WholeLine) - Len(Sep))
Print #FNum, WholeLine
Next RowNdx
EndMacro:
On Error GoTo 0
Application.ScreenUpdating = True
Close #FNum
MsgBox "Completed.", vbInformation
ActiveWorkbook.Close
End Sub

Answer 1

Looking at your code:
Dim StartRow As Long
Dim EndRow As Long
Dim StartCol As Integer
Dim EndCol As Integer
Dim CellValue As String
StarRange = StrCol & StrRow
EndRange = EndCols & endrows
I suspect you have some typos in your variable names. Is it StartRow or StrRow, for example?
Without using a fine-toothed comb to do your debugging for you, I would highly recommend that you always use
Option Explicit
at the start of every module. This tells VBA "don't let me use any variables I did not explicitly declare" - which in practice means (most of the time) "warn me if I misspelled a variable".
I also noticed that you set a variable ws in the line
Set ws = wb.Sheets("Sheet1")
Then proceed not to use it. Portland Runner posted a good suggestion for how to make use of such a variable - although without seeing the rest of your code / form, it's not clear if that does a better job for you. Typically "ActiveSheet" is a bad idea - it is usually a relic from recording a macro, but not the most efficient or portable thing to do.
It looks like you took code from a couple of different places and repurposed it. I recommend that you go through line by line and make sure that every line is needed, and does what you want.
Finally, as part of the debugging process I would put a breakpoint (F9) in the line
WholeLine = ""
then step through to see whether lines are being formed as you think they are (input range is right, formatting is right, and line is written correctly). My suspicion lies with the way you define your input range. Are StartRow, StartCol etc. actually what you want them to be?
Finally (and possible most importantly) in the lines
For ColNdx = StartCol To EndCol
If Cells(RowNdx, ColNdx).Value = "" Then
CellValue = Chr(34) & Chr(34)
Else
CellValue = Cells(RowNdx, ColNdx).Value
End If
WholeLine = WholeLine & CellValue & Sep
Next ColNdx
You refer to Cells - but don't reference the workbook / sheet that these cells belong to. I suspect that VBA is referencing a difference sheet than you intended. Again - if you properly create the ws variable, then these lines should be changed to
For ColNdx = StartCol To EndCol
If ws.Cells(RowNdx, ColNdx).Value = "" Then
CellValue = Chr(34) & Chr(34)
Else
CellValue = ws,Cells(RowNdx, ColNdx).Value
End If
WholeLine = WholeLine & CellValue & Sep
Next ColNdx
and that may well solve your problem.