Vim: Quickly select rectangular blocks of text in visual-block mode - vim

Question

I'm looking for a fast way to select a block of text in visual-block mode. I deal with files of this nature:
aaaa bbbb cccc
aaaa bbbb cccc
aaaa bbbb cccc
dddd Xeee ffff
dddd eeee ffff
dddd eeee ffff
gggg hhhh iiii
gggg hhhh iiii
gggg hhhh iiii
My goal is to select the middle block in visual-block mode. I would do:
Navigate to the corner (where the X is)
Ctrl-V
'e' to extend selection to the end of block
'jj' or '2j' to extend the selection downward to the bottom of the block.
I'm looking for an alternative to (4) that, similar to 'e', would move to the last row of the block. In this simple example 'jj' is not too inconvenient, but sometimes these are large blocks.
There's a similar question here , but that involves jumping a pre-determined number of lines. Is there a way to do this, again an analog to 'e', but moving row-wise instead of column-wise? Thanks!

Answer 1

Starting on the X, you could do this with <C-v>}kee:
<C-v> – start blockwise visual mode
} – go to the end of the paragraph (that motion supposedly provides the benefit of this rather involved combo)
k – one above to exclude the empty line
ee – move the cursor from the first column to the end of the inner block.

Answer 2

I had some fun trying to make a function "select Visual block around cursor".
function! ContiguousVBlock()
let [lnum, vcol] = [line('.'), virtcol('.')]
let [top, bottom] = [lnum, lnum]
while matchstr(getline(top-1), '\%'.vcol.'v.') =~# '\S'
let top -= 1
endwhile
while matchstr(getline(bottom+1), '\%'.vcol.'v.') =~# '\S'
let bottom += 1
endwhile
let lines = getline(top, bottom)
let [left, right] = [vcol, vcol]
while len(filter(map(copy(lines), 'matchstr(v:val,"\\%".(left-1)."v.")'),'v:val=~#"\\S"')) == len(lines)
let left -= 1
endwhile
while len(filter(map(copy(lines), 'matchstr(v:val,"\\%".(right+1)."v.")'),'v:val=~#"\\S"')) == len(lines)
let right += 1
endwhile
call setpos('.', [0, top, strlen(matchstr(lines[0], '^.*\%'.left.'v.')), 0])
execute "normal! \<C-V>"
call setpos('.', [0, bottom, strlen(matchstr(lines[-1], '^.*\%'.right.'v.')), 0])
endfunction
nnoremap <Leader>vb :<C-U>call ContiguousVBlock()<CR>
You can try it with <Leader>vb: It should select any contiguous non-whitespace rectangular block around the cursor. The vertical axis is preferred.
Maybe I'll improve it later, but for now you can try if it solves your problem, if you like.
As an alternative to my homegrown attempt, you could try the popular plugin textobj-word-column. It gives you text objects ac ic aC iC to select a column of words or WORDs.

Answer 3

Start visual mode with v. Then select inner paragraph with ip. Enter visual block mode with <C-v>. Now just go to the end of the block with es as required.
Starting from the bottom right of the block is the same thing, but instead of e, use w.