Using arrays and macros in VBA [closed] - excel

Question

Closed. This question does not meet Stack Overflow guidelines. It is not currently accepting answers.
Questions asking for code must demonstrate a minimal understanding of the problem being solved. Include attempted solutions, why they didn't work, and the expected results. See also: Stack Overflow question checklist
Closed 9 years ago.
Improve this question
I'm a QA. I'm not a developer, but I asked my boss for some busy work. She gave me a development project, and I'm completely confused. We have a spreadsheet with a long list of salespeople and their customers. For each customer, the salesperson, customer name, sales amount, and location are listed like so:
Salesperson Customer Name Sales Amount Location
salesperson1 customerA 3456789 Atlanta
salesperson1 customerB 9475903 Atlanta
salesperson1 customerC 7236433 Atlanta
salesperson1 customerD 9809489 Raleigh
salesperson2 customerA 3456789 Raleigh
salesperson2 customerB 9475903 Raleigh
salesperson2 customerC 7236433 Raleigh
salesperson2 customerD 9809489 Raleigh
salesperson2 customerE 3456789 Raleigh
salesperson3 customerA 9475903 Portland
salesperson3 customerB 7236433 Portland
salesperson3 customerC 9809489 Portland
salesperson4 customerA 9475903 Portland
salesperson4 customerB 7236433 Portland
salesperson4 customerC 9809489 Portland
There are hundreds of lines of salespeople and customers on this spreadsheet. My job is to create a new workbook template. I have successfully done that. The template takes relative sales data and does calculations based on sales numbers. Currently, I've been able to get all of the data from the source in to the template, and the calculations work. However, I need to go further. For each salesperson, I need there data loaded on to a separate sheet, and I need a separate template for each location. For example: notice that salesperson3 and salesperson 4 are in the Portland location. I need a separate sheet for salesperson3 and a separate sheet for salesperson4 on the same workbook which needs to be saved as PORTLAND.XLSM. There will also need to be a template called RALEIGH.XLSM and ALTANTA.XLSM.
So here are my questions:
How do I make an array to notice when I go from salesperson1 to salesperson2 to salesperson3 to salesperson4?
How do I do an array that will eliminate anyone not at that location? I presume I will need a worksheet for each location, and if the name of the worksheet doesn't match the location of that salesperson, that salesperson doesn't get a sheet in that workbook.
I haven't used VB since I was in college almost 2 decades ago. I know the logic, but I don't know the language and syntax.

Answer 1

As Brad mentioned this is going to be a beast to maintain. That being said, if I understand your question correctly, I'd use the .Range() function. If you have your data in a table you can pull an array and do what you're looking for with this function.
Public Sub createSheets()
Dim salespersons As Range, location As String, fileLocation As String, salesperson As String, newSheet As Worksheet
Set salespersons = Range("Table1[Salesperson]")
For i = 1 To salespersons.Count
location = salespersons(i).Offset(0, 3).Value
If i = 1 Or (salespersons(i).Offset(0, 3).Value <> salespersons(i - 1).Offset(0, 3).Value) Then
Call createBook(location)
End If
Next i
For Each wbook In Application.Workbooks
For i = 1 To salespersons.Count
If i = 1 Or (i > 1 And salespersons(i) <> salespersons(i - 1)) Then
salesperson = salespersons(i).Value
location = salespersons(i).Offset(0, 3).Value
If location & ".xlsx" = wbook.Name Then
If i = 1 Or (salespersons(i).Value <> salespersons(i - 1).Value) Then
On Error Resume Next
Set newSheet = wbook.Worksheets(salesperson)
If Err.Number <> 0 Then
Set newSheet = wbook.Worksheets.Add
newSheet.Name = salesperson
End If
End If
End If
End If
Next i
Next
End Sub
Public Sub createBook(location As String)
Dim newBook As Workbook, newSheet As Worksheet, result1 As Boolean, result2 As Boolean
result1 = isWorkbookOpen(location & ".xlsx")
If result1 = False Then
On Error Resume Next
Workbooks(location).Save
If Err.Number <> 0 Then
On Error Resume Next
Workbooks.Open (location & ".xlsx")
If Err.Number <> 0 Then
Workbooks.Add.SaveAs (location & ".xlsx")
Error Err.Number
End If
End If
End If
End Sub
Function isWorkbookOpen(location As String)
Dim ff As Long, Errno As Long
On Error Resume Next
ff = FreeFile()
Open Filename For Input Lock Read As #ff
Close ff
Errno = Err
On Error GoTo 0
Select Case Errno
Case 0:
isWorkbookOpen = False
Case 70:
isWorkbookOpen = True
Case 75:
isWorkbookOpen = False
Case Else: Error Errno
End Select
End Function

