I have three or four tables each of them having 4 to 7 columns.
all tables having "name" column common.
all tables having rank values but based on different columns. ie; rank values of each table differs. suppose in table1 name x got rank1, in second table name z got rank1 etc...
but I want to calculate the overall rank based on all ranking tables.
I mean, table1 can be weighed as 0.2, table2 weight 0.6 etc...so that I want to see overall rank of name x,y,z etc....
Is there any way in excel or any alternative software??
I assume you want to weight the original "scores" not the ranks.
In another table you can use a VLOOKUP to get the score from each of the other tables, multiplied by the weight, e.g.
=VLOOKUP(A2,Table1,2,0)*0.6+VLOOKUP(A2,Table2,2,0)*0.2+VLOOKUP(A2,Table3,2,0)*0.2
Where A2 is the name and assuming that each table has the name in one column followed by the score in the next.
Now you can simply rank the "new" scores
Revised suggestion:
Given your comments I think you could still do the same as my initial suggestion except weight the ranks - I don't see how that won't be valid even if some of your original ranks are in descending order and some in ascending order........but if your rank is to the left of the name you can't use VLOOKUP so I would switch to SUMIF (although INDEX/MATCH would also work, so this formula in H2 copied down gives a combined rank assuming weights of 0.6/0.2/0.2 (adjust as required)
=SUMIF(C$2:C$4,G2,B$2:B$4)*0.6+SUMIF(C$7:C$9,G2,B$7:B$9)*0.2+SUMIF(C$12:C$14,G2,B$12:B$14)*0.2
and then you can get the overall rank with this formula in I2 copied down:
=RANK(H2,H$2:H$4,1)
Related
hi, I would like to discuss on how to get sorting ascending formula from this case. Expected result is as shown in the picture in blue column. The only reference that can be used is Rank column (Yellow) and Group column (white).
Any idea how to get the rank unique expected column (blue)? the flow is go through in the group, find the min number in the rank within the group and put into the reverse order.
Assuming Group is in A1, series fill ColumnC from 1 to 10 then sort that column from where the second Group starts (C4:C10) by A A to Z and B Smallest to Largest.
I have a percent rank below
=PERCENTRANK(INDEX(T$2:T$28557,MATCH($A408,$A$2:$A$28557,0)):INDEX(T$2:T$28557,MATCH($A408,$A$2:$A$28557,1)),T407,3)*100
I want it to return a ranking only for matching in column A. But it's returning a ranking for the whole data set. For example, I have a list of schools in column A and I want to find the percent ranking of students in each school, not the entire district. Is there a formula for that?
Here's some mock data. So I need to find out what the percent ranks in columns D and F are for each school independent of all the others.
Mock Data
As your data is sorted use COUNTIF() to get the end of the school name:
Put this in D2 and copy down:
=PERCENTRANK(INDEX(C$2:C$21,MATCH($A2,$A$2:$A$21,0)):INDEX(C$2:C$21,MATCH($A2,$A$2:$A$21,0)+COUNTIF($A$2:$A$21,$A2)-1),C2,3)*100
Put this in F2 and copy down
=PERCENTRANK(INDEX(E$2:E$21,MATCH($A2,$A$2:$A$21,0)):INDEX(E$2:E$21,MATCH($A2,$A$2:$A$21,0)+COUNTIF($A$2:$A$21,$A2)-1),E2,3)*100
I have an Excel table with three columns. Column A has a list of countries, Column B has a list of cities in each country and Column C has populations of those cities.
The way the table is structured makes it so that Column A will have repeated names of countries - as many times as the number of cities in each country, in column B.
I would like to sum the populations of the first five cities in each country.
I have tried using SUMIF and COUNTIF but haven't managed to do it. How can I sum the populations (in row C) of the first five cities appearing for each country?
Are you trying to sum the population of the first five cities in the list or the population of the top 5 most populous cities for each country (which if the list is sorted by population, these are the same)? If it's the latter you can do it with a one line array formula
=SUM(LARGE(IF(A:A="CountryName",C:C),{1,2,3,4,5}))
(Ctrl+Shift+Enter after setting up the formula)
Where you replace "CountryName" with a reference to the country you want the sum of the top 5 populations for. I think the only issue with this is it will fail if there are less than 5 cities in a country on the list.
Here is a version of the formula that works when there are less than 5 cities but still caps at out at the top 5. Getting an array of 1-n values is kind of an ugly hack in Excel but this seems to work.
=SUM(LARGE(IF(A:A="CountryName",C:C),ROW(OFFSET(A1,,,MIN(COUNTIF(A:A,"CountryName"),5)))))
(Ctrl+Shift+Enter after setting up the formula)
Add a column D. In D2 write the following formula D2=COUNTIF($A$1:$A2,$A2) and drag it down.
Now what this will do is ranking the instances of a particular country.
Now it's a very simple formula for column E, where you will get the sum
E2=SUMIFS($C$2:$C$1000,$A$2:$A$1000,$A2,$D$2:$D$1000,"<=5") and drag it down
Now for each country you will have the sum of population of first 5 cities
1) I have two tables. 1st table contains data for more then 20,000 rows and 2nd table I already have the following columns details i.e. Region, Item, Number and I just have to get the Total value of the product from the 1st table
2) There are two types of prices in the 1st table . One is Retail Price and Another one is a Wholesale price
3) In each of the regions Rep, Item and Numbers are same in most of the cases, but the Total price is different
4) I am able to get the Total price details in 2nd table through vlookup formula (After concatinating the following columns i.e. Region, Item and Number from both the tables) wherever there is an account number for retail price
5) Currently I am manually updating "Total Price" details in 2nd table for Wholesale price which is taking lot of time.
Is it possible to build a formula to get the wholesale price details in the 2nd table, since there are more then one account number, but the price is same
If the wholesale price is the lowest price for the specific item, then you can find it with the formulas MIN and IF.
Based on your screen shot:
D is the column with the list of items
I5 is the cell with the item name for which you want to find the wholesale price
F is the column with the list of prices
If you enter the following formula in cell K5, it should find the lowest price for pencils
=MIN(IF(D:D=I5,F:F))
On this link, there is an explanation if you want to use multiple criteria.
http://www.contextures.com/excelminmaxfunction.html
try the sumifs function.
It takes multiple arguments and criteria. So it should look something like:
cell value at j5 = sumifs(f3:f23, b3:b23, h5, d3:d23, i5....)
you need to mark off which rows in your first table are wholesale selling. So it should be a column of some kind. Once you do that, let's say in column G, then you add onto the sumifs function...
, g3:g23, L5)
What you're doing is summing up all of the values in column F where h5 (region) matches in b3:b23, i5 (item) match in d3:d23, and where L5 (retail type) match in a new column g2:g23.
This will find all of the values that match that criteria exactly.
Vlookup is useful, but it's harder to scale IMO than the advanced if functions.
SUMIFS is probably the better way to go on this one, but as an alternative there is also SUMPRODUCT.
=SUMPRODUCT(($H3=$B$3:$B$20004)*($I3=$D$3:$D$20004)*($J3=$E$3:$E$20004)*($F$3:$F$20004))
The * acts as an AND statement in a logical check, and each of the ($H3=$B$3:$B$20004) is a logical check. When the row is true it will evaluate to 1. When it is false it will evaluate to 0. in the end you wind up with a list of prices or 0s that get summed. The end result is the sum of everything that matches your criteria.
The danger of using this formula is that it can get labour intensive as it is performing array calculations without being an array formula.
I have an excel sheet containing two columns of data that I'd like to rank.
Suppose we have the following:
A B
Franz 58
Daniel 92
Markus 37
Jörg 58
I would like a formula to rank the above data based on column B, and where there are duplicate values (Franz and Jörg) to put the alphabetical name first. What I have at the moment is simply duplicating Franz twice:
=INDEX(Name,MATCH(A2,Points,0))
Can someone advise me of formula / code that will rank the data and arrange duplicate values alphabetically?
Thanks
I would add a helper column in next to your data to help out with ties.
so in column C use
=B1+1/COUNTIF($A$1:$A$4,"<="&A1)/10
This will add on a decimal ranking system based on the name. This assumes that your numbers in column B do not have decimal places, if they do then you will need to increase the 10 on the end of the formula to account for it ie: for 2 decimal places use 1000, 3 : 10000 etc
Use this formula to get the first name
=INDEX(name,MATCH(LARGE(points,1),points,0))
adjust the 1 to 2 for the second name etc
EDIT had the sign around the wrong way
This will rank your data and will not repeat duplicates too:
In C2:
=SUM(1*(b2>$b$2:$b$5))+1+IF(ROW(b2)-ROW($b$2)=0,0,SUM(1*(b2=OFFSET($b$2,0,0,INDEX(ROW(b2)-ROW($b$2)+1,1)-1,1))))
CTRL+SHIFT+ENTER to turn it into an array
Drag these down to C5 and it will not duplicate rank where the name is the same, it will rank them alphabetically if they are the same.
Then if you wanted to order them automatically in order of top performer/score you then do this:
Putting this in E2:
=INDEX(A2:A5,MATCH(LARGE(C2:C5,ROW()-1),C2:C5,0))
...and drag down
Then use a vlookup on your data to return the score putting this in F2:
=vlookup(E2,A2:C5,2,false)
...and drag down
This should give you a table of highest scoring people in score order.
Assuming A2 is the first of the ranked points scores try this version
=INDEX(Name,SMALL(IF(A2=Points,ROW(Points)-MIN(ROW(Points))+1),COUNTIF(A$2:A2,A2)))
confirmed with CTRL+SHIFT+ENTER and copied down
Requires the Name list to be sorted because names with duplicate scores will be listed in the order shown