Determine if a point is on or near the hypotenuse - geometry

Question

In this program, I am trying to get dot drawn onto the hypotenuse. If the line is diagonal, it seems to work fine. But the more vertical or horizontal the line gets, the dots are more sparse. If the line is completely vertical or horizontal, I get no dots. Also the longer the red line, dots are drawn further away from it.
This question here seems to be similar to what I'm asking, but I don't understand the answer.
How to check if a point (int - Coordinates) is within the hypotenuse of a triangle
I need a dot drawn at every pixel on the red line, but not too far away from it (1 or 2 pixels at most)
This code is for Processing.
int sx,sy,ex,ey;
void setup(){
sx=150;
sy=150;
ex=550;
ey=550;
size(600,600);
}
void draw(){
background(255);
stroke(#ff0000);
fill(0);
line(sx,sy,ex,ey);
stroke(0);
for(int y=0;y<height;y++){
for(int x=0;x<width;x++){
if(((x<=sx && x>=ex) || (x>=sx && x<=ex)) && ((y<=sy && y>=ey) || (y>=sy && y<=ey))){
double xdiff=ex-sx;
double ydiff=ey-sy;
double xpos=(x-sx)/xdiff;
double ypos=(y-sy)/ydiff;
double diff=xpos-ypos;
if(diff>-0.01 && diff < 0.01) ellipse(x,y,3,3);
}
}
}
}
void mousePressed() {
if(mouseButton == LEFT){
ex=mouseX;
ey=mouseY;
}else{
sx=mouseX;
sy=mouseY;
}
}

Answer 1

Can you just follow the line itself instead of testing every pixel?
int sx,sy,ex,ey;
void setup(){
size(600,600); //size() should always be the first line of setup()
sx=150;
sy=150;
ex=550;
ey=550;
background(255);
}
void draw(){}
void mousePressed(){
background(255);
fill(0);
stroke(0);
if(mouseButton == LEFT){
ex=mouseX;
ey=mouseY;
}else{
sx=mouseX;
sy=mouseY;
}
line(sx,sy,ex,ey);
float dx = (ex-sx);
float dy = (ey-sy);
float numDots = sqrt(pow(ey-sy,2) + pow(ex-sx,2));
for(int i = 0; i < numDots; i++){
ellipse(sx + i*dx/numDots, sy + i*dy/numDots,3,3);
}
}
Or, using Processing's PVector class:
PVector start,end;
void setup(){
size(600,600); //size() should always be the first line of setup()
start = new PVector(150,150);
end = new PVector(550,500);
background(255);
}
void draw(){}
void mousePressed(){
background(255);
fill(0);
stroke(0);
if(mouseButton == LEFT)
end.set(mouseX,mouseY);
else
start.set(mouseX,mouseY);
line(start.x,start.y,end.x,end.y);
PVector slope = new PVector(end.x-start.x,end.y-start.y);
float numDots = end.dist(start);
for(int i = 0; i < numDots; i++){
ellipse(start.x + i*slope.x/numDots, start.y + i*slope.y/numDots,3,3);
}
}