VBScript User input variable - excel

Question

I am creating a script to split csv files up, I want to let the user input the interval in which the files are split into new ones.
The problem I am having is that when I input the interval it isn't splitting, but yet if I hard code the value in it does split.
Option Explicit
Const ForReading = 1
Const ForWriting = 2
Dim objFSO, objInputFile, objOutputFile
Dim intLine, intFile
Dim strHeaders
Dim strInputFile, strOutputPrefix, strLine
Dim MyDate
Dim userSplit
Dim split
'strInputFile = InputBox("Enter file location")
strInputFile = "H:\VBS\domS_CUST.csv"
strOutputPrefix = strInputFile & DatePart("yyyy", Now) & "-" & DatePart("m", Now) & "-" & DatePart("d", Now)
intFile = 1
intLine = 0
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objInputFile = objFSO.OpenTextFile(strInputFile, ForReading)
If (objInputFile.AtEndOfStream = True) Then
' The file is empty
WScript.Quit 1
End If
strHeaders = objInputFile.ReadLine
userSplit = InputBox("Enter when you want to split")
Do While (objInputFile.AtEndOfStream = False)
split = userSplit
strLine = objInputFile.ReadLine
If (intLine <= 0) Then
Set objOutputFile = objFSO.CreateTextFile(strOutputPrefix & "_" & intFile & ".csv", True)
objOutputFile.WriteLine strHeaders
intLine = 1
End If
objOutputFile.WriteLine strLine
If (intLine >= split) Then
objOutputFile.Close
Set objOutputFile = Nothing
intFile = intFile + 1
intLine = 0
Else
intLine = intLine + 1
End If
Loop
The input is this line:
userSplit = InputBox("Enter when you want to split")
And I cannot seem to get it to split at the value of this, any help would be much appreciated!

Answer 1

You have an On Error Resume Next in your code that you didn't show, otherwise the line
split = userSplit
would've raised the error
Illegal Assignment: 'split'
split is the name of a built-in function, so it cannot be used as a variable name. It's also completely unnecessary, because you could simply use userSplit without assigning its value to another variable.
Correction: As Ekkehard.Horner pointed out in the comments, the Dim split supersedes the built-in function definition, thus no error is raised.
However, the main reason why your code doesn't work as you expect is that the InputBox function returns a string value. To make the comparison with intLine work correctly, you need to convert the string to an integer or long integer:
userSplit = CLng(InputBox("Enter when you want to split"))
...
If (intLine >= userSplit) Then
And you should at least add a check to handle situations where the user pressed "Cancel":
userSplit = CLng(InputBox("Enter when you want to split"))
If userSplit <= 0 Then WScript.Quit 1
Also, by using the the Line property, your code could be simplified to this:
filename = "H:\VBS\domS_CUST.csv"
Set fso = CreateObject("Scripting.FileSystemObject")
Set infile = fso.OpenTextFile(filename)
prefix = fso.BuildPath(fso.GetParentFolderName(filename) _
, fso.GetBaseName(filename) & "_" & Year(Now) & "-" _
& Right("0" & Month(Now), 2) & "-" & Right("0" & Day(Now), 2) & "_")
userSplit = CLng(InputBox("Enter when you want to split"))
If userSplit <= 0 Then WScript.Quit 1
Do Until infile.AtEndOfStream
If infile.Line = 1 Then
headers = infile.ReadLine
Else
If (infile.Line - 2) Mod userSplit = 0 Then
If infile.Line > 2 Then outfile.Close
Set outfile = fso.CreateTextFile _
(prefix & (infile.Line - 2) \ userSplit + 1 & ".csv", True)
outfile.WriteLine headers
End If
outfile.WriteLine infile.ReadLine
End If
Loop
outfile.Close