I have some parameters in a text file which goes as follows
parameter1 =5
parameter2=4
----------
---------
parameter(n-1) = 6
parameter(n)=11
My requirement is that the values of the parameters should sum upto 100 and there can be number of parameters. I was wondering if I could write a function in Vim , which could calculate the sum and display it somewhere?
I have no idea how to pass arguement to such a function,I was thinking it could somehow be done by block selecting the lines with parameter values.
Add following function to your vimrc file:
function! CustomSum()
let sum = 0
for l in range( 1, line('$') )
let fields = split( getline(l), '\s*=\s*' )
if ( len( fields ) != 2 || fields[1] =~? '\D' )
continue
endif
let sum = sum + fields[1]
endfor
return sum
endfunction
And run it:
:echo CustomSum()
That with your input data yields:
26
EDIT to add a range to previous function. Now accepts a range as input parameters named a:firstline and a:lastline. I increment them with 0 to convert them to integers, otherwise the range function complains. Last line echoes the result for debugging but would be better idea to handle the result in a return call (only uncomment it).
function! CustomSum() range
let sum = 0
for l in range( a:firstline + 0, a:lastline + 0 )
let fields = split( getline(l), '\s*=\s*' )
if ( len( fields ) != 2 || fields[1] =~? '\D' )
continue
endif
let sum = sum + fields[1]
endfor
echo sum
"" return sum
endfunction
Now you can do visually selection or normal ranges, like:
:'<,'>call CustomSum()
or
:1,5call CustomSum()
Both should work.
This can also be done with a (pseudo) one-liner as well:
:let s=0
:g/parameter\d\+\s*=\s*\d\+/let s+=matchstr(getline('.'), '\d\+\s*$')
:echo s
It you want a function you fall back to Birei's solution
EDIT: BTW, we can also echo it directly with:
echo eval(join(map(filter(getline(1,'$'), 'v:val =~ "=\\s*\\d"'), 'matchstr(v:val, "=\\s*\\zs\\d\\+")'), '+'))
or if you prefer a command:
command! -nargs=0 -range=% Sum echo eval(join(map(filter(getline(<line1>,<line2>), 'v:val =~ "=\\s*\\d"'), 'matchstr(v:val, "=\\s*\\zs\\d\\+")'), '+'))
Related
I have been poking around for a good solution for a vim thesaurus. The capability is built-in, obviously, but the file everyone seems to use is the mthesaur.txt. While it 'works' in the sense that the commands in insert mode bring up a list, it seems to me the results are programatically correct but not super useful. The vim online thesaurus plugin works very well, but the latency over the wire and necessity of using a split for the returned buffer is less than ideal. Anyone have an opinion about this?
I have written a plugin that can address the two issues you raised here.
Multi-language Thesaurus Query plugin for Vim
It improves the using experience in two regards: more sensible synonym choosing
mechanism; and better and more flexible synonym source(s).
Thesaurus_query.vim screen cast
By default, the plugin uses vim's messagebox for candidate display, with each
synonym labeled by a number. And it let user choose the suitable one to replace
the word under cursor by typing in its number. It works similar to vim's
default spell correction prompt. And drastically reduced the operation time for
choosing proper synonym from a long list of candidates.
To improve the quality of synonym candidates, multiple query backends were
used. For English user, two are note worthy.
thesaurus_com Backend using Thesaurus.com as synonym source
mthesaur_txt Backend using mthesaur.txt as synonym source
thesaurus_com Backend will work straight away. For Local Query Backend to work,
you will need to download mthesaur.txt and tell the plugin where it is
located either by setting variable thesaurus or specifying
variable g:tq_mthesaur_file. Or else only Online Backend will be
functional.
By default, Online Query Backend will be used first. But if internet is not
available or too slow, future query in the current vim session will be handled
by Local Query Backend first to reduce latency time. Priority of these two
backends can also be manually altered(see documentation).
To address the latency issue(which usually stands out when the word is not found), I have introduced a timeout mechanism. You may set
let g:tq_online_backends_timeout = 0.6
if your internet is reasonably fast. So that the latency could be reduced to
under 0.6 second.
The plugin is written in Python, though. So you might want to use it with Vim compiled with Python and/or Python3 support.
If your system is unix-like and if you have awk installed, then I have a
simple solution to your problem that gives you access to thesauri in
multiple languages without internet connection and without a split
window either.
First download LibreOffice thesauri from:
https://cgit.freedesktop.org/libreoffice/dictionaries/tree/
for example.
(Look after th_*.dat files, these are the ones you need, not the .aff and
.dic files which work only for spellchecking with Hunspell.) Download
the *.dat thesauri of your liking and copy them to a subdirectory of the
folder where you will put your plugin; this subdirectory should be
called, "thes."
Now create a new file in your plugin folder (the folder where you should
have the "thes" subdirectory with the *.dat thesauri inside) and put the
following in this file:
" offer choice among installed thesauri
" ==================================================
let s:thesaurusPath = expand("<sfile>:p:h") . "/thes"
function! s:PickThesaurus()
" 1, 1: glob does not ignore any pattern, returns a list
let thesaurusList = glob(s:thesaurusPath . "/*", 1, 1)
if len(thesaurusList) == 0
echo "Nothing found in " . s:thesaurusPath
return
endif
let index = 0
let optionList = []
for name in thesaurusList
let index = index + 1
let shortName = fnamemodify(name, ":t:r")
let optionList += [index . ". " . shortName]
endfor
let choice = inputlist(["Select thesaurus:"] + optionList)
let indexFromZero = choice - 1
if (indexFromZero >= 0) && (indexFromZero < len(thesaurusList))
let b:thesaurus = thesaurusList[indexFromZero]
endif
endfunction
command! Thesaurus call s:PickThesaurus()
This will allow you to pick the thesaurus of your choice by typing
:Thesaurus in Vim's command mode.
(Actually, if you plan to use only one thesaurus then you don't need any
of this; just assign the full name of your thesaurus file to the
buffer-local variable, b:thesaurus).
Finally, add the following to your plugin file:
" run awk on external thesaurus to find synonyms
" ==================================================
function! OmniComplete(findstart, base)
if ! exists("b:thesaurus")
return
endif
if a:findstart
" first, must find word
let line = getline('.')
let wordStart = col('.') - 1
" check backward, accepting only non-white space
while wordStart > 0 && line[wordStart - 1] =~ '\S'
let wordStart -= 1
endwhile
return wordStart
else
" a word with single quotes would produce a shell error
if match(a:base, "'") >= 0
return
endif
let searchPattern = '/^' . tolower(a:base) . '\|/'
" search pattern is single-quoted
let thesaurusMatch = system('awk'
\ . " '" . searchPattern . ' {printf "%s", NR ":" $0}' . "'"
\ . " '" . b:thesaurus . "'"
\)
if thesaurusMatch == ''
return
endif
" line info was returned by awk
let matchingLine = substitute(thesaurusMatch, ':.*$', '', '')
" entry count was in the thesaurus itself, right of |
let entryCount = substitute(thesaurusMatch, '^.*|', '', '')
let firstEntry = matchingLine + 1
let lastEntry = matchingLine + entryCount
let rawOutput = system('awk'
\ . " '" . ' NR == ' . firstEntry . ', NR == ' . lastEntry
\ . ' {printf "%s", $0}' . "'"
\ . " '" . b:thesaurus . "'"
\)
" remove dash tags if any
let rawOutput = substitute(rawOutput, '^-|', '', '')
let rawOutput = substitute(rawOutput, '-|', '|', 'g')
" remove grammatical tags if any
let rawOutput = substitute(rawOutput, '(.\{-})', '', 'g')
" clean spaces left by tag removal
let rawOutput = substitute(rawOutput, '^ *|', '', '')
let rawOutput = substitute(rawOutput, '| *|', '|', 'g')
let listing = split(rawOutput, '|')
return listing
endif
endfunction
" configure completion
" ==================================================
set omnifunc=OmniComplete
set completeopt=menuone
This will allow you to get the synonyms of any word you type in insert
mode. While still in insert mode, press Ctrl-X Ctrl-O (or any key
combination you mapped on omnicompletion) and a popup menu will show up
with the synonym list.
This solution is very crude as compared to Chong's powerful plugin (see above), but it is lightweight and works well enough for me. I use it with thesauri in four different languages.
Script for ~/.vimrc, it needs the file thesaurii.txt (merged dictionaries from https://github.com/moshahmed/vim/blob/master/thesaurus/thesaurii.txt) and perl.exe in path for searching for synonyms. Script tested on win7 and cygwin perl.
Calls aspell to do spell correction, if no synonyms are found. See https://stackoverflow.com/a/53825144/476175 on how to call this function on pressing [tab].
set thesaurus=thesaurii.txt
let s:thesaurus_pat = "thesaurii.txt"
set completeopt+=menuone
set omnifunc=MoshThesaurusOmniCompleter
function! MoshThesaurusOmniCompleter(findstart, base)
" == First call: find-space-backwards, see :help omnifunc
if a:findstart
let s:line = getline('.')
let s:wordStart = col('.') - 1
" Check backward, accepting only non-white space
while s:wordStart > 0 && s:line[s:wordStart - 1] =~ '\S'
let s:wordStart -= 1
endwhile
return s:wordStart
else
" == Second call: perl grep thesaurus for word_before_cursor, output: comma separated wordlist
" == Test: so % and altitude[press <C-x><C-o>]
let a:word_before_cursor = substitute(a:base,'\W','.','g')
let s:cmd='perl -ne ''chomp; '
\.'next if m/^[;#]/;'
\.'print qq/$_,/ if '
\.'/\b'.a:word_before_cursor.'\b/io; '' '
\.s:thesaurus_pat
" == To: Debug perl grep cmd, redir to file and echom till redir END.
" redir >> c:/tmp/vim.log
" echom s:cmd
let s:rawOutput = substitute(system(s:cmd), '\n\+$', '', '')
" echom s:rawOutput
let s:listing = split(s:rawOutput, ',')
" echom join(s:listing,',')
" redir END
if len(s:listing) > 0
return s:listing
endif
" Try spell correction with aspell: echo mispeltword | aspell -a
let s:cmd2 ='echo '.a:word_before_cursor
\.'|aspell -a'
\.'|perl -lne ''chomp; next unless s/^[&]\s.*?:\s*//; print '' '
let s:rawOutput2 = substitute(system(s:cmd2), '\n\+$', '', '')
let s:listing2 = split(s:rawOutput2, ',\s*')
if len(s:listing2) > 0
return s:listing2
endif
" Search dictionary without word delimiters.
let s:cmd3='perl -ne ''chomp; '
\.'next if m/^[;#]/;'
\.'print qq/$_,/ if '
\.'/'.a:word_before_cursor.'/io; '' '
\.&dictionary
let s:rawOutput3 = substitute(system(s:cmd3), '\n\+$', '', '')
let s:listing3 = split(s:rawOutput3, ',\s*')
if len(s:listing3) > 0
return s:listing3
endif
" Don't return empty list
return [a:word_before_cursor, '(no synonyms or spell correction)']
endif
endfunction
I'm new to Vimscript but I am trying to find all the lines which contain #property.
What I am trying is:
norm! gg
wh search( "#property", "cW" ) != 0
echo getline( "." )
endw
But this code has a deadlock. What am I doing wrong?
Don’t pass the c flag, or at least not every time. c specifies that a match at the cursor should be accepted – but search() always moves the cursor to a match!
For example,
let flags = "cW"
while search("#property", flags) != 0
echo getline(".")
let flags = "W"
endwhile
This is a small part of the file, the original file has hundreds of lines.
Line 1 below insert the new line Numbers 1, 2, 3 lines below the new line number 2, 3, and so on, are as follows.
How to use gVim command and function to achieve the change from above to below.
I'm using gVim of windows platform.
Before the modification
hsd
xlfh
1lm
2lm
3lm
4lm
5lm
6lm
7lm
8lm
9lm
slm
s1lm
......
After the modification
hsd
1
xlfh
1lm
2
3
2lm
3lm
4lm
4
5
6
5lm
6lm
7lm
8lm
7
8
9
10
9lm
slm
s1lm
......
I do not know why you would need to do this, but if you need this often, consider a function inside .vimrc:
function! Nameme()
1
let mov = 1
let start = 1
let inc = 0
while 1
call append(line('.'), range(start, start+inc))
let mov += 2
let inc += 1
let start += inc
if mov + line('.') > line('$')
break
endif
execute mov + line('.')
endwhile
endfunction
Then you could just :call Nameme().
It is possible in Vim, merging another file containing the numbers to insert (created by /bin/cat -n for example), here is the beginning.
gg go to first line
o1<esc>"ayy a (will increase) initialized to 1
"byy b (will be cumsum of a) initialized to 1
qz loop this:
:.,<c-r>a advance by a lines
"bp put a(a-1)
... but I will only continue if you format your question so that it does not end up deleted
I've often seen assignments to variables of the form "let s.='something'" Here's the specific piece of code in a vim script that I've been struggling to understand:
let s .= '%' . i . 'T'
let s .= (i == t ? '%1*' : '%2*')
let s .= ' '
let s .= i . ':'
let s .= winnr . '/' . tabpagewinnr(i,'$')
let s .= ' %*'
let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
The code adds the tab number (i) and viewport number (winnr of tabpagewinnr(i,'$')) to the tab name, so that it looks something like "1: 2/4 Buffer name". From the looks of it, the .= operation seems to be appending stuff to s. But then, I don't understand what the first two lines do. Any help is appreciated.
vim's online help is your friend:
:h .=
:let {var} .= {expr1} Like ":let {var} = {var} . {expr1}".
:h expr-.
expr6 . expr6 .. String concatenation
:h expr1 (well - this is a little hard to find):
expr2 ? expr1 : expr1
The expression before the '?' is evaluated to a number. If it evaluates to TRUE, the result is the value of the expression between the '?' and ':', otherwise the result is the value of the expression after the ':'.
Example:
:echo lnum == 1 ? "top" : lnum
Since the first expression is an "expr2", it cannot contain another ?:. The
other two expressions can, thus allow for recursive use of ?:.
Example:
:echo lnum == 1 ? "top" : lnum == 1000 ? "last" : lnum
To keep this readable, using |line-continuation| is suggested:
:echo lnum == 1
:\ ? "top"
:\ : lnum == 1000
:\ ? "last"
:\ : lnum
You should always put a space before the ':', otherwise it can be mistaken for
use in a variable such as "a:1".
One at a time:
let s .= '%' . i . 'T'
Assuming i=9 and s="bleah", s will now be "bleah%9T"
let s .= (i == t ? '%1*' : '%2*')
This is the familiar ternary operator from C. If t==9, then s is now "bleah%9T%1*". If t is anything but 9, then s is now "bleah%9T%2*"
I am a vim user, and I want to be able to loop over a range of substrings when I am substituting. How can I use some vim magic to go from a set of lines like this:
Afoo
Bfoo
Cfoo
Dfoo
to
Abar
Bbar
Cbaz
Dbaz
?
I want to search my file from the start for the next occurance of foo, and replace the first two instances with bar, and the second two with baz. Is using a for loop the best option? If so, then how do I use the loop variable in the substitution command?
I would use a function that has a state, and call this function from %s. Something like:
" untested code
function! InitRotateSubst()
let s:rs_idx = 0
endfunction
function! RotateSubst(list)
let res = a:list[s:rs_idx]
let s:rs_idx += 1
if s:rs_idx == len(a:list)
let s:rs_idx = 0
endif
return res
endfunction
And use them with:
:call InitRotateSubst()
:%s/foo/\=RotateSubst(['bar', 'bar', 'baz', 'baz'])/
The call to the two commands could be encapsulated into a single command if you wish.
EDIT: Here is a version integrated as a command that:
accepts as many replacements as we wish, all the replacements needs to be separated with the separator-character ;
supports back-references ;
can replace only the N first occurrences, N == the number of replacements specified if the command call is banged (with a !)
does not support usual flags like g, i (:h :s_flags) -- for that, we would have for instance to impose the command call to always ends up with a / (or whatever separator-character), if not the last text is interpreted as flags.
Here is the command definition:
:command! -bang -nargs=1 -range RotateSubstitute <line1>,<line2>call s:RotateSubstitute("<bang>", <f-args>)
function! s:RotateSubstitute(bang, repl_arg) range
let do_loop = a:bang != "!"
" echom "do_loop=".do_loop." -> ".a:bang
" reset internal state
let s:rs_idx = 0
" obtain the separator character
let sep = a:repl_arg[0]
" obtain all fields in the initial command
let fields = split(a:repl_arg, sep)
" prepare all the backreferences
let replacements = fields[1:]
let max_back_ref = 0
for r in replacements
let s = substitute(r, '.\{-}\(\\\d\+\)', '\1', 'g')
" echo "s->".s
let ls = split(s, '\\')
for d in ls
let br = matchstr(d, '\d\+')
" echo '##'.(br+0).'##'.type(0) ." ~~ " . type(br+0)
if !empty(br) && (0+br) > max_back_ref
let max_back_ref = br
endif
endfor
endfor
" echo "max back-ref=".max_back_ref
let sm = ''
for i in range(0, max_back_ref)
let sm .= ','. 'submatch('.i.')'
" call add(sm,)
endfor
" build the action to execute
let action = '\=s:DoRotateSubst('.do_loop.',' . string(replacements) . sm .')'
" prepare the :substitute command
let args = [fields[0], action ]
let cmd = a:firstline . ',' . a:lastline . 's' . sep . join(args, sep)
" echom cmd
" and run it
exe cmd
endfunction
function! s:DoRotateSubst(do_loop, list, replaced, ...)
" echom string(a:000)
if ! a:do_loop && s:rs_idx == len(a:list)
return a:replaced
else
let res0 = a:list[s:rs_idx]
let s:rs_idx += 1
if a:do_loop && s:rs_idx == len(a:list)
let s:rs_idx = 0
endif
let res = ''
while strlen(res0)
let ml = matchlist(res0, '\(.\{-}\)\(\\\d\+\)\(.*\)')
let res .= ml[1]
let ref = eval(substitute(ml[2], '\\\(\d\+\)', 'a:\1', ''))
let res .= ref
let res0 = ml[3]
endwhile
return res
endif
endfunction
which could be used this way:
:%RotateSubstitute#foo#bar#bar#baz#baz#
or even, considering the initial text:
AfooZ
BfooE
CfooR
DfooT
the command
%RotateSubstitute/\(.\)foo\(.\)/\2bar\1/\1bar\2/
would produce:
ZbarA
BbarE
RbarC
DbarT
This is Not strictly what you want but can be useful for cycles.
I've written a plugin swapit http://www.vim.org/scripts/script.php?script_id=2294 which among other things can help with cycling through lists of strings. Eg.
:Swaplist foobar foo bar baz
then type
This line is a foo
create a simple yank/paste line, go to last word and ctrl-a swap.
qqyyp$^A
then execute the swap pattern
100#q
to get
This line is foo
This line is bar
This line is baz
This line is foo
This line is bar
This line is baz
This line is foo
This line is bar
This line is baz
This line is foo
This line is bar
This line is baz
...
It could probably be applied to your problem although its {cword} sensitive.
Why not:
:%s/\(.\{-}\)foo\(\_.\{-}\)foo\(\_.\{-}\)foo\(\_.\{-}\)foo/\1bar\2bar\3baz\4baz/
I'm not sure that it covers the breadth of the problem but does have the virtue of being a simple substitute. A more complex one may cover the solution if this one doesn't.
This is how I'd attempt that macro.
qa Records macro in buffer a
/foo<CR> Search for the next instance of 'foo'
3s Change the next three characters
bar To the word bar
<Esc> Back to command mode.
n Get the next instance of foo
. Repeat last command
n Get the next instance of foo
3s Change next three letters
baz To the word bar
<Esc> Back to command mode.
. Repeat last command
q Stop recording.
1000#a Do a many times.
Any advice on how to do it better is welcome.
thanks,
Martin.
It's probably going to be much easier to record a macro that can replace the first two, and then use :s for the rest.
The macro might look like /foo^Mcwbar^[. If you're not familiar with macro mode, just hit q, a (the register to store it in) and then the keystrokes /foo <Enter> cwbar <Escape>.
Now once you've got that macro, do 2#a to replace the first two occurrences in the current buffer and use :s normally to replace the rest.