Answer 2

Here's an option using pivot tables that requires NO VBA. If you use this, maintenance takes a little more work, but it's very simple to set up and hand off:
From your source, make a pivot-table and add it to a new document.
For your Report Filter, add the SalesPerson and Location. Leave the actual dropdowns at (All) for now or just pick values at random.
For your Row label, you can add the Customer.
For your Values, you can sum your sales amounts.
Make the tab as pretty as you like. This will be your template for all the sales people. The Options ribbon lets you add custom calcuations, % of row totals, etc. Go wild. You now have a tab which can serve as a template for every salesperson!
Make a blank workbook for each location. For each location's workbook, add this template tab for each salesperson that works there. In that tab's pivot table's filters, pick the location and a salesperson.
Repeat #6 until each workbook has a tab for each salesperson and each of those tabs has the proper salesperson and location selected.
Yes, that was monotonous, but now you're done with the hard part! Every salesperson has their own tab and every location has their own file. Thanks to the report filters in the many, many tabs you've just made, each tab is filtered to just the sales in that location for that salesperson.
Updating the data:
The biggest drawback to this option is that everytime a SalesPerson starts selling at a new location, or a new SalesPerson is hired, you'll have to add a new tab. But thanks to your common template tab, this isn't very painful.
For regular updates, just open each file and go to the Data ribbon and Refresh all.

Answer 3

This will loop over a source sheet (the active sheet) and generate a number of workbooks (one per location). A sheet containing customer name and sales amount for each sales person is added to the workbook.
once the workbooks are generated it saves them as their location's name.
' get a named worksheet from specified workbook, creating it if required
Public Function GetSheet(ByVal Name As String, ByVal Book As Workbook, Optional ByVal Ignore As Boolean = False) As Worksheet
Dim Sheet As Worksheet
Dim Key As String
Dim Result As Worksheet: Set Result = Nothing
Key = UCase(Name)
' loop over all the worksheets
For Each Sheet In Book.Worksheets
' break out of the loop if the sheet is found
If UCase(Sheet.Name) = Key Then
Set Result = Sheet
Exit For
End If
Next Sheet
' if the sheet isn't found..
If Result Is Nothing Then
If Ignore = False Then
If Not GetSheet("Sheet1", Book, True) Is Nothing Then
' rename sheet1
Set Result = Book.Worksheets("Sheet1")
Result.Name = Name
End If
Else
' create a new sheet
Set Result = Book.Worksheets.Add
Result.Name = Name
End If
End If
Set GetSheet = Result
End Function
Sub Main()
Dim Source As Worksheet
Dim Location As Workbook
Dim Sales As Worksheet
Dim LocationKey As String
Dim SalesKey As String
Dim Index As Variant
Dim Map As Object: Set Map = CreateObject("Scripting.Dictionary")
Dim Row As Long
Set Source = ThisWorkbook.ActiveSheet
Row = 2 ' Skip header row
Do
' break out of the loop - assumes that the first empty row signifies the end
If Source.Cells(Row, 1).Value2 = "" Then
Exit Do
End If
LocationKey = Source.Cells(Row, 4).Value2
' look at the location, and find the workbook, creating it if required
If Map.Exists(LocationKey) Then
Set Location = Map(LocationKey)
Else
Set Location = Application.Workbooks.Add(xlWBATWorksheet)
Map.Add LocationKey, Location
End If
SalesKey = Source.Cells(Row, 1).Value2
' get the sheet for the salesperson
Set Sales = GetSheet(SalesKey, Location)
' insert a blank row at row 1
Sales.Rows(1).Insert xlShiftDown
' populate said row with the data from the source
Sales.Cells(1, 1).Value2 = Source.Cells(Row, 2)
Sales.Cells(1, 2).Value2 = Source.Cells(Row, 3)
'increment the loop
Row = Row + 1
Loop
' loop over the resulting workbooks and save them - using the location name as file name
For Each Index In Map.Keys
Set Location = Map(Index)
Location.SaveAs Filename:=Index
Next Index
End Sub
Update
This code is only really helpful if you are generating read-only reports, that get replaced every time you generate the report. (this code will probably fail to save on subsequent runs as it does not check to see if a file exists when trying to save, you'll need to delete any previous output before running it again).
This code (in its current form) would need to be added into the workbook with your source data, and the data sheet would need to be active before you run the Main() macro.
If you are trying to do more than just generate a report (like replacing the source data sheet with your new files) it would be much simpler in Access as a few people have already suggested.