Xquery - to get the count of an element - sharepoint

Question

I am new to Xquery. My requirement is very simple, but I couldn’t - due to my lack of knowledge.
I am trying to query a sharepoint site. The sharepoint site’s sample data in xml format is:
<z:row ows_owshiddenversion="4"
ows_Regional_x0020_Regulatory_x0020_="Kyle Godfrey"
ows_Status="No Activity"/>
<z:row ows_owshiddenversion="4"
ows_Regional_x0020_Regulatory_x0020_="Grace Flux"
ows_Status="Strong Interest"/>
<z:row ows_owshiddenversion="4"
ows_Regional_x0020_Regulatory_x0020_="Foo Bar"
ows_Status="Active State"/>
<z:row ows_owshiddenversion="4"
ows_Regional_x0020_Regulatory_x0020_="Batz Quix"
ows_Status="Active State"/>
The requirement is to get the ows_Status and its count. For example:
Strong Interest 1
No Activity 1
Active State 2
As a beginner, I tried a simple query - that is, hardcoded the status name in the where clause of the let statement, but it seems that the where clause didn’t have any effect on the query.
let $Statusvariable := $queryresponse//#ows_Status
where ($queryresponse//#ows_Status="Active State")
return
<Status>{fn:data($Statusvariable)}</Status>
I expected the above code to return only “Active State” status. But it returned all the statuses.
Can you point out my mistake in the above query and provide me the right query to get both statuses and its counts.

Answer 1

OK, let's take this one step at a time. First, what's going wrong. Paraphrased in English, your query means "Let the variable $Statusvariable have as its value the set of ows_Status attributes in the query response, but only in the case that there is at least one ows_Status attribute with the value "Active State". Then return the typed value of $Statusvariable." You may have meant to write something more like
for $x in $queryresponse//#ows_Status
where $x = "Active State"
return <Status>{$x}</Status>
If you want to know how many occurrences there are of each value of the ows_Status attribute, in descending frequency order, I'd write something like this (not tested):
for $value in distinct-values($queryresponse//#ows_Status)
let $n := count($queryresponse//#ows_Status[. = $value])
order by $n descending
return <Status count="{$n}">{$value}</Status>

Answer 2

The probleme here is, that the $queryresponse in each case has such an element, so the condition is always true. You should instead compare it to each individual row record, not the whole response data.
You should also use for if you want to iterate over a set of results.
for $row in $queryresponse//*:row
let $Statusvariable := $row/#ows_Status
where $row/#ows_Status="Active State"
return
<Status>{fn:data($Statusvariable)}</Status>

Answer 3

The query you're using could be shortened to
$queryresponse//#ows_Status[.="Active State"]/element { 'Status' } { data(.) }
For the problem you're really trying to solve (grouping and counting), use C. M. Sperberg-McQueen's answer which is totally fine. XQuery 3.0 would support group by which would be more declarative, but sharepoint doesn't know that